Anzeige
Archiv - Navigation
1876to1880
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Kalender automatisch füllen

Kalender automatisch füllen
28.03.2022 16:36:49
Felix
Hallo,
eine Kollegin hat mir eine, als Nicht-Excel-Profi, Frage gestellt, die ich nicht so einfach beantworten kann.
Zur Frage:
Ich habe mehrere Excel-Mappen und möchte Daten von einer, in eine andere, in der ein Kalender ist, eintragen.
Also z.B. Ich habe eine Mappe mit einer Spalte "Datum" und eine mit "Themen" und möchte die Zellen der Spalte "Themen", wenn das Datum im Kalender übereinstimmt, in den Kalender schreiben. Anbei einmal die Mappe mit den Daten und einmal der Kalender.
Könnt ihr mir evtl helfen?
Hier die Excel-Dateien:
https://www.herber.de/bbs/user/152114.xlsx
https://www.herber.de/bbs/user/152115.xlsx
Danke und liebe Grüße aus Österreich :)

16
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Kalender automatisch füllen
28.03.2022 16:50:25
{Boris}
Hi,
mit Deinem bestehenden Aufbau wird das nicht - oder nur sehr umständlich - realisierbar sein, da die Einträge in Deinem Kalender untereinander verkettet werden müssen - damit würde auch das Datum Bestandteil des Textes werden und ließe sich nicht so einfach auswerten, und...
Ändere Deinen Aufbau - konkret: Füge in der Kalenderdatei 1 Spalte mit den Datümern ein (untereinander - das ganze Jahr) - und rechts davon holst Du Dir in den einzelnen Spalten die Termine z.B. per SVERWEIS aus den einzelnen Mappen. Am Ende kannst Du dann diese Einträge mit der Funktion TEXTVERKETTEN in Deinen "Übersichtskalender" eintragen.
VG; Boris
Anzeige
Beispiel
28.03.2022 17:07:22
{Boris}
Hi,
in Deine Kalenderdatei schreibst Du alle Datümer untereinander - beginnend in A14 (1.1.22, 2.1.22 usw.)
In den Spalten B, C, D und E holst Du Dir per normalem SVERWEIS die Termine aus Deinen anderen Mappen - im Beispiel also max. 4 andere Mappen.
In Spalte F verkettest Du wie folgt:
F14:
=TEXT(A14;"TT.MM.JJJJ")&ZEICHEN(10)&TEXTVERKETTEN(ZEICHEN(10);WAHR;B14:E14)
und runterkopieren.
In Deinen Kalender kommt jetzt folgende Formel in
A5:
=LET(x;DATUM($B$3;$A$3;(2-WOCHENTAG(DATUM($B$3;$A$3;1);2))+(SPALTE(A4)-1)+(ZEILE(B1)-1)*7); WENNFEHLER(SVERWEIS(x;$A$14:$F$82;6;);x))
und sowohl nach rechts als auch nach unten kopieren. Die Zellen im Bereich A5:G10 versiehst Du jetzt noch in den Zelloptionen mit Zeilenumbruch.
Hoffe, das war verständlich.
VG, Boris
Anzeige
Kleine Ergänzung...
28.03.2022 17:12:54
{Boris}
Hi,
ich hatte in meiner Textmappe die Matrix nur bis Zeile 82 drin - das musst Du erweitern auf z.B. 400:
=LET(x;DATUM($B$3;$A$3;(2-WOCHENTAG(DATUM($B$3;$A$3;1);2))+(SPALTE(A4)-1)+(ZEILE(B1)-1)*7); WENNFEHLER(SVERWEIS(x;$A$14:$F$400;6;);x))
VG, Boris
AW: Kleine Ergänzung...
28.03.2022 17:25:02
Felix
Hi,
danke für die schnelle Antwort, funktioniert soweit sehr gut :)
Morgen schau ich mir noch an, wie ich das mit SVERWEIS mache. Sind ja teilweise mehrere Zeilen mit demselben Datum aber anderen Themen...
Danke auf jeden Fall! :)
LG Felix
Mehrere Treffer zum selben Datum...
28.03.2022 17:39:21
{Boris}
Hi,
...kannst Du - bezogen auf mein Beisüpiel - so ermitteln:
B14:
=MTRANS(FILTER([152115.xlsx]Tabelle1!$B$1:$B$500;[152115.xlsx]Tabelle1!$A$1:$A$500=A14;""))
und runterkopieren.
Wobei 152115.xlsx eine Quelldatei ist. Wenn Deine Quellmappen stets auch mehrere Ereignisse zum selben Datum enthalten, musst Du für genügen Spalten in Deiner Kalenderdatei sorgen - für jede Mappe so viele Spalten, wie es maximal Treffer geben kann. Aber an Spalten mangelt es ja nicht in einem Excel-Arbeitsblatt.
VG, Boris
Anzeige
AW: Mehrere Treffer zum selben Datum...
29.03.2022 09:36:34
Felix
Hi,
hab ich jetzt hinbekommen, danke dir vielmals!
Es haut jetzt allerdings meine bedingte Formatierung zusammen. Ich lasse (siehe Bild) immer den jetzigen Monat fett erscheinen und die anderen Tage hellgrau...
Was mache ich falsch?
Userbild
Und: kann ich, wenn in der Ausgangsmappe ein Thema durchgestrichen und oder rot ist, dieses Thema vom Kalender ausschließen?
Dankeschön!
LG Felix
Zeig mal bitte Deine Datei...
29.03.2022 10:56:35
{Boris}
Hi,
...mit dem aktuellen Stand.
VG, Boris
AW: Zeig mal bitte Deine Datei...
29.03.2022 11:10:56
Felix
Hi,
hier bitte: https://www.herber.de/bbs/user/152123.xlsx
Ich habe, zu dem Filtern mit durchgestrichen, evtl eine andere Lösung. Habe eine Spalte, in der Ausgangsdatei, gefunden (Spalte I) in der, immer, wenn das Thema durchgestrichen ist ein Bindestrich (–) steht. Das könnte man zum Vergleichen nehmen, oder?
Danke und lG Felix
Anzeige
Ändere Deine erste Bedingung...
29.03.2022 11:24:44
{Boris}
Hi,
...in der Bedingten Formatierung wie folgt:
=MONAT(LINKS(A5;10))=$A$3
VG, Boris
AW: Ändere Deine erste Bedingung...
29.03.2022 11:47:04
Felix
Hi,
super danke, habe ich für beide so Formatierungen so gemacht, funktioniert :)
Wie mach ich es jetzt am besten, dass die Spalte I in Sonderthemengesamtuebersicht_2022.xlsx berücksichtigt wird, sodass nur Themen eingespielt werden, bei denen in der Spalte I kein Bindestrich (–) steht?
=MTRANS(FILTER([Sonderthemengesamtuebersicht_2022.xlsx]SONDERTHEMEN_2022!$C$1:$C$500; [Sonderthemengesamtuebersicht_2022.xlsx]SONDERTHEMEN_2022!$B$1:$B$500=A14;""))
Dankeschön und lG Felix
Nachfrage...
29.03.2022 11:51:40
{Boris}
Hi,
...steht der Bindestrich in Spalte I solo oder ist er Bestandteil eines längeren Strings?
VG, Boris
Anzeige
AW: Nachfrage...
29.03.2022 11:55:12
Felix
Hi,
der Bindestrich steht solo drin.
Hier ein Auszug aus dem File.
Userbild
LG Felix
OK - siehe meine andere Antwort...oT
29.03.2022 11:55:46
{Boris}
VG, Boris
AW: Ändere Deine erste Bedingung...
29.03.2022 11:54:58
{Boris}
Hi,
grundsätzlich kannst Du UND-Bedingungen innerhalb der FILTER-Funktion multiplizieren (ODER-Bedingungen werden addiert):
Hier das Beispiel auf zusätzliche Überprüfung der Spalte I auf Bindestrich (solo):
=MTRANS(FILTER([Sonderthemengesamtuebersicht_2022.xlsx]SONDERTHEMEN_2022!$C$1:$C$500; ([Sonderthemengesamtuebersicht_2022.xlsx]SONDERTHEMEN_2022!$B$1:$B$500=A14) *([Sonderthemengesamtuebersicht_2022.xlsx]SONDERTHEMEN_2022!$I$1:$I$500"-");""))
VG, Boris
Anzeige
AW: Ändere Deine erste Bedingung...
29.03.2022 11:58:56
Felix
Hi,
wahnsinn, danke. Meister der Excel-Formeln ;)
LG Felix
Sehr gut! :-) oT
29.03.2022 12:05:32
{Boris}
VG, Boris

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige