Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

Mit Wert aus Dropdown Link erstellen

Betrifft: Mit Wert aus Dropdown Link erstellen von: Stephan Studer
Geschrieben am: 12.10.2020 07:34:39

hallo zusammen
Ich möchte mit einem Wert, welchen ich aus einer Dropdownliste zusammensetze einen Link generieren, mit welchem ich dann in derselben Arbeitsmappe auf ein anderes Tabellenblatt springe, wo dieser Wert z.B. in der Zeile B5-G5 vorhanden ist.
Geht das ohne ein Makro?
In der Musterdatei (unten angefügt) wähle ich im Tabellenblatt "Start" den Gerätetyp aus und möchte dann mit diesem Wert automatisch auf die richtige Tabelle (in diesem Fall die "1") springen. Es wäre mir auch schon geholfen, wenn rechts daneben ein Wert mit "Link" erscheint, mit welchem man dann auf die richtige Tabelle springen kann.

Vielen Dank für eure Hilfe.

Gruss Stephan

https://www.herber.de/bbs/user/140816.xlsm

Betrifft: AW: Mit Wert aus Dropdown Link erstellen
von: fcs
Geschrieben am: 12.10.2020 11:09:55

Hallo Stephan,

per Formel ginge es so, wenn alle auswählbaren Einträge im Blatt "Index" gelistet sind.

LG
Franz

HTML add In




Start
 EFG
7Deutsch  
8   
9   
10   
11VZUG  
12   
13   
14   
15DFPQSL6LinkDFPQSL6

verwendete Formeln
Zelle Formel Bereich N/A
G15=HYPERLINK("#"&INDEX(Index!$B:$B;VERGLEICH(Start!E15;Index!C:C;0))&"!A5";E15)  
http://excel-inn.de/dateien/vba_beispiele/tabellenanzeige_in_html_addin.zip
http://Hajo-Excel.de/tools.htm
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007
Add-In-Version 25.21 einschl. 64 Bit






Betrifft: AW: Mit Wert aus Dropdown Link erstellen
von: Stephan Studer
Geschrieben am: 12.10.2020 15:20:22

Hallo Franz

Vielen Dank für deine Antwort und Lösung.
Ich möchte jedoch wenn möglich nur eine Liste führen (Tabelle Dropdown).
Geht das auch ohne zweite Liste?

LG Stephan

Betrifft: AW: Mit Wert aus Dropdown Link erstellen
von: fcs
Geschrieben am: 13.10.2020 11:57:29

Hallo Stephan,

Es gibt in Excel keine Formel-Funktion, die über mehrere Tabellenblätter suchen kann.

welche Funktion haben denn die nummerierten Blätter?

Steht jede Nummer für einen Hersteller?

Falls ja, dann könnte man im Blatt Dropdown die Liste der Hersteller entsprechend erweitern, um in der HYPERLINK-Formel die Blatt-Nummer zu ermitteln.

Ansonsten bleibt nur der Weg via Makro (z.B. Ereignismakro, das Änderung in E15 verarbeitet).

Gruß
Franz

Betrifft: AW: Mit Wert aus Dropdown Link erstellen
von: Stephan Studer
Geschrieben am: 14.10.2020 10:07:03

Hallo Franz

Vielen Dank für deine Antwort.
Mit den Nr. der Blätter habe ich bei meinem aktuellen File im Blatt Index gearbeitet und so den Link erstellt (wie du es auch beschrieben hast). Da ich aber nun gerne nur eine Liste mit den Gerätenamen unterhalten möchte, suche ich nach einer Lösung dafür.
Wie sieht so ein Ereignismakro aus? Das habe ich noch nie verwendet.
Vielen Dank für deine Hilfe.
Gruss Stephan

Betrifft: AW: Mit Wert aus Dropdown Link erstellen
von: fcs
Geschrieben am: 14.10.2020 16:09:25

Hallo Stephan,

hier ein entsprechendes Makro.

LG
Franz
'Ereignis-Makro im VBA-Editor unter dem Code-Module von Tabellenblatt "Start" einfügen
Private Sub Worksheet_Change(ByVal Target As Range)
  Dim varFind
  Dim rngFind As Range
  Dim wks As Worksheet
  Select Case Target.Address(False, False, xlA1)
  Case "E15" 'Zelle, deren Änderung überwacht werden soll
    varFind = Target.Value  'Wert in geänderter Zelle
    For Each wks In ThisWorkbook.Worksheets
      Select Case wks.Name
      Case Me.Name, "Index", "Sprachen", "Dropdown"
        'diese Blätter nicht durchsuchen
      Case Else
        'Produkt-Nummer in Zeile 5 suchen
        Set rngFind = wks.Range("5:5").Find(What:=varFind, LookIn:=xlValues, lookat:=xlWhole)
        If Not rngFind Is Nothing Then
          wks.Activate
          rngFind.Select
          Exit For
        End If
      End Select
    Next
    If rngFind Is Nothing Then
      MsgBox "Produkt-Nummer """ & varFind & """ nicht gefunden"
    End If
  End Select
End Sub


Betrifft: AW: Mit Wert aus Dropdown Link erstellen
von: Stephan Studer
Geschrieben am: 16.10.2020 11:50:52

Hallo Franz

Genial! Funktioniert super.
Vielen Dank für deine Bemühungen.
LG Stephan