Suche nur in Spalte

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
InputBox MsgBox
Bild

Betrifft: Suche nur in Spalte von: Detlef Reyher
Geschrieben am: 04.03.2005 11:39:55

Hallo,


Sub SuchenE()
   Dim rng As Range, rngSource As Range, rngStart As Range
   Dim varInput As Variant
   Dim iRow As Integer
   varInput = Application.InputBox( _
      prompt:="Geben Sie bitte den Suchbegiff für Spalte E ein:", _
      Title:="Zeilen kopieren", _
      Default:="", _
      Left:=263, _
      Top:=169, _
      Type:=2)
   If varInput = False Then Exit Sub
   Set rng = ActiveSheet.Columns("E").Find( _
      what:=varInput, lookat:=xlWhole, LookIn:=xlValues)
   If rng Is Nothing Then
      Beep
      MsgBox "Suchbegriff nicht gefunden!"
      Exit Sub
   End If
   Set rngStart = rng
   Set rngSource = rng.EntireRow
   Do
      Set rng = Cells.FindNext(after:=rng)
      If rng.Address = rngStart.Address Then Exit Do
      Set rngSource = Application.Union(rngSource, rng.EntireRow)
   Loop
   With Worksheets("Tabelle2")
      iRow = .Cells(Rows.Count, 1).End(xlUp).Row
      If iRow = 1 Then iRow = 2 Else iRow = iRow + 3
      rngSource.Copy .Cells(iRow, 1)
      .Columns.AutoFit
   End With
End Sub


Der Code ist gut, nur zum Donnerwetter, warum sucht dieser Code im ganzen Blatt und nicht nur in der Spalte (E).
Ich tüftle jetzt schon eine Stunde und bekomme ich es nicht hin.
(Bin warscheinlich zu blööööd)
Kann mir einer einen Tip geben, dringend!!!!

Danke im voraus
Gruß Detlef
Bild


Betrifft: AW: Suche nur in Spalte von: Matthias G
Geschrieben am: 04.03.2005 11:43:43

Hallo Detlef,

statt
Set rng = Cells.FindNext(after:=rng)

müsste es heißen
Set rng = ActiveSheet.Columns("E").FindNext(after:=rng)

Gruß Matthias


Bild


Betrifft: AW: Suche nur in Spalte von: d
Geschrieben am: 04.03.2005 15:55:15

Hallo,

ich habe zwar schon einmal meinen Dank ausgesproche, aber jetzt ist er nicht mehr drinn.

Also nochmal es funzt.

So einfach und doch sooo schwer (für mich).

Gruß an alle Detlef


Bild


Betrifft: AW: Suche nur in Spalte von: Frederik Fuhrmann
Geschrieben am: 04.03.2005 11:43:53

HAllo!

Es muss heißen:

Set rng = ActiveSheet.Columns("E:E")....

Gruß
F.


Bild


Betrifft: AW: Suche nur in Spalte von: Detlef Reyher
Geschrieben am: 04.03.2005 15:57:06

Hallo Frederik,

die Lösung von Matthias ist i.O.

trotzdem Danke für Deine Hilfe.

Gruß Detlef


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Suche nur in Spalte"