Arbeitsmappe regelmäßig aktualisieren

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Markus,
OnTime ist schon der richtige Weg. Du muss "nur" die OnTime-Aktion am Ende des ausgeführten Makros erneut ausführen.
Zusätzlich muss du unter DieseArbeitsmappe in der Workbook_BeforeClose-Prozedur die OnTime-Aktion wieder zurücksetzen, um die letzten Aufruf ggf. zu löschen.
Gruß
Franz


'###### Modul Bespielcode für OnTime-Mehrfachausführung #####
'Prozedur "Aktion_OnTime_Aus" muss auch von der Workbook_BeforeClose-Prozedur aufgerufen werden! _
Private wbThis As Workbook, NextOnTime As Date
Private Const strInterval As String = "00:05:00" 'Zeitinterval für OnTime = 5 Minuten
Private Const strProzedur As String = "Aktion_OnTime" 'Prozedurname für OnTime-Aktion
Sub Schaltfläche1_BeiKlick()
Call Aktion_OnTime_Ein
End Sub
Sub Aktion_OnTime_Ein()
'Prozedur zur Aktualisierung starten
Set wbThis = ThisWorkbook
NextOnTime = Now + CDate(strInterval)
Application.OnTime earliesttime:=NextOnTime, Procedure:=strProzedur
End Sub
Sub Aktion_OnTime()
'Arbeitsmappe und Tabelle aktivieren in der OnTime-Aktionen ausgeführt werden soll
wbThis.Activate
wbThis.Worksheets("Tab1").Activate
'Code der in der Tabelle ausgeführt werden soll
MsgBox "OnTime-Aktion wurde gestartet" 'Testzeile
'Prozedur per OnTime neu starten
NextOnTime = Now + CDate(strInterval)
Application.OnTime earliesttime:=NextOnTime, Procedure:=strProzedur
End Sub
Sub Aktion_OnTime_Aus()
'Letzte OnTime-Aktion ggf. löschen
On Error Resume Next
Application.OnTime earliesttime:=NextOnTime, Procedure:=strProzedur, Schedule:=False
Set wbThis = Nothing
End Sub
'Code unter DieseArbeitsmappe
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Call Aktion_OnTime_Aus
End Sub

Hallo Markus,
die Zeile
wbThis.Activate
sollte ok sein, dieser Variablen wird in der Prozedur "Aktion_OnTime_Ein" das Objekt zugewiesen
wbThis.Worksheets("Tab1").Activate
In dieser Zeile muss du den Namen der Tabelle entsprechend deiner Arbeitsmappe anpassen.
Bei mir hat das ganze funktioniert unter Excel97 auch bei mehren geöffneten Arbeitsmappen.
Probleme könnte es geben, wenn du parallel am VBA-Code von Dateien herumbastelst. Dann wird ggf. das VBA-Projekt zurückgesetzt und damit auch alle Variablen geleert. In diesem Fall nach dem Fehler VBA-Prozedur beenden und Timer neu starten.
Evtl hilft, um den Fehler zu vermeiden auch folgende Ergänzung im Code:


If wbThis is Nothing then
set wbThis = Workbooks("NamederDatei.xls")
End If
wbThis.Activate
wbThis.Worksheets("Tab1").Activate

Gruß
Franz

Beliebteste Forumthreads (12 Monate)

Arbeitsmappe regelmäßig aktualisieren

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Arbeitsmappe regelmäßig aktualisieren

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread