Microsoft Excel

Herbers Excel/VBA-Archiv

Sverweis mit Datum prüfen

Betrifft: Sverweis mit Datum prüfen von: Peter
Geschrieben am: 16.10.2020 10:59:08

Hallo zusammen,
ich benötige bitte eure Hilfe:
Beispieltabelle ist hier:
https://www.herber.de/bbs/user/140905.xlsx

Ich muss prüfen ob die Nr1 und Nr2 (beide müssen stimmen) an einem Datum (Spalte E) in Tabelle 1 (A und B) vorkommen, Hier stehen die Nr1 und 2 ebenfalls drin. Leider habe ich in der Tabelle 20202 nur ein Datum und in Tabelle1 eben zwei also muss ich prüfen ob das Datum dazwischen liegt und Ok ist...
Wenn alles passt benötige ich die Werte der Spalten H und I diesem müssen dann in 20202 hinten dran geschrieben werden.

Vielen Dank für die Hilfe und GRüße
Peter

Betrifft: AW: Sverweis mit Datum prüfen
von: SF
Geschrieben am: 16.10.2020 11:06:37

Hola,

=WENNFEHLER(INDEX(Tabelle1!H:H;AGGREGAT(15;6;ZEILE(Tabelle1!$H$2:$H$14)/((Tabelle1!$C$2:$C$14=$D2) *(Tabelle1!$D$2:$D$14=$C2)*($E2>=Tabelle1!$A$2:$A$14)*($E2<=Tabelle1!$B$2:$B$14));1));"")

Gruß,
steve1da

Betrifft: AW: Sverweis mit Datum prüfen
von: chris b.
Geschrieben am: 16.10.2020 11:12:16

Hallo steve1da,
ich hab auch mal hier rein geschaut.
Bin gerade am lernen und würde auch gerne die Formel verstehen.
Dazu müsste ich aber wissen in welche zelle ich Sie einfügen muss. Könntest du es mir sagen ?
grüße Chris

Betrifft: AW: Sverweis mit Datum prüfen
von: SF
Geschrieben am: 16.10.2020 11:13:32

Hola,

die Formel kommt in die Zelle, in der das erste Ergebnis erwartet wird, also in G2.

Gruß,
steve1da

Betrifft: AW: Sverweis mit Datum prüfen
von: chris b.
Geschrieben am: 16.10.2020 11:16:52

Danke. Aber irgendwie passiert da gar nichts.
Funktioniert die Formel in Excel 2007 ?
Hier meine Datei.
https://www.herber.de/bbs/user/140909.xlsx

Betrifft: AW: Sverweis mit Datum prüfen
von: SF
Geschrieben am: 16.10.2020 11:22:59

Hola,

nein, Aggregat() gibt es erst ab Excel2010.

Gruß,
steve1da

Betrifft: AW: Sverweis mit Datum prüfen
von: chris b.
Geschrieben am: 16.10.2020 11:24:06

Alles klar.
Dankeschön !

Betrifft: AW: Sverweis mit Datum prüfen
von: Peter
Geschrieben am: 16.10.2020 11:37:12

...a Traum !! 1001 Dankeschön und ein schönes Wochenende

Peter

Betrifft: AW: Sverweis mit Datum prüfen
von: Peter
Geschrieben am: 20.10.2020 11:07:01

Hallo SF,
wenn du das liest kannst du mir bitte nochmal helfen? was muss ich ändern wenn ich nur die Spalte C oder D in Verbindung mit dem Datum E prüfen will?
Ich habe nun festgestellt das da oft Zahlendreher drin sind wenn beide richtig sein müssen, Danke
Grüße
Peter

Betrifft: AW: nicht nachvollziehbar ...
von: neopa C
Geschrieben am: 20.10.2020 13:27:23

Hallo Peter,

.. was genau meinst Du mit: "oft Zahlendreher drin sind wenn beide richtig sein müssen" genau?

Die Formel in G2 könnte man auch etwas kürzer definieren zu:

=WENNFEHLER(INDEX(Tabelle1!H:H;AGGREGAT(15;6;ZEILE(A$2:A$99)/(Tabelle1!C$2:C$99=$D2)/(Tabelle1!D$2:D$99=C2)/(E2>=Tabelle1!A$2:A$99)/(E2<=Tabelle1!B$2:B$99);1));"")

wobei davon ausgegangen ist, dass die Datumswerte von und bis auch unterschiedlichen sein könnten, was im Beispiel nicht der Fall ist.

und nach unten kopiert.

Gruß Werner
.. , - ...

Betrifft: AW: nicht nachvollziehbar ...
von: Peter
Geschrieben am: 20.10.2020 13:53:14

OK ich versuche zu erklären,

die Prüfung gibt mir Werte zurück, jetzt kann es vorkommen das nur NR1 oder nur Nr2 stimmt aber die Kombination eben nicht.. ich weis blöd aber das würde ich gerne so prüfen wollen (müssen)

Optimal = Nr1 und Nr2 und Datum im Bereich stimmt = 100 % Treffer
Geht auch noch = Nr1 und Datum im Bereich stimmt oder Nr2 und Datum Bereich stimmt.

Den Rest muss ich prüfen was da los war, es sind immer fast 50.000 Einträge da hilft es mir enorm
Danke
Peter

Betrifft: AW: dann also eine ODER-Beziehung ...
von: neopa C
Geschrieben am: 20.10.2020 14:18:45

Hallo peter,

... dann so:

=WENNFEHLER(INDEX(Tabelle1!H:H;AGGREGAT(15;6;ZEILE(A$2:A$99)/((Tabelle1!C$2:C$99=$D2) +(Tabelle1!D$2:D$99=C2)>0)/(E2>=Tabelle1!A$2:A$99)/(E2<=Tabelle1!B$2:B$99);1));"")

Gruß Werner
.. , - ...

Betrifft: AW: dann also eine ODER-Beziehung ...
von: Peter
Geschrieben am: 20.10.2020 15:14:22

Hallo Werner
Danke vielmals funktioniert, aber warum gibt er mir nur die erste Zeile (H) zurück? wenn ich nach rechts rüber ziehe (kopiere) solle er mir doch H/I/J.. zurück geben können ?

Danke und Grüße
Peter

Betrifft: AW: dann musst Du ein noch paar $ investieren ...
von: neopa C
Geschrieben am: 20.10.2020 15:49:46

Hallo Peter,

... in G2 so: =WENNFEHLER(INDEX(Tabelle1!H:H;AGGREGAT(15;6;ZEILE(A$2:A$99)/((Tabelle1!$C$2:$C$99=$D2)+(Tabelle1!$D$2:$D$99=$C2)>0)/($E2>=Tabelle1!$A$2:$A$99)/($E2<=Tabelle1!$B$2:$B$99);1));"")

Gruß Werner
.. , - ...

Betrifft: AW: dann musst Du ein noch paar $ investieren ...
von: Peter
Geschrieben am: 20.10.2020 16:27:10

Hallo Werner,

!! SUPER!! Klasse, vielen Dank dir

Grüße
Peter

Betrifft: AW: bitteschön owT
von: neopa C
Geschrieben am: 20.10.2020 18:39:19

Gruß Werner
.. , - ...