Datensatz importieren

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
InputBox MsgBox
Bild

Betrifft: Datensatz importieren
von: Uwe
Geschrieben am: 04.03.2005 21:07:20
Guten abend ins Forum,
wiedereinmal komm ich nicht weiter und bräuchte bitte Hilfe:
ich möchte aus einer externen Datei (ausgelagerte Daten.xls) einzelne Zeilen in eine andere Arbeitsmappe(Datenerfassung.xls)einfügen. Jede Zeile wird in Spalte "B" mit einer Auftragsnummer versehen. Jetzt hätte ich es gerne so, dass
wenn ich in der Datei Datenerfassung.xls auf den Button "Datensatz zurückholen" klicke die externe Datei geöffnet wird(was auch einwandfrei funktioniert)und sich ein Fenster (so wie bei BearbeitenSuchen)öffnet wo die gesuchte Auftragsnummer eingegeben werden kann. Nun soll bei Übereinstimmung der Datensatz dieser Zeile herauskopiert und in die andere Arbeitsmappe eingefügt werden. Danach soll diese Zeile in der Datei "ausgelagerte Daten" gelöscht werden.
Kann mir dabei jemand helfen???
Vielen Dank im voraus.
Uwe

Bild

Betrifft: AW: Datensatz importieren
von: Josef Ehrensberger
Geschrieben am: 04.03.2005 23:00:24
Hallo Uwe!
Zeig mal den bisherigen Code, und beschreibe auch wo die Daten eingefügt werden sollen!

Gruß Sepp

P.S.: Rückmeldung nicht vergessen!


Bild

Betrifft: AW: Datensatz importieren
von: Uwe
Geschrieben am: 04.03.2005 23:32:08
Guten abend Sepp,
ich habe bisher folgendes in der Recherche gefunden:
Dim Zelle As Range
Dim Blatt As Worksheet
Dim str As String
str = InputBox _
("Bitte geben Sie die Auftragsnummer ein!")
If str = "" Then Exit Sub
For Each Blatt In ActiveWorkbook.Sheets
For Each Zelle In Blatt.UsedRange
If Zelle = str Then
Blatt.Activate
Zelle.Select '----- wie kann ich hier anstelle der Zelle den Zellbereich "b:ad" markieren???
Erg = MsgBox("Wollen Sie weitersuchen?", vbYesNoCancel, " Hallo " & Environ("Username"))
If Not Erg = vbYes Then Exit Sub
End If
Next Zelle
Next Blatt
MsgBox "Suchbegriff nicht gefunden!"
End Sub
Der markierte Zellbereich soll dann kopiert und in dem Workbook "Datenerfassung.xls" in Zeile 2 eingefügt werden. Danach muss der kopierte Datensatz an seinem Ursprung (Workbook "ausgelagerte Daten")durch löschen der ganzen Zeile entfernt werden.
Uwe
Bild

Betrifft: noch eine Frage!
von: Josef Ehrensberger
Geschrieben am: 04.03.2005 23:48:03
Hallo Uwe!
Noch eine Frage!
Steht die Nummer in einem bestimmten Tabellenblatt, oder kann sie in mehreren
Tabellen stehen?

Gruß Sepp
Bild

Betrifft: AW: noch eine Frage!
von: Uwe
Geschrieben am: 04.03.2005 23:51:24
Hallo Sepp,
Die Auftragsnummer steht immer in der Spalte "B" und nur in der Datei "ausgelagerte Daten.xls" und dem dazugehörigen Sheet "ausgelagerte Daten"
Gruss Uwe
Bild

Betrifft: AW: noch eine Frage!
von: Josef Ehrensberger
Geschrieben am: 05.03.2005 00:07:59
Hallo Uwe!
Probier mal.

Sub Auftragsnummer()
Dim wbDaten As Workbook
Dim wks As Worksheet, wksD As Worksheet
Dim rng As Range
Dim sFind As String
sFind = InputBox("Bitte geben Sie die Auftragsnummer ein!")
If sFind = "" Then Exit Sub
On Error GoTo ERRORHANDLER
Application.ScreenUpdating = False
'Tabelle in der die Daten eingefügt werden sollen
Set wks = ThisWorkbook.Sheets("Tabelle1") 'Tabellenname anpassen!
'Datei "ausgelagerte Daten.xls" - Pfad anpassen
Set wbDaten = Workbooks.Open("C:\Eigene Dateien\ausgelagerte Daten.xls")
'Tabelle "ausgelagerte Daten"
Set wksD = wbDaten.Sheets("ausgelagerte Daten")
'Auftragsnummer suchen
Set rng = wksD.Range("B:B").Find(What:=sFind, LookIn:=xlValues, lookat:=xlWhole)
   If Not rng Is Nothing Then
   'Bereich ("Bx:ABx") kopieren
   wksD.Range(wksD.Cells(rng.Row, 2), wksD.Cells(rng.Row, 28)).Copy wks.Cells(2, 1)
   'Zeile der Fundstelle löschen
   wksD.Rows(rng.Row).Delete
   Else
   MsgBox "Auftragsnummer nicht vorhanden!", vbInformation
   End If
'Datei "ausgelagerte Daten.xls" schliessen, änderungen speichern
wbDaten.Close True
ERRORHANDLER:
Application.ScreenUpdating = True
End Sub


Gruß Sepp
P.S.: Rückmeldung nicht vergessen!


Bild

Betrifft: AW: Wahnsinn
von: Uwe
Geschrieben am: 05.03.2005 00:18:04
Hallo Sepp,
ganz genau so hab ich es mir vorgestellt.
Vielen vielen Dank!!!!!
Ich bin echt platt.
Uwe
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Datensatz importieren"