2 WENN-Bedingungen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: 2 WENN-Bedingungen
von: Olli
Geschrieben am: 10.11.2003 11:55:02

Hallo Experten,

wir haben bei der Bearbeitung einer Excel-Tab. folgendes Problem:

aus einer Tabelle sollen Werte "unter Berücksichtigung zweier WENN-Bedingungen" ausgesucht werden.

Dies kann man sich folgend darstellen.
Tab.1 zeigt an:
Spalte A Spalte B Spalte C
Rubrik 1 Var.1 400,-
Rubrik 1 Var.2 300,-

In Tab.2 sollen eine Zelle angeben:
Wenn in SpalteA=Rubrik1 und in SpalteB=Var.1 setze 400,-, ansonsten 0!!
oder
Wenn in SpalteA=Rubrik1 und in SpalteB=Var.2 setze 300,-, ansonsten 0!!

Ich hoffe das Problem verständlich rübergebracht zu haben und hoffe auf Lösungsvorschläge (würde einige Arbeitschritte vereinfachen!)

Danke im vorraus
Olli

Bild


Betrifft: AW: 2 WENN-Bedingungen
von: Holger Levetzow
Geschrieben am: 10.11.2003 12:11:49

da gibt es zig Möglichkeiten, z.B.

=WENN(A1&B1="Rubrik 1Var.1";400;WENN(A1&B1="Rubrik 1Var.2";300;0))

Holger


Bild


Betrifft: AW: 2 WENN-Bedingungen
von: Thomas S.
Geschrieben am: 10.11.2003 12:21:36

Hallo Olli

Spalte C: Formel =WENN(D2=0;E2;D2)
Spalte D: Formel =WENN(UND(A2="Rubrik 1";B2="Var.1");400;0)und Schrift unsichtbar oder Spalte ausblenden
Spalte E: Formel =WENN(UND(A2="Rubrik 1";B2="Var.2");300;0)und Schrift unsichtbar oder Spalte ausblenden

jetzt sind deine Bedingungen erfüllt.

Gruß Thomas S.


Bild


Betrifft: AW: 2 WENN-Bedingungen
von: Galenzo
Geschrieben am: 10.11.2003 12:28:16

Hallo,
die Kurzform für die Verbindung zweier WENNs ohne UND:
=WENN((A2="Rubrik 1")*(B2="Var.1");400;0)
oder mit UND:
=WENN(UND(A2="Rubrik 1";B2="Var.1");400;0)

mfg


Bild


Betrifft: Die "echte" Kurzform wäre dann aber ohne WENN:
von: Boris
Geschrieben am: 10.11.2003 12:40:35

Hi Galenzo,

=(A2="Rubrik 1")*(B2="Var.1")*400

Grüße Boris


Bild


Betrifft: AW: Klasse!
von: Galenzo
Geschrieben am: 10.11.2003 12:43:18

Lernmodus.Activate
Msgbox "Toll" & "wieder was gelernt"
:-)


Bild


Betrifft: AW: 2 WENN-Bedingungen
von: Jörg Gradert
Geschrieben am: 10.11.2003 13:22:33

Hallo Thomas,
WENN()´s lassen sich verschachteln, so kannst Du dir die Hilfsspalten ersparen.
Holgers Formel ist übrigens für die Aufgabenstellung OK.

WENN(Bedingung;dannWert;sonstWert)
WENN(Bedingung1;dannWert1;WENN(Bedingung2;dannWert2;sonstWert))

Formel in C2 sieht dann so aus
=WENN(UND(A2="Rubrik 1";B2="Var.1");400;WENN(UND(A2="Rubrik 1";B2="Var.2");300;0))

oder mehr hier

http://www.excelformeln.de/formeln.html?welcher=128

demnach funktioniert auch folgende, wie ich finde, schöne Form, da ich immer Probleme mit der Übersichtlichkeit bei den Klammerebenen habe.

bei Text als Rückgabewert
=WENN(Bedingung1;"EINS";) & WENN(Bedingung2;"ZWEI";) & ... 'sonst garnichts
Man kann auch für sonst leere Anführungsstriche einsetzen.

Bei Zahl als Rückgabewert
=WENN(Bedingung1;1;) + WENN(Bedingung2;2;) + ... 'sonst garnichts
Man kann auch für sonst 0 einsetzen.

Formel in C2 in dieser Form
=WENN(UND(A2="Rubrik 1";B2="Var.1");400;) + WENN(UND(A2="Rubrik 1";B2="Var.2");300;)

Gruss Jörg


Bild


Betrifft: Formel von Boris
von: Jörg Gradert
Geschrieben am: 10.11.2003 13:56:28

Hallo Alle miteinander,

=(A2="Rubrik 1")*(B2="Var.1")*400+(A2="Rubrik 1")*(B2="Var.2")*300

Boris, die Idee anstelle von WENN() mit FALSCH/WAHR zu multiplizieren finde ich gut.
Hast Du mir wohl schon mal gezeigt, hatte ich vergessen.

Gruss Jörg


Bild


Betrifft: AW: 2 WENN-Bedingungen
von: Thomas S.
Geschrieben am: 11.11.2003 13:07:23

Hallo allen Wenn-Spezialisten

Ich hab nicht gedacht, was man in so kurzer Zeit alles lernen kann.

Vielen Dank


Bild

Beiträge aus den Excel-Beispielen zum Thema " Fehler bei Konstanten"