Automatische Email Bedingungen

Hallo zusammen,
ich möchte folgende Excel-Datei modernisieren. Sie soll dazu dienen, dass ich ein wenig mehr Überblick über meine Projekte habe. Insgesamt habe ich hier zwei Reiter. Im ersten Reiter sind verschiedene Aufgaben von diversen Personen/Abteilungen zu verrichten.
Wenn dann eine Person X in der Spalte C mit der bedingten Formatierung, wie hier eine 4 eingibt, der Kreis also voll ist und somit die Aufgabe erledigt, soll der Empfänger aus der Spalte D informiert werden. Am Besten dies dann mit der Information was gemacht wurde, wie hier Zeile 2 Auftrag erstellt.
Die Email soll sich Excel dann im zweiten Reiter Kontaktdaten herausziehen. Diese Zuweisung soll so vonstatten gehen, dass in einer Spalte B dasselbe Kundenkürzel eingetragen ist. Damit möchte ich eine Zuordnung erreichen.
Angenommen man trägt in Zeile drei eine 4 ein, dann soll die Person die für TDC zuständig ist, diese Benachrichtigung automatisch per Email erhalten. Nun sucht Excel im nächsten Reiter in der Spalte B nach dem Wort TDC. Wenn das gefunden wurde, soll es in dieser Zelle in der Spalte E sich die zugehörige Email-Adresse ziehen. Nachdem das alles erfüllt wurde, soll eine Outlook-Email an diese Person automatisch verschickt werden.
Optional wäre solch eine Lösung per Button Funktion interessant und nicht automatisch, sondern erst wenn man auf einen Button klickt.
Anbei meine Version, wie weit ich mit meinen Anfänger-Kenntnissen gekommen bin..
Danke euch!
https://www.herber.de/bbs/user/142288.xlsm

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Marco,
hier mal eine Idee, wie Du Dein Vorhaben umsetzen könntest. Ich hoffe, ich habe alles richtig verstanden...
Habe allerdings meinen eMail-Style verwendet....
Du kannst auch die Schrift formatieren und wie Du das startest (z.B. per Button) musst Du Dir noch überlegen.
Probiere es halt mal aus:

Code:
[Cc][+][-]

Private Sub Mail_Senden()
'Sendet Mail mit Signatur
  Dim WSh1 As Worksheet, WSh2 As Worksheet, iZeile As Long
  Dim sMailtext As String, iGefunden As Long, sKunde As String
 
  Set WSh1 = ThisWorkbook.Sheets("ini_Vorlage")             ' Blatt mit Maildaten
  Set WSh2 = ThisWorkbook.Sheets("Eingabe")                 ' Datenblatt
  If ActiveSheet.Name <> WSh2.Name Then Exit Sub            ' Falsches Blatt
 
  iZeile = ActiveCell.Row
  If WSh2.Cells(iZeile, "C").Value < 4 Then Exit Sub        ' Projekt nicht fertig

'Kunden suchen
  sKunde = WSh2.Cells(iZeile, "D").Value
  If sKunde = "" Then Exit Sub                              ' Keine Kunde angegeben
  
  On Error Resume Next
  iGefunden = Application.WorksheetFunction.Match(sKunde, WSh1.Range("B:B"), 0)
  On Error GoTo 0
  If iGefunden = 0 Then
     MsgBox "Für den Kunden '" & sKunde & "' wurden keine Maildaten gefunden!" _
            , vbCritical, "Mailversand"
     Exit Sub
  End If
 
'Jetzt die Mail kreieren
  With CreateObject("Outlook.Application").CreateItem(0)
    .BodyFormat = 2                                         ' HTML-Format
    .Subject = "Information für die Abteilung " _
             & WSh1.Cells(iGefunden, "A").Value             ' Betreff
    .To = WSh1.Cells(iGefunden, "E").Value                  ' Empfänger
    sMailtext = WSh1.Cells(iGefunden, "D").Value
    If sMailtext Like "Herr*" Then
        sMailtext = "r " & sMailtext
    Else
        sMailtext = " " & sMailtext
    End If
    sMailtext = "<body style='font-size:10pt;font-family:Arial;color:#000000;'>" _
              & "Sehr geehrte" & sMailtext & ",<br><br>" _
              & "folgende Aufgabe wurde durchgeführt:<br><br>" _
              & "<b>" & WSh2.Cells(iZeile, "A").Value _
              & "</b><br></body>" ' Mailtext
    .GetInspector
    .HTMLBody = Replace(sMailtext, vbLf, "<br>") _
              & .HTMLBody                                   ' Mailbody + Signatur füllen
    .Display
  End With

End Sub

_________________________
viele Grüße aus Freigericht 😊
Karl-Heinz

Beliebteste Forumthreads (12 Monate)

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread