Frage Macro Datenimport

Hallo,
ich haette da mal eine Frage zum Thema Datenimport via Makro in excel, ist vermutlich nicht sehr schwierig, habe aber bemerkenswert wenig Ahnung, waer sehr nett, wenn mir jemand helfen koennte...
Folgendes Problem:
Von einem Messgeraet bekomme ich pro Messung zwei files: aXXXXXXXX.tab und bXXXXXXXX.tab (delimeted, semicolon separated files). Das Ausgabeverzeichnis ist fix, und die achtstellige Nummer XXXXXXXX ist fuer beide Dateien identisch. Ich wuerde nun gern per Macro einen Datenimport durchfuehren, hier liegt mein Problem. Ich haette gern, zu Begin des Makros, eine Abfrage nach der achtstelligen Nummer (XXXXXXXX). Das Makro muesste dann zunaechst einen Datenimport des files aXXXXXXXX.tab in mein excel sheet (e.g. Feld A1) durchfuehren; im Anschluss einen Datenimport des files bXXXXXXXX.tab in dasselbe excel sheet (e.g. Feld A25) durchfuehren, die Details des Datentransports sind nicht so sehr das Problem, eher das handling der Dateinahmen.
Wie Ihr seht bin ich in punkto VBA nicht sehr bewandert, ich hoffe es findet sich jemand, der mir weiterhelfen kann.
Vielen Dank im Voraus,
Steffen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Steffen!
Option Explicit

Sub frageNummer()
Dim lNum As Long
Dim strFile As String, strTemp As String, strPath As String
Dim lRow As Long
lRow = 1
strPath = "D:\Temp\"
Do
lNum = Application.InputBox("Bitte geben Sie die Nummer ein!", "Nummer", lNum, Type:=1)
If lNum = Empty Then Exit Sub
If Len(CStr(lNum)) = 8 Then Exit Do
MsgBox "Bitte überprüfen Sie die Nummer!"
Loop
strFile = strPath & "a" & lNum & ".tab"
If Not FileExist(strFile) Then _
MsgBox "Datei """ & strFile & """ nicht gefunden!": Exit Sub
'Import erste Datei
Open strFile For Input As #1
Do While Not EOF(1)
Input #1, strTemp
Cells(lRow, 1) = strTemp
lRow = lRow + 1
Loop
Close #1
strFile = strPath & "b" & lNum & ".tab"
If Not FileExist(strFile) Then _
MsgBox "Datei """ & strFile & """ nicht gefunden!": Exit Sub
'Import zweite Datei
Open strFile For Input As #1
Do While Not EOF(1)
Input #1, strTemp
Cells(lRow, 1) = strTemp
lRow = lRow + 1
Loop
Close #1
Columns("A:A").TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
Semicolon:=True, Comma:=False, Space:=False, Other:=False, FieldInfo _
:=Array(Array(1, 1))
Columns.AutoFit
End Sub

Public Function FileExist(ByVal Dateiname As String) As Boolean
On Error GoTo errorhandler
If Dateiname = "" Then GoTo errorhandler
FileExist = Dir$(Dateiname) <> ""
Exit Function
errorhandler:
FileExist = False
Resume Next
End Function
Code eingefügt mit: Excel Code Jeanie
Gruß Sepp

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Frage Macro Datenimport

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread