Leere Zeilen im Excel löschen

Bild

Betrifft: Leere Zeilen im Excel löschen von: Weng
Geschrieben am: 05.04.2005 15:12:41

Hallo!

Weiß jemand von euch wie man im Excel leere Zeilen mit einem Makro automatisch rauslöschen kann?

Gruß!

Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: Tobias Marx
Geschrieben am: 05.04.2005 15:21:02

Servus!

Sub Zellen_loeschen()
  ActiveSheet.UsedRange.SpecialCells(xlCellTypeBlanks).Select
  Selection.Delete Shift:=xlUp
End Sub

Gruss

Tobias


Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: Hajo_Zi
Geschrieben am: 05.04.2005 15:27:12

Hallo Tobias,

mal ohne Select


Sub Zellen_loeschen()
  ActiveSheet.UsedRange.SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
End Sub



es werden aber nicht leere Zeilen gelöscht sondern Zellen.


Bitte keine Mail, Probleme sollten im Forum gelöst werden.
Microsoft MVP für Excel
Das Forum lebt auch von den Rückmeldungen.
Betriebssystem XP Home SP2 und Excel Version 2003 SP1.




Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: Tobias Marx
Geschrieben am: 05.04.2005 15:29:26

Servus Hajo,

Hast mich mal wieder beim "Selecten" ertappt... aber dieses Mal isses ein Programmierbeispiel vom Chef Hans Herber, habs nur so von einer seiner Grafiken abgetippt :) Und er hat auch "selected" -g-

Gruss

Tobias


Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: Weng
Geschrieben am: 05.04.2005 15:29:13

Hallo,
1. mal danke für die schnelle antwort,
aber damit ist mir noch nicht geholfen.
Kurz noch mal die Beschreibung:
Ich hab n Excel Blatt, und da steht in manchen Zeilen was und in manchen nichts,d.h. ich will die Zeilen löschen wo kein wert drin steht,
ich hab mir des ungefähr so vorgestellt, funktioniert aber nicht so ganz:

Dim m As Integer
Dim z As Integer
Dim c As Integer
Dim q As Integer
q = 2
c = 3
z = 200

For m = 1 To z

Cells(q, c).Activate

If Selection.Value = "" Then
Rows(q & ":" & q).Select
Selection.Delete Shift:=xlUp
q = q + 1

Else
q = q + 1
End If
Next m
Cells(1, 1).Activate


Hat da einer von euch eine Lösung?
THX

Chris


Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: Hajo_Zi
Geschrieben am: 05.04.2005 15:34:02

Hallo Chris,

Option Explicit


Sub Leerzeilenlöschen()
'   Leerzeilen löschen einschließlich der Zeilen die entstehen wenn Zeilen am ende
'   gelöscht werden, auch Leerzeilen in der Tabelle werden gelöscht
'   von Wolf.W.Radzinski
'   es wurden nicht alle Leerzeilen in einer Datei erkannt
'   darum Ergänzung
    On Error Resume Next
    Dim r As Range
    Dim anz As Long
    Dim c_ges As Long
    Dim col As New Collection
    c_ges = ActiveSheet.UsedRange.Column + ActiveSheet.UsedRange.Columns.Count - 1
    For Each r In ActiveSheet.UsedRange.EntireRow
        anz = 0
'       ******** Hajo.Ziplies@web.de
        Dim I As Byte
        Dim L As Byte
        L = 0
        For I = 1 To 20
            If Cells(r.Row, I) <> "" Then
                L = 1
                Exit For
            End If
        Next I
        If L = 0 Then col.Add r
'       ******
'        anz = r.SpecialCells(xlCellTypeBlanks).Count
'        If anz >= c_ges Then col.Add r
    Next
    For Each r In col
        r.Delete
    Next
End Sub

Gruß Hajo

Das Forum lebt auch von den Rückmeldungen.


Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: Weng
Geschrieben am: 05.04.2005 15:37:40

Juhu,:-)

es funktioniert, hab so lange schon daran rumprobiert.

Vielen Dank ;-)

Gruß Chris


Bild


Betrifft: AW: Warum... von: FP
Geschrieben am: 05.04.2005 22:16:25

Hallo Hajo,

... ist eine Zeile wenn die Spalten 1 bis 20 leer sind eine Leerzeile???

Was ist wenn erst in Spalte 21 ein Wert steht? ;-)

Servus aus dem Salzkammergut
Franz


Bild


Betrifft: AW: Warum... von: Hajo_Zi
Geschrieben am: 06.04.2005 06:13:59

Hallo FRanz,

im Forum geben wir Ansätze. An die Bedingungen anpassen müß der Anwender. Ansonsten würde es ja Auftragsprogrammierung lauten und nicht Forum. Ich habe hier noch keine Stelle gefunden wo es Geld gibt!

Gruß Hajo

Das Forum lebt auch von den Rückmeldungen.


Bild


Betrifft: OT scheint nicht so von: th.heinrich
Geschrieben am: 05.04.2005 15:44:08

https://www.herber.de/forum/archiv/592to596/t593113.htm#593231


Bild


Betrifft: AW: Leere Zeilen im Excel löschen von: WolleKa
Geschrieben am: 05.04.2005 16:50:43

Hallo Weng,
die Zeilen müssen nicht immer gleich gelöscht werden. Zum Ausdruck reicht auch verstecken.
Hierzu mein Makro: (Für Puristen vielleicht ein Bisschen zuviel "Select")


'

Sub Zeile_Verbergen()
'
' Zeile_Verbergen Makro
' Makro am 03.09.04 von Karius aufgezeichnet
Sheets("Tab").Activate
ActiveSheet.Protect DrawingObjects:=False, Contents:=False, Scenarios:=False
Sheets("Tab").Select
For x = 5 To 800
    Range("G" & x).Select
    zellinhalt = ActiveCell.Text
        If zellinhalt = "0" Then
            Selection.EntireRow.Hidden = True
        End If
Next
'
ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
Range("A4").Select
End Sub

'

Sub Zeilen_Öffnen()
'
    Sheets("Tab").Select
    ActiveSheet.Protect DrawingObjects:=False, Contents:=False, Scenarios:=False
    Rows("5:800").Select
    Rows("5:800").EntireRow.AutoFit
    Range("A4").Select
    'ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
    'Worksheets("Eingabe").Activate
    'Range("E8").Select
End Sub


Gruß
WolleKa


Bild


Betrifft: AW: schneller kann ich's nicht... von: FP
Geschrieben am: 05.04.2005 22:05:24

Hallo Weng,


Sub DelEmptyRows()
  Dim s       As Integer
  Dim z9      As Long
  Dim z1      As Long
  Dim Appl    As Application
  Set Appl = Application
  Appl.ScreenUpdating = False
  Appl.Calculation = xlCalculationManual
  With ActiveSheet.UsedRange
    s = .Columns.Count
    For z9 = .Rows.Count To 1 Step -1
      z1 = z9
      While Appl.CountBlank(.Rows(z9)) = s
        z9 = z9 - 1
      Wend
      If z1 > z9 Then
        Range(.Rows(z1).Row & ":" & .Rows(z9 + 1).Row).Delete
        z9 = z9 + 1
      End If
    Next
  End With
  Appl.Calculation = xlCalculationAutomatic
  Appl.ScreenUpdating = True
End Sub


Servus aus dem Salzkammergut
Franz


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Leere Zeilen im Excel löschen"