Pivot wählen und formatieren - nah dran!

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Andreas,
ich habe mal kurz über den Code drübergeschaut und dazu folgende Tips :

Eine PivotTabelle kann nicht über ihren PivotCacheIndex eindeutig identifiziert werden, da es auch vorkommen kann, dass mehrere PIVOT-Tabelle den gleichen Datenbestand als Datenquelle verwenden und daher den gleichen CacheIndex haben.
Also : z.B. 5 PIVOT-Tabelen teilen sich 2 CacheIndizes
siehe auch hier : http://spotlight-wissen.de/lisp/pages/messages/amse-1155038998-32546
Definiere die Variable i als STRING, dann kannst Du den Namen der PIVOT-Tabelle der angeklickten Zelle auslesen :
i = PivotIdent.PivotTable.Name (anstatt : i = PivotIdent.PivotTable.CacheIndex)
Da dieser auf jedem Tabellenblatt eindeutig ist, kannst Du damit die PIVOT-Tabelle eindeutig referenzieren. Dazu musst Du noch nicht mal den Code ändern, da anstelle des Index einer Pivot-Tabelle auch der Name als Argument verwendet werden kann !

Für weitere Anregungen fehlt mir jetzt die Zeit, da ich jetzt auch Feierabend habe
Gruß, NoNet

Hallo Andreas,
hier mal mein Vba-Code dazu:


Sub Pivot_Formatieren()
Dim PivotIdent As Range
Dim AnzahlPivot As Long
Dim pvField As PivotField, strFmt As String, varInp, Nullvalues As Variant
Dim pvTable As PivotTable
AnzahlPivot = ActiveSheet.PivotTables.Count
''MsgBox AnzahlPivot
Select Case AnzahlPivot
Case 0
Exit Sub
Case 1
Set pvTable = ActiveSheet.PivotTables(1)
Case Else   ' mehr als 1 Pibottabelle
On Error Resume Next
Set PivotIdent = Application.InputBox("Es sind mehr als 1 Pivot Tabelle vorhanden, " &  _
_
"bitte auf die zu formatierende clicken:" & vbLf & _
"Abbrechen verläßt den Formatierungsvorgang.", "Pivot Identifikation",  _
Type:=8)
On Error GoTo 0
If PivotIdent Is Nothing Then
Exit Sub
Else
On Error Resume Next
Set pvTable = PivotIdent.PivotTable
On Error GoTo 0
If pvTable Is Nothing Then
MsgBox "Ihre Auswahl liegt nicht in einer Pivottabelle", 16, "Makroende"
Set PivotIdent = Nothing
Exit Sub
End If
End If
End Select
MsgBox pvTable.Name
varInp = Application.InputBox("Bitte Dezimalstellen eingeben:" & vbLf _
& "Abbrechen verläßt die Pivot Formatierung.", "Dezimalstellen", 2, Type:=1)
If VarType(varInp) = vbBoolean Then Exit Sub
'# # # Nullwerteeinstellung_START
Nullvalues = MsgBox("Sollen Nullwerte angezeigt werden?", vbYesNo, "Nullwerte")
If Nullvalues = vbYes Then
ActiveWindow.DisplayZeros = True
ElseIf Nullvalues = vbNo Then
ActiveWindow.DisplayZeros = False
End If
'# # # Nullwerteeinstellung_ENDE
If varInp = 0 Then
strFmt = "#,##0_ ;[Red]-#,##0 "
Else
strFmt = "#,##0." & String(varInp, "0") & "_ ; [RED]-#,##0." & String(varInp, "0")
End If
For Each pvField In pvTable.DataFields
pvField.NumberFormat = strFmt
pvField.Function = xlSum
Next
Set pvField = Nothing
Set PivotIdent = Nothing
Set pvTable = Nothing
End Sub

Gruß von Luschi
aus klein-Paris

Beliebteste Forumthreads (12 Monate)

Pivot wählen und formatieren - nah dran!

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Pivot wählen und formatieren - nah dran!

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread