Sortieren auf nicht selektiertem sheet

• Sortieren auf nicht selektiertem sheet von Lupus vom 26.11.2003 11:18:04
  • AW: Sortieren auf nicht selektiertem sheet - von Nike am 26.11.2003 11:24:49
    • AW: Sortieren auf nicht selektiertem sheet - von Lupus am 26.11.2003 12:09:34
      • AW: Sortieren auf nicht selektiertem sheet - von Nike am 26.11.2003 13:21:55
        • AW: Danke - von Lupus am 26.11.2003 16:00:24
    • AW: Sortieren auf nicht selektiertem sheet - von Lupus am 26.11.2003 12:28:52

Betrifft: Sortieren auf nicht selektiertem sheet
von: Lupus
Geschrieben am: 26.11.2003 11:18:04
Hallo Exceluser,

wie kann man per VBA ein Tabellenblatt sortieren, ohne das Tabellenblatt zu aktivieren oder zu selektieren.

Der untenaufgeführte Code funktioniert nur, wenn Worksheets(10) das aktive Worksheet ist, nicht jedoch, wenn ein anderes Worksheet aktiv ist.

Sub ordnen_Artikelnummer()
Dim Bereich As Range
Dim eSpalte As Integer, lSpalte As Integer
lZeile = Worksheets(10).Range("A1").CurrentRegion.Cells(Range("A1").CurrentRegion.Cells.Count).Row
lSpalte = Worksheets(10).Range("A1").CurrentRegion.Cells(Range("A1").CurrentRegion.Cells.Count).Column
Set Bereich = Worksheets(10).Range(Cells(1, 1), Cells(lZeile, lSpalte))
Bereich.Sort Key1:=Range("A2"), Order1:=xlAscending, Header:=xlGuess, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
End Sub

Gruß Lupus

Betrifft: AW: Sortieren auf nicht selektiertem sheet
von: Nike
Geschrieben am: 26.11.2003 11:24:49
Hi,

Sub ordnen_Artikelnummer()
dim wks as worksheet
Dim Bereich As Range
Dim eSpalte As Integer, lSpalte As Integer
set wks = Worksheets(10)
lZeile = wks.Range("A1").CurrentRegion.Cells(wks.Range("A1").CurrentRegion.Cells.Count).Row
lSpalte = Wks.Range("A1").CurrentRegion.Cells(wks.Range("A1").CurrentRegion.Cells.Count).Column
Set Bereich = wks.Range(wks.Cells(1, 1), wks.Cells(lZeile, lSpalte))
Bereich.Sort Key1:=wks.Range("A2"), Order1:=xlAscending, Header:=xlGuess, _
OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal
End Sub

Bye

Nike

Betrifft: AW: Sortieren auf nicht selektiertem sheet
von: Lupus
Geschrieben am: 26.11.2003 12:09:34
Hi Nike,

danke; erhalte leider einen Laufzeitfehler 9 (Index außerhalb des gültigen Bereichs) bei set wks = Worksheets(10).

Worin besteht den nun eigentlich der Unterschied zwischen Deinem und meinem Code?

Gruß Lupus

Betrifft: AW: Sortieren auf nicht selektiertem sheet
von: Nike
Geschrieben am: 26.11.2003 13:21:55
Hi,

>Worin besteht den nun eigentlich der Unterschied zwischen Deinem und meinem Code?

Hm, meiner funktioniert? ;-)

Ok, genug gescherzt.
ich hab bei allen Zellbezügen
einen Verweis auf das betroffene Tabellenblatt dabei (wks.),
nur so funkts...

Bye

Nike

Betrifft: AW: Danke
von: Lupus
Geschrieben am: 26.11.2003 16:00:24

Betrifft: AW: Sortieren auf nicht selektiertem sheet
von: Lupus
Geschrieben am: 26.11.2003 12:28:52
Hallo Nike,

alles klar, hatte zwischendurch ein Tabellenblatt gelöscht.

Danke, Gruß Lupus

Excel-Beispiele zum Thema " Sortieren auf nicht selektiertem sheet"
Felder über VBA sortieren	Zellinhalte zeilenweise sortieren
Nach dem Zufallsprinzip umsortieren	Menüpunkte sortieren
Tabellen hinzufügen und sortieren	Alphanumerisch sortieren
Werte in mehreren Spalten sortieren	IP-Nummern nach Gruppen sortieren
Zeilenweise sortieren	Auf- und absteigend sortieren ohne Sortierfunktion