Anzeige
Archiv - Navigation
372to376
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
372to376
372to376
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Ausblenden der Arbeitsblatt-Menüleiste

Ausblenden der Arbeitsblatt-Menüleiste
02.02.2004 19:45:15
Jenny
Hallo ich habe eine Frage.
Wenn ich eine Excel Datei erstellen möchte, die
nachdem sie aufgerufen wurde ähnlich aussieht wie
eine Seite einer Powerpoint Presentation, wie
bekomme ich oben die Arbeitsblatt-Menüliste weg ?
Wenn ich über Ansicht/Symbolleiste/Anpassen da den
Haken rausmache und auf schliessen klicke ist das
ding schwub die wub wieder da (grrr...)
wäre super lieb wenn mir einer von euch einen tipp
geben kann
vielen dank
Jennifer-Victoria

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Ausblenden der Arbeitsblatt-Menüleiste
02.02.2004 19:56:54
Hajo_Zi
Hallo Jennifer-Victoria
schaue mal auf meine Homepage da ist ein Beispiel, auf der Seite Fremde Dateien.

Falls Code vorhanden wurde dieser getestet unter Betriebssystem XP Pro und Excel Version XP SBE.
Bitte keine Mail, Probleme sollten im Forum gelöst werden.
Microsoft MVP für Excel
Das Forum lebt auch von den Rückmeldungen.
Betriebssystem XP Pro und Excel Version XP Pro


AW: Ausblenden der Arbeitsblatt-Menüleiste
02.02.2004 19:59:27
GraFri
Hallo
Alles in ein Modul, speicher, schließen und neu starten.


Option Explicit
Dim Cn%
Dim CdbList()
Dim Status_FormulaBar   As Boolean
Dim Status_HorScroll    As Boolean
Dim Status_VerScroll    As Boolean
Dim Status_StatusBar    As Boolean
Dim Status_Gridlines    As Boolean
Dim Status_Headings     As Boolean

Sub Auto_Open()
Dim Cdb As CommandBar
'Wenn Titelleiste von Excel geändern werden soll
'Application.Caption = "Meine Mustervorlage"

'falls die eigenen Symbolleisten auch ausgeblendet werden sollen, dann den
'Code 'And Cdb.BuiltIn = True' aus nachstehender Zeile entfernen
Cn = 1
For Each Cdb In Application.CommandBars
    If Cdb.Visible And Cdb.Type <> msoBarTypeMenuBar And Cdb.BuiltIn = True Then
        ReDim Preserve CdbList(Cn)
        CdbList(Cn) = Cdb.Name
        Cn = Cn + 1
        Cdb.Visible = False
    End If
Next
'Stellt den Status fest und blendet alles aus
With ActiveWindow
    Status_HorScroll = .DisplayHorizontalScrollBar
    If .DisplayHorizontalScrollBar = True Then .DisplayHorizontalScrollBar = False
    Status_VerScroll = .DisplayVerticalScrollBar
    If .DisplayVerticalScrollBar = True Then .DisplayVerticalScrollBar = False
    
    Status_Gridlines = .DisplayGridlines
    If .DisplayGridlines = True Then .DisplayGridlines = False
    
    Status_Headings = .DisplayHeadings
    If .DisplayHeadings = True Then .DisplayHeadings = False
End With
With Application
    Status_StatusBar = .DisplayStatusBar
    If .DisplayStatusBar = True Then .DisplayStatusBar = False
    
    Status_FormulaBar = .DisplayFormulaBar
    If .DisplayFormulaBar = True Then .DisplayFormulaBar = False
End With
'Menüleiste
CommandBars(1).Enabled = False
End Sub

Sub Auto_Close()
Dim Cdb As CommandBar
Dim Ci%

For Ci = 1 To Cn - 1
    Application.CommandBars(CdbList(Ci)).Visible = True
Next Ci
With ActiveWindow
    .DisplayHeadings = Status_Headings
    .DisplayHorizontalScrollBar = Status_HorScroll
    .DisplayVerticalScrollBar = Status_VerScroll
    .DisplayGridlines = Status_Gridlines
End With
With Application
    .DisplayStatusBar = Status_StatusBar
    .DisplayFormulaBar = Status_FormulaBar
End With
CommandBars(1).Enabled = True
End Sub

     Code eingefügt mit Syntaxhighlighter 2.5

Mit freundlichen Grüßen, GraFri
Anzeige
AW: Ausblenden der Arbeitsblatt-Menüleiste
02.02.2004 23:57:35
Jenny
irgendwie funktioniert das nicht oder mache ich was falsch :-( (schnieeff)
wenn ich mit alt+F11 den editor öffne klicke ich auf "diese arbeitsmappe" und
kopiere den text rein, klicke auf die diskette , schliesse den editor, dann die datei und ... nix passiert...
AW: Ausblenden der Arbeitsblatt-Menüleiste
03.02.2004 01:06:24
Ulf
In ein Standardmodul gehört der Code, Herr Grafi kennt Workbook Open
vielleicht noch nicht.
Ulf
AW: Ausblenden der Arbeitsblatt-Menüleiste
03.02.2004 01:15:28
Jenny
Öhm Jungs ist ja wirklich lieb wie Ihr euch bemüht aber ich verstehe nur die hälfte von dem was ihr sagt... muss ich da jetzt erst ne programier sprache lernen bevor ich das ausstellen kann und damit ich euch verstehen kann oder geht das irgendwie auch einfach aus excel mit nem anklick verfahren ???!!!
Anzeige
AW: Ausblenden der Arbeitsblatt-Menüleiste
03.02.2004 01:22:30
Ulf
Was'n? Weißt du jetzt noch nicht wie?
Ulf
Ausblenden der Menüleisten - neue Version
03.02.2004 07:23:36
GraFri
Hallo
An Ulf: Danke für den Hinweis.
Nachstehend der Code für 'DieseArbeitsmappe'.


Option Explicit
Dim Cn%
Dim CdbList()
Dim Status_FormulaBar   As Boolean
Dim Status_HorScroll    As Boolean
Dim Status_VerScroll    As Boolean
Dim Status_StatusBar    As Boolean
Dim Status_Gridlines    As Boolean
Dim Status_Headings     As Boolean
Dim Status_WorkTabs     As Boolean

Private Sub Workbook_Open()
Dim Cdb As CommandBar
'Wenn Titelleiste von Excel geändern werden soll
'Application.Caption = "Meine Mustervorlage"
'falls die eigenen Symbolleisten auch ausgeblendet werden sollen, dann den
'Code 'And Cdb.BuiltIn = True' aus nachstehender Zeile entfernen
Cn = 1
For Each Cdb In Application.CommandBars
    If Cdb.Visible And Cdb.Type <> msoBarTypeMenuBar And Cdb.BuiltIn = True Then
        ReDim Preserve CdbList(Cn)
        CdbList(Cn) = Cdb.Name
        Cn = Cn + 1
        Cdb.Visible = False
    End If
Next
'Stellt den Status fest und blendet alles aus
With ActiveWindow
    Status_HorScroll = .DisplayHorizontalScrollBar
    If .DisplayHorizontalScrollBar = True Then .DisplayHorizontalScrollBar = False
    Status_VerScroll = .DisplayVerticalScrollBar
    If .DisplayVerticalScrollBar = True Then .DisplayVerticalScrollBar = False
    
    Status_Gridlines = .DisplayGridlines
    If .DisplayGridlines = True Then .DisplayGridlines = False
    
    Status_Headings = .DisplayHeadings
    If .DisplayHeadings = True Then .DisplayHeadings = False
    Status_WorkTabs = .DisplayWorkbookTabs
    If .DisplayWorkbookTabs = True Then .DisplayWorkbookTabs = False
End With
With Application
    Status_StatusBar = .DisplayStatusBar
    If .DisplayStatusBar = True Then .DisplayStatusBar = False
    
    Status_FormulaBar = .DisplayFormulaBar
    If .DisplayFormulaBar = True Then .DisplayFormulaBar = False
'Menüleiste
    .CommandBars(1).Enabled = False
End With

End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Dim Cdb As CommandBar
Dim Ci%

For Ci = 1 To Cn - 1
    Application.CommandBars(CdbList(Ci)).Visible = True
Next Ci
With ActiveWindow
    .DisplayHeadings = Status_Headings
    .DisplayHorizontalScrollBar = Status_HorScroll
    .DisplayVerticalScrollBar = Status_VerScroll
    .DisplayGridlines = Status_Gridlines
    .DisplayWorkbookTabs = Status_WorkTabs
End With
With Application
    .DisplayStatusBar = Status_StatusBar
    .DisplayFormulaBar = Status_FormulaBar
    
    .CommandBars(1).Enabled = True
End With
End Sub

     Code eingefügt mit Syntaxhighlighter 2.5


mfg, GraFri
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige