Datumsformat wird beim Import nicht richtig gesetz

Bild

Betrifft: Datumsformat wird beim Import nicht richtig gesetz
von: SamGambschie
Geschrieben am: 15.03.2005 09:49:15
Hallo allerseits,
ich habe das Problem, das beim Import einer Text-Datei das Datumsformat für die Monate März, Mai, Oktober und Dezember nicht korrekt gesetzt werden.
Die Datei wird mittels eines VBA-Scripts eingelesen und dann formatiert. (script hierzu siehe unten).
Die einzulesende Datei wurde vorher durch Macros generiert.
Ich hab schon alles mögliche ausprobiert, komme aber auf keinen grünen Zweig.
Vermutlich ist es irgendeine Kleinigkeit, die ich übersehen habe ... aber wie war das mit dem Wald und den Bäumen? So ähnlich geht es mir.
Über einen entsprechenden Tip würde ich mich freuen.
Gruß
SamGambschie
************************
Anhänge:
Bsp. für eine einzulesende Datei: (1.Zeile enthält die Spaltenüberschriften)
ALIAS#USER-ID#LAST LOGON#LAST MODIFY#STATUS
Mustermann1#150,2#1MÄR05,5:00#15JAN99#THAWED
Mustermann2#150,2#14OKT05,6:36#29MÄR99#THAWED
Mustermann3#150,2#14MAI05,7:29#29MÄR99#THAWED
Mustermann4#150,20#13DEZ05,16:00#24NOV03#THAWED
Mustermann5#150,20#8JUN05,12:04#28JAN99#THAWED
Mustermann6#212,18#5JAN05,7:35#22OKT04#THAWED
Mustermann7#216,12#31AUG05,12:39#7DEZ04#THAWED
*************
Script(e):


Sub Aliasliste_erstellen()
    ChDir "x:\Auswertungen"
    Workbooks.OpenText Filename:= _
        "x:\Auswertungen\Aliaslist_ADS01.txt", Origin:=xlWindows, _
        StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
        ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=False, Comma:=False _
        , Space:=False, Other:=True, OtherChar:="#", FieldInfo:=Array(Array(1, 1 _
        ), Array(2, 2), Array(3, 2), Array(4, 1), Array(5, 1))
    Application.Run "PERSONL.XLS!Datum_Engl_Deutsch_Aliasliste"
 
End Sub


Sub Datum_Engl_Deutsch_Aliasliste()
    Columns("D:E").Select
        Selection.Cut Destination:=Columns("E:F")
    Range("C1:C500").Select
    Selection.TextToColumns Destination:=Range("C1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=True, Space:=False, Other:=False, FieldInfo _
        :=Array(Array(1, 4), Array(2, 1))
    Range("C1:D1").Select
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .ShrinkToFit = False
        .MergeCells = False
    End With
    Selection.Merge
    Range("A1:F1").Select
    Selection.AutoFilter
End Sub

Bild

Betrifft: AW: Datumsformat wird beim Import nicht richtig gesetz
von: bst
Geschrieben am: 15.03.2005 10:15:38
Morgen SamGambschie,
versuch mal nach dem OpenText sowas.
HTH, Bernd
--
With Intersect(Columns(4), ActiveSheet.UsedRange)
.Replace "MÄR", "MAR"
.Replace "MAI", "MAY"
.Replace "OKT", "OCT"
.Replace "DEZ", "DEC"
.NumberFormatLocal = "TT.MM.JJJJ"
End With
Bild

Betrifft: AW: Datumsformat wird beim Import nicht richtig ge
von: SamGambschie
Geschrieben am: 15.03.2005 10:59:06
Hallo Bernd,
bei der Generierung des Text-Files hab ich die Formatierung in die andere Richtung ( also engl. in deutsch) drin, da die ursprünglichen Daten mit dem engl. Datumsformat vorliegen.
In einer der ersten Versuche hatte ich diese Umformatierung noch nicht drin und da ging es auch nicht.
Gruß
SamGambschie
Bild

Betrifft: AW: Datumsformat wird beim Import nicht richtig ge
von: bst
Geschrieben am: 15.03.2005 13:13:51
Mahlzeit SamGambschie,
bei mir mit xl2000 hat das funktioniert.
Was tut denn bei Dir dabei nicht ?
Wenn Du die Text-Dateien selbst - via VBA ? - erzeugst ist mir Dein Problem nun ganz und gar nicht mehr klar. Lese sie doch genauso ein wie Du schreibst. Dabei sollte es doch
zu keinen 'länderspezifischen' Problemen kommen können ??
cu, Bernd
Bild

Betrifft: AW: Datumsformat wird beim Import nicht richtig ge
von: SamGambschie
Geschrieben am: 15.03.2005 15:36:38
Hallo Bernd,
Ich hab mal nen Screenshot vom Ergebnis gemacht, wenn ich das VBA-Macro ausführe:
Userbild

Das Text-File wird im übrigen nicht mit VBA erzeugt.
Dafür hab ich spezielle Software, die ich selbst geschrieben hab.
Das Ausgabeformat für die Datei ist das ASCII-Format. Aber an der Text-Datei kann es eigentlich nicht liegen, da ich diese schon auf Herz und Nieren (Ich meine damit evtl. Steuerzeichen u.ä.) geprüft habe.
Gruß
SamGambschie
Bild

Betrifft: AW: Datumsformat wird beim Import nicht richtig ge
von: bst
Geschrieben am: 15.03.2005 21:20:24
Abend nochmal,
Du siehst mich überrascht. Deine 2. Datumsspalte hätte IMHO richtig sein müssen.
Um die 1. hatte ich mich nicht gekümmert.
Versuch mal dieses. Funktioniert bei mir mit xl2000.
cu, Bernd
--
Option Explicit
Const myFileName = "D:\daten\demo.txt"

Sub Aliasliste_erstellen()
   Workbooks.OpenText Filename:=myFileName, Origin:=xlWindows, _
      StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
      ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=False, Comma:=False, _
      Space:=False, Other:=True, OtherChar:="#"
   Columns(4).Insert
   Columns(3).TextToColumns Destination:=Range("C1"), DataType:=xlDelimited, _
      TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
      Semicolon:=False, Comma:=True, Space:=False, Other:=False
      
    With Intersect(Range("C:C,E:E"), ActiveSheet.UsedRange)
      .Replace "MÄR", "MAR"
      .Replace "MAI", "MAY"
      .Replace "OKT", "OCT"
      .Replace "DEZ", "DEC"
      .NumberFormatLocal = "TT.MM.JJJJ"
   End With
   Columns.AutoFit
End Sub

Bild

Betrifft: AW: Datumsformat wird beim Import nicht richtig ge
von: samgambschie
Geschrieben am: 16.03.2005 11:31:35
Hallo Bernd,
super, so funktionierts - vielen Dank.
Gruß
SamGambschie
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Datumsformat wird beim Import nicht richtig gesetz"