Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
356to360
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
356to360
356to360
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

12 workbooks öffnen-drin: jeweils 11 Blätter(gs)

12 workbooks öffnen-drin: jeweils 11 Blätter(gs)
05.01.2004 17:40:12
peristeri
Hallo an Euch alle!

schon vor Weihnachten hatte ich dieses Problem und Dieter u. Nepomuk gaben mir sehr hilfreiche Tipps.
Obwohl die genannten Schritte im einzelnen funktionieren, klappt es beim zusammenfügen nicht;-((
Nun bin ich auf Eure Hilfe wieder angewiesen und auf diese Möglichkeit im Forum sehr dankbar...
Euer Peristeri

Aufgabe:
12 workbooks öffnen (deren Namen sollen 1999.xls bis 2010.xls sein), unter genannten pfad speichern
jedes dieser workbooks soll 11 sheets (mit namen: gs1 bis gs11) besitzen.

Vielen Dank


Sub neue_dateien_mit_gs()
Dim i As Integer
Dim jahr As Integer
Dim monat As Integer
Dim pfad As String
Dim wb As Workbook
Dim gs As Integer 'zähler
pfad = "D:\Eigene Dateien\"
jahr = Year(Date)
For i = 1 To 12
Set wb = Workbooks.Add
wb.SaveAs FileName:=pfad & Format$(DateSerial(i - 2, 1, 1), "yyyy") & ".xls"
For gs = 1 To 11       'soll 11 Blätter pro Datei erstellen!
'es funktioniert!
Sheets.Add
ActiveSheet.name = "GS" & gs
Next gs
wb.SaveAs FileName:=pfad & Format$(DateSerial(i - 2, 1, 1), "yyyy") & ".xls"
wb.Close
Next i
End Sub

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: 12 workbooks öffnen-drin: jeweils 11 Blätter(gs)
06.01.2004 01:18:07
Dieter Klemke
Hallo peristeri,
du speicherst 2 mal mit SaveAs unter dem gleichen Namen. Das erste SaveAs muss weg.
Wenn du tatsächlich nur genau die Blätter GS1 bis GS11 haben willst, solltest du die standardmäßig vorhandenen Blätter "Tabelle1" usw. entfernen.
Wenn die Blätter GS1 bis GS11 aufsteigend eingefügt werden sollen, musst du noch einen Positionsparameter einfügen.
Ich habe das mal im folgenden Code zusammengestellt:

Sub neue_dateien_mit_gs()
Dim i As Integer
Dim jahr As Integer
Dim monat As Integer
Dim pfad As String
Dim wb As Workbook
Dim ws As Worksheet
Dim gs As Integer 'zähler
pfad = "D:\Eigene Dateien\"
jahr = Year(Date)
For i = 1 To 12
Set wb = Workbooks.Add
For gs = 1 To 11       'soll 11 Blätter pro Datei erstellen!
'es funktioniert!
Sheets.Add After:=wb.Sheets(wb.Sheets.Count)
ActiveSheet.Name = "GS" & gs
Next gs
Application.DisplayAlerts = False
For Each ws In wb.Worksheets
If Left$(ws.Name, 2) <> "GS" Then ws.Delete
Next ws
Application.DisplayAlerts = True
wb.SaveAs Filename:=pfad & Format$(DateSerial(i - 2, 1, 1), "yyyy") & ".xls"
wb.Close
Next i
End Sub

MfG
Dieter
Anzeige
AW: 12 workbooks öffnen-drin: jeweils 11 Blätter(g
07.01.2004 15:35:57
peristeri
Hallo Dieter!

leider funktioniert der Befehl
sheets add after..... nicht!
die methode "add" für das objekt "sheet" ist fehlgeschlagen fehler 1004!

Dein Tipp mit dem doppelten save as stimmte. ich hatte es selbst festgestellt!
ich arbeite dran von Deinem Vorschlag voranzukommen.
Danke Dir !
Peristeri
Problem ist gelöst!!! DANKE
07.01.2004 15:54:03
peristeri
Ich habe den Tipp von Reinhard probiert und es läuft!
Vielen Dank für Deine tatkräftige Unterstützung!
AW: 12 workbooks öffnen-drin: jeweils 11 Blätter(g
07.01.2004 16:24:16
Dieter Klemke
Hallo peristeri,
mit dem Programm von Reinhard hast du auf jeden Fall eine sehr elegante Lösung.
Ich verstehe allerdings nicht, warum der Befehl
Sheets.Add After:=wb.Sheets(wb.Sheets.Count)
nicht funktioniert.
Falls es dich noch interessiert, kannst du es mit
wb.Sheets.Add After:=wb.Sheets(wb.Sheets.Count)
versuchen, das ist noch etwas sauberer formuliert.
MfG
Dieter
Anzeige
AW: 12 workbooks öffnen-drin: jeweils 11 Blätter(g
06.01.2004 04:27:20
Reinhard

Hi Peristi,
probier mal:
Option Explicit
Sub Jahr_GS_Arbeitsmappen()
Dim Pfad As String
Dim Merker As Integer
Dim y As Integer
Dim gs As Integer
Pfad = "D:\Eigene Dateien\"
Merker = Application.SheetsInNewWorkbook
Application.SheetsInNewWorkbook = 11
For y = 1999 To 2010
Workbooks.Add
For gs = 1 To Application.SheetsInNewWorkbook
Worksheets(gs).Name = "GS" & gs 'oder auch: Worksheets(gs).Name = "GS" & Format(gs, "00")
Next gs
ActiveWorkbook.SaveAs Filename:=Pfad & y & ".xls"
ActiveWorkbook.Close
Next y
Application.SheetsInNewWorkbook = Merker
End Sub
Gruß
Reinhard

Anzeige
AW: 12 workbooks öffnen-drin: jeweils 11 Blätter(g
07.01.2004 15:51:19
peristeri
Hallo Reinhard!!!

ich habe am Bildschirm das Öffnen von 12 Mappen mit jeweils 11 Blättern mitverfolgen können und war aus dem Häuschen!

Es war für mich wie das Öffnen einer Champus-Flasche!!!

DANKE DANKE DIR!!!!!!Es läuft!!!
Danke Dir! Problem ist gelöst!!!
07.01.2004 15:58:51
peristeri
Hallo Reinhard!

ich bedanke mich nochmals mit der richtigen Ueberschrift, damit Du merkst, daß Deine Hilfe ausschlaggebend war. Ansonsten lies die letzte Nachricht auf Deinen Tipp.

....danke Dir
peristeri

300 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige