Microsoft Excel

Excel und VBA: Formeln, Programmierung, Lösungen

Die Excel/VBA-Beispiele

VBA-Begriff: AddIn-Objekt

Stellt ein einzelnes installiertes oder nicht installiertes Add-In dar. Das AddIn-Objekt ist ein Element der AddIns-Auflistung. Die AddIns-Auflistung enthält eine Liste aller installierten und nicht installierten Add-Ins, die in Microsoft Excel zur Verfügung stehen. Diese Liste entspricht der Add-In-Liste im Dialogfeld Add-Ins (Menü Extras).

Verwenden des AddIn-Objekts

Verwenden Sie AddIns(Index), um ein einzelnes AddIn-Objekt zurückzugeben. Dabei ist Index der Add-In-Titel oder eine Indexzahl. Mit dem folgenden Beispiel wird das Add-In "Analyse-Funktionen" installiert.

AddIns("analysis toolpak").Installed = True

Der Add-In-Titel, der im Dialogfeld Add-Ins angezeigt wird, ist nicht mit dem Add-In-Namen (dem Dateinamen des Add-Ins) zu verwechseln. Die Schreibweise des Add-In-Titels, nicht jedoch die Groß-/Kleinschreibung, muss mit der im Dialogfeld Add-Ins übereinstimmen.

Die Indexzahl stellt die Position des Add-Ins im Feld Verfügbare Add-Ins im Dialogfeld Add-Ins dar. Mit dem folgenden Beispiel wird eine Liste erstellt, die die angegebenen Eigenschaften der verfügbaren Add-Ins enthält.

With Worksheets("sheet1")
    .Rows(1).Font.Bold = True
    .Range("a1:d1").Value = _
        Array("Name", "Full Name", "Title", "Installed")
    For i = 1 To AddIns.Count
        .Cells(i + 1, 1) = AddIns(i).Name
        .Cells(i + 1, 2) = AddIns(i).FullName
        .Cells(i + 1, 3) = AddIns(i).Title
        .Cells(i + 1, 4) = AddIns(i).Installed
    Next
    .Range("a1").CurrentRegion.Columns.AutoFit
End With

Anmerkungen

Die Add-Methode fügt der Liste verfügbarer Add-Ins ein Add-In hinzu, installiert es jedoch nicht. Setzen Sie die Installed-Eigenschaft des Add-In auf True, um das Add-In zu installieren. Wenn Sie ein Add-In installieren möchten, das nicht in der Liste verfügbarer Add-Ins erscheint, müssen Sie zuerst die Add-Methode verwenden und anschließend die Installed-Eigenschaft setzen. Dies ist in einem einzigen Arbeitsschritt möglich, wie im folgenden Beispiel gezeigt wird (Sie müssen bei der Add-Methode den Namen des Add-Ins verwenden und nicht den Titel).

AddIns.Add("generic.xll").Installed = True

Verwenden Sie Workbooks(Index), um einen Bezug auf die Arbeitsmappe zurückzugeben, die einem geladenen Add-In entspricht. Dabei ist Index der Dateiname des Add-Ins (nicht der Titel). Sie müssen den Dateinamen verwenden, da geladene Add-Ins normalerweise nicht in der Workbooks-Auflistung erscheinen. Im folgenden Beispiel wird der Variablen wb die Arbeitsmappe MYADDIN.XLA zugewiesen.

Set wb = Workbooks("myaddin.xla")

Im folgenden Beispiel wird der Variable wb die Arbeitsmappe des Add-Ins "Analyse-Funktionen" zugewiesen.

Set wb = Workbooks(AddIns("analysis toolpak").Name)

Wenn die Installed-Eigenschaft True zurückgibt, das Aufrufen von Add-In-Funktionen jedoch nicht funktioniert, wurde das Add-In möglicherweise nicht richtig geladen. Der Grund dafür ist, dass das AddIn-Objekt zwar Informationen über das Vorhandensein und den Installationsstatus des Add-Ins liefert, nicht aber über den tatsächlichen Inhalt der Arbeitsmappe des Add-Ins. Um sicherzustellen, dass ein installiertes Add-In auch geladen wurde, sollten Sie die Arbeitsmappe des Add-Ins öffnen. Im folgenden Beispiel wird die Arbeitsmappe des Add-Ins "My Addin" geöffnet, falls das Add-In nicht bereits in der Workbooks-Auflistung vorhanden ist.

On Error Resume Next    ' turn off error checking
Set wbMyAddin = Workbooks(Addins("My Addin").Name)
lastError = Err
On Error Goto 0         ' restore error checking
If lastError <> 0 Then
    ' the add-in workbook isn't currently open. Manually open it.
    Set wbMyAddin = Workbooks.Open(Addins("My Addin").FullName)
End If