Herbers Excel/VBA-Archiv

aus excel Mail mit LotusNotes

• aus excel Mail mit LotusNotes von mischa richter vom 28.09.2003 14:50:25
  • AW: aus excel Mail mit LotusNotes - von Ramses am 28.09.2003 17:05:13
    • danke - von mischa richter am 28.09.2003 17:21:09

Betrifft: aus excel Mail mit LotusNotes von: mischa richter
Geschrieben am: 28.09.2003 14:50:25

hi,
wie kann ich mit vba aus msExcel heraus eine LotusNotes - Mail erstellen?

Mit MS-Outlook ist es ja kein Problem.

Danke schonmal.

Mischa




Betrifft: AW: aus excel Mail mit LotusNotes von: Ramses
Geschrieben am: 28.09.2003 17:05:13

Hallo

das hab ich mal gefunden.
Da ich kein Notes habe kann ich es leider nicht testen und dir auch keinen Support anbieten.
Da wären dann die einschlägigen News-Groups die erste Wahl :-)




Public Sub SendNotesMail(Subject As String, Attachment As String, Recipient As String, BodyText As String, SaveIt As Boolean)
'Set up the objects required for Automation into lotus notes
Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim EmbedObj As Object 'The embedded object (Attachment)
'Start a session to notes
Set Session = CreateObject("Notes.NotesSession")
'Get the sessions username and then calculate the mail file name
'You may or may not need this as for MailDBname with some systems you
'can pass an empty string
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
'Open the mail database in notes
Set Maildb = Session.GETDATABASE("", MailDbName)
If Maildb.IsOpen = True Then
'Already open for mail
Else
Maildb.OPENMAIL
End If
'Set up the new mail document
Set MailDoc = Maildb.CREATEDOCUMENT
MailDoc.Form = "Memo"
MailDoc.sendto = Recipient
MailDoc.Subject = Subject
MailDoc.Body = BodyText
MailDoc.SAVEMESSAGEONSEND = SaveIt
'Set up the embedded object and attachment and attach it
If Attachment <> "" Then
    Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment")
    Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment, "Attachment")
    MailDoc.CREATERICHTEXTITEM ("Attachment")
End If
'Send the document
MailDoc.PostedDate = Now() 'Gets the mail to appear in the sent items folder
MailDoc.Send 0, Recipient
'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set Session = Nothing
Set EmbedObj = Nothing
End Sub 

     Code eingefügt mit Syntaxhighlighter 1.16


Gruss Rainer




Betrifft: danke von: mischa richter
Geschrieben am: 28.09.2003 17:21:09

danke - werds demnächst testen!
mischa