Anwendung bereits geöffnet?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hi Boris,
also gut, dann die Kindergartentaugliche Version:

Option Explicit
Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
Private Declare Function GetWindowText Lib "user32.dll" Alias "GetWindowTextA" ( _
    ByVal hWnd As Long, _
    ByVal lpString As String, _
    ByVal cch As Long) As Long
Private Declare Function GetClassName Lib "user32.dll" Alias "GetClassNameA" ( _
    ByVal hWnd As Long, _
    ByVal lpClassName As String, _
    ByVal nMaxCount As Long) As Long
Private Declare Function GetWindow Lib "user32.dll" ( _
    ByVal hWnd As Long, _
    ByVal wCmd As Long) As Long
Private Declare Function GetWindowLong Lib "user32.dll" Alias "GetWindowLongA" ( _
    ByVal hWnd As Long, _
    ByVal nIndex As Long) As Long
Private Declare Function GetWindowTextLength Lib "user32.dll" Alias "GetWindowTextLengthA" ( _
    ByVal hWnd As Long) As Long
Private Declare Function SetWindowPos Lib "user32.dll" ( _
     ByVal hWnd As Long, _
     ByVal hWndInsertAfter As Long, _
     ByVal x As Long, _
     ByVal y As Long, _
     ByVal cx As Long, _
     ByVal cy As Long, _
     ByVal wFlags As Long) As Long
Private Const HWND_TOPMOST = -1
Private Const HWND_NOTOPMOST = -2
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_SHOWWINDOW = &H40
Private Const GW_HWNDFIRST = 0
Private Const GW_HWNDNEXT = 2
Private Const GWL_STYLE = -16
Private Const WS_VISIBLE = &H10000000
Private Const WS_BORDER = &H800000
Private Const MAX_COUNT = 256
Private Const gcClassnameMSIExplorer = "IEFrame"
Public Sub prcForumssearch()
    Const strSearch = "herbers"
    Dim lnghWnd As Long, lngStyle As Long, lngReturn As Long
    Dim strClassName As String, strTitle As String
    strClassName = Space$(MAX_COUNT)
    lnghWnd = GetWindow(FindWindow(vbNullString, vbNullString), GW_HWNDFIRST)
    Do
        lngStyle = GetWindowLong(lnghWnd, GWL_STYLE) And (WS_VISIBLE Or WS_BORDER)
        If lngStyle = (WS_VISIBLE Or WS_BORDER) Then
            lngReturn = GetClassName(lnghWnd, strClassName, MAX_COUNT)
            If Left$(strClassName, lngReturn) = gcClassnameMSIExplorer Then
                strTitle = LCase$(Trim$(GetWindowTitle(lnghWnd)))
                If InStr(1, strTitle, strSearch) <> 0 Then
                    SetWindowPos lnghWnd, HWND_TOPMOST, 0, 0, 0, 0, _
                        SWP_NOSIZE Or SWP_NOMOVE Or SWP_NOACTIVATE Or SWP_SHOWWINDOW
                    SetWindowPos lnghWnd, HWND_NOTOPMOST, 0, 0, 0, 0, _
                        SWP_NOSIZE Or SWP_NOMOVE Or SWP_NOACTIVATE Or SWP_SHOWWINDOW
                Else

'                    hier kommt dein Code zum öffnen der Site
'                    ein bsschen darfst du auch noch dran basteln
                End If
            End If
        End If
        lnghWnd = GetWindow(lnghWnd, GW_HWNDNEXT)
    Loop Until lnghWnd = 0
End Sub
Private Function GetWindowTitle(ByVal lnghWnd As Long) As String
    Dim lngReturn As Long, strTemp As String
    lngReturn = GetWindowTextLength(lnghWnd) + 1
    strTemp = Space$(lngReturn)
    GetWindowText lnghWnd, strTemp, lngReturn
    GetWindowTitle = Left$(strTemp, Len(strTemp) - 1)
End Function

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Anwendung bereits geöffnet?

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread