Variable an UserForm übergeben

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Sub Worksheet_BeforeDoubleClick(ByVal target As Range, Cancel As Boolean) Dim x As Integer newtarget = target.Row If target.Row > 16 And target.Row < 382 Then If target.Column > 1 And target.Column < 17 Then Info.Show Else x = MsgBox("Dieses Feld ist gesperrt!", vbOKOnly) End If Else x = MsgBox("Dieses Feld ist gesperrt!", vbOKOnly) End If Range("A1").Select End Sub

Hi,
versuch es mal so:

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Row > 16 And Target.Row < 382 And Target.Column > 1 _
        And Target.Column < 17 Then
        With UserForm1
            .Tag = Cells(Target.Row, 1).Text
            .Show
        End With
    Else
        MsgBox "Dieses Feld ist gesperrt!"
    End If
    Range("A1").Select
End Sub

' **********************************************************************
' Modul: UserForm1 Typ: Userform
' **********************************************************************

Option Explicit

Private Sub UserForm_Activate()
    TextBox1.Value = Me.Tag
End Sub

Gruß
Nepumuk

Hi,
wenn du es gerne ein bisschen komplizierter hast :-), kannst du das auch über eine Klasse lösen:

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private objClass As clsArray

Public Sub prcTest()
    Dim intArray(1 To 10) As Integer
    intArray(1) = 666
    Set objClass = New clsArray
    objClass.prpArray = intArray
    UserForm1.Show
    Set objClass = Nothing
End Sub

Public Function fncClass() As Object
    Set fncClass = objClass
End Function

' **********************************************************************
' Modul: clsArray Typ: Klassenmodul
' **********************************************************************

Option Explicit

Private vntVariable As Variant

Public Property Get prpArray() As Variant
    prpArray = vntVariable
End Property

Public Property Let prpArray(ByVal vntValue As Variant)
    vntVariable = vntValue
End Property

' **********************************************************************
' Modul: UserForm1 Typ: Userform
' **********************************************************************

Option Explicit

Private Sub CommandButton1_Click()
    Dim objArray As Object
    Dim vntArray As Variant
    Set objArray = fncClass
    vntArray = objArray.prpArray
    MsgBox vntArray(1)
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

12 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Variable an UserForm übergeben

12 Beiträge zum Forumthread Beiträge zu diesem Forumthread

12 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread