=wenn(oder))Formel funktioniert hier nicht...

Bild

Betrifft: =wenn(oder))Formel funktioniert hier nicht... von: Peter W
Geschrieben am: 04.03.2005 19:35:25

Servus,

Muss bei Folgender Tabelle alle Nummern finden und anzeigen die in Zeile 2 stehen die in Zelle vorgegebenm Kriterium entsprechen (i44) zB. DZ.
Leider komm ich mit meiner Wenn(oder(Formel nicht wirklich weiter.

Vieleicht weiss jemand Rat, sitzt da schon ne Weile dran. Danke

Excel Jeanie HTML

Bild
Bild
  Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  



MfG

Peter
Bild


Betrifft: WVERWEIS bei mehrfach vork. Suchkriterium von: Boris
Geschrieben am: 04.03.2005 19:51:36

Hi Peter,

für die "DZ": Irgendwo diese Arrayformel - und dann runterkopieren:

{=INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A1)))}

Grüße Boris


Bild


Betrifft: AW: =wenn(oder))Formel funktioniert hier nicht... von: HermannZ
Geschrieben am: 04.03.2005 20:09:05

Hallo Peter,

Beispiel;
TestAlt
 ABCDEFG
119       
12021222324252627
121EZEZDZ3BettDZEZDZ
122       
123für DZ      
12423      
12525      
12627      
127       
128       
129       
130       
131Formel herunterkopieren      
132       
Formeln der Tabelle
A124 : {=WENN(ISTFEHLER(INDEX($120:$120;KKLEINSTE(WENN($121:$121="DZ";SPALTE($1:$1));ZEILE($A1))));"";(INDEX($120:$120;KKLEINSTE(WENN($121:$121="DZ";SPALTE($1:$1));ZEILE($A1)))))}

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  


Gruß hermann


Bild


Betrifft: AW: Sorry nicht aktuallisiert oT.. von: HermannZ
Geschrieben am: 04.03.2005 20:10:00

.


Bild


Betrifft: #ZAHL! abfangen - verkürzt von: Boris
Geschrieben am: 04.03.2005 20:14:52

Hi Hermann,

du musst nicht die ganze Formel davor schalten und auf Fehler überprüfen. Zähle einfach nur die "DZ" und vergleiche sie mit der ZEILE:

{=WENN(ZEILE($A1)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A1))))}
Grüße Boris

Bild


Betrifft: AW: #ZAHL! abfangen - verkürzt von: HermannZ
Geschrieben am: 04.03.2005 20:23:25

Hallo Boris,

Danke für den Hinweis,darauf bin ich jetzt in der schnelle garnicht gekommen.
habe einfach bein ausprobieren #ZAHL gesehen und weil ich zu faul war einfach ISTFEHLER gesetzt und kopiert.
werde das nächste mal versuchen daran zu denken.

Gruß hermann


Bild


Betrifft: Dankeschön... von: Peter W
Geschrieben am: 04.03.2005 21:15:35

... für die schnelle und mustergültige Lösung.

Wäre ich alleine nie im Leben draufgekommen, hab auch ehrlich gesagt keinerlei Ahnung was Ihr mir da gebastelt habt. Nochmals vielen Danke

MfG

Peter


Bild


Betrifft: AW: #ZAHL! abfangen - verkürzt :-) von: FP
Geschrieben am: 04.03.2005 22:24:00

Hi Boris,

warum nicht so :-)

Tabelle3
 ABCDEFGHIJKLMNOPQRSTUVWXY
121222324252627282930313233343536373851525354555657
2EZEZDZ3BettDZEZ3Bett3BettDZ3BettDZDZ3BettDZ3BettDZ3Bett3BettEZDZEZEZEZEZEZ
3                         
42323                       
52525                       
62929                       
73131                       
83232                       
93434                       
103636                       
115252                       
12                         
Formeln der Tabelle
A4 : {=WENN(ZEILE($A1)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A1))))}
B4 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A1));99)}
A5 : {=WENN(ZEILE($A2)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A2))))}
B5 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A2));99)}
A6 : {=WENN(ZEILE($A3)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A3))))}
B6 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A3));99)}
A7 : {=WENN(ZEILE($A4)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A4))))}
B7 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A4));99)}
A8 : {=WENN(ZEILE($A5)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A5))))}
B8 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A5));99)}
A9 : {=WENN(ZEILE($A6)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A6))))}
B9 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A6));99)}
A10 : {=WENN(ZEILE($A7)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A7))))}
B10 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A7));99)}
A11 : {=WENN(ZEILE($A8)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A8))))}
B11 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A8));99)}
A12 : {=WENN(ZEILE($A9)>ZÄHLENWENN($2:$2;"DZ");"";INDEX($1:$1;KKLEINSTE(WENN($2:$2="DZ";SPALTE($1:$1));ZEILE($A9))))}
B12 : {=REST(KKLEINSTE(WENN($2:$2="DZ";$1:$1;99);ZEILE(A9));99)}

Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  



Servus aus dem Salzkammergut
Franz


Bild


Betrifft: Genehmigt unter Auflagen...;-) von: Boris
Geschrieben am: 04.03.2005 22:33:48

Hi Franz,

99 steht als Platzhalter für die größte (+1) Zahl, die vorkommen kann.
Zudem funktioniert das nur für Zahlen - für Texte geht´s net.

Ansonten: Gute Idee :-)

Grüße Boris


Bild


Betrifft: Umgekehrt ist auch REST überflüssig: von: Boris
Geschrieben am: 04.03.2005 22:42:43

Hi Franz,

{=KGRÖSSTE(($2:$2="DZ")*$1:$1;ZEILE(A1))}

Grüße Boris


 Bild

Beiträge aus den Excel-Beispielen zum Thema "WENN und tatsächliches "leer" lassen"