kkleinste über mehrere Tabellen

Bild

Betrifft: kkleinste über mehrere Tabellen
von: Uwe
Geschrieben am: 03.11.2003 20:49:08

Hallo Zusammen,

ich brauche mal eure Hilfe zu einem Problem, bei dem ich nicht mehr weiter komme:

Folgende unten genannte Formel benutze ich um in einer Tabelle mit dem Namen:"Übersicht" aus den zwei anderen Tabellen mit den Namen "Tabelle1" und "Tabelle2" die kleinste in der Spalte B hier zu Testzwecken nur in
Zeile 2 bis 11 Konto-Nr. als erste Konto-Nr. in der Tabelle "Übersicht"
anzuzeigen und dann in den daruter folgenden Zellen die nächste größere, usw.

Mein Problem besteht darin, dass als Ergebnis #NV angezeigt wird und ich nicht den Fehler finde...

Zur Veranschaulichung habe ich die Exel-Tabelle:
https://www.herber.de/bbs/user/1733.xls

Es wäre riesig toll, wenn mir hierbei jemand helfen könnte.

Im voraus vielen Dank.
Uwe

{=INDEX((N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE(2:11))));VERGLEICH(KKLEINSTE(N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE(2:11)));ZEILE()-1);(N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE(2:11))));0))}

Bild


Betrifft: KKLEINSTE über mehrere Tabellen im Array
von: Boris
Geschrieben am: 03.11.2003 23:06:03

Hi Uwe,

das sollte doch eigentlich viel einfacher und kürzer gehen:

{=KKLEINSTE(N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE($2:$11)));ZEILE(A1))}

und dann runterkopieren.

Beginnt mit der kleinsten, dann die 2.-kleinste etc. etc..

Grüße Boris


Bild


Betrifft: AW: KKLEINSTE über mehrere Tabellen im Array
von: Uwe
Geschrieben am: 03.11.2003 23:19:40

Hallo Boris,

danke für Deine schnelle Hilfe, aber es dürfen keine Duplikate
vorkommen: wenn zwei gleiche Zahlen vorkommen, zeigt er auch
zweimal die gleiche Zahl an. Dies sollte aber vermieden werden.

Wäre für eine weiter Hilfestellung sehr dankbar.

Uwe


Bild


Betrifft: KKLEINSTE über mehrere Tabellen ohne Doppler
von: Boris
Geschrieben am: 03.11.2003 23:32:53

Hi Uwe,

hättest du das im ersten Beitrag dazugeschrieben, dann wär´s auch schon beantwortet.
Anyway - so geht´s:

In D2:
{=MIN(N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE($2:$11))))}

In D3 (und runterkopieren):

{=MIN(WENN(N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE($2:$11)))>D2;N(INDIREKT("Tabelle"&SPALTE(A:B)&"!B"&ZEILE($2:$11)))))}

Natürlich wieder alles Array-Formeln.

Grüße Boris


Bild


Betrifft: Super: Vielen Dank
von: Uwe
Geschrieben am: 03.11.2003 23:42:33

Hallo Boris,

vielen Dank für die superschnelle Hilfe.
Hat alles geklappt.

Schönen Abend noch.

Uwe


Bild

Beiträge aus den Excel-Beispielen zum Thema " kkleinste über mehrere Tabellen"