Beiträge zum Thread: addieren spalte B wenn spalte A eindeutig ist

Moin Alex, :-)

... sind doch auch gleich? ;-)

=SUMME(EINDEUTIG(B1:B6))

Servus
Case

Moin Alex, :-)

... von mir: ;-)
So ist es richtig (da ja Spalte A mit reinspielt):

=SUMME(INDEX(EINDEUTIG(A1:B6);0;2))

Servus
Case

Hallo Case,

Danke dein zweiter Beitrag war genau meine gesuchte Lösung. - jetzt muss ich die nur noch verstehen :-)

Vielen Dank!

Moin Alex, :-)

... EINDEUTIG(A1:B6) enthält den Bereich der eindeutigen Werte. Index hat ja diese Syntax: ;-)
INDEX(Matrix;Zeile;[Spalte])

Also nehme ich hier die 2 Spalte des eindeutigen Bereiches von A1:B6 und summiere ihn. ;-)

https://support.microsoft.com/de-de/office/eindeutig-funktion-c5ab87fd-30a3-4ce9-9d1a-40204fb85e1e
https://support.microsoft.com/de-de/office/index-funktion-a5dcf0dd-996d-40a4-a822-b56b061328bd

Servus
Case

Moin Alex, :-)

... Excelversionen >=2024 wird es "lesbarer": ;-)

=SUMME(SPALTENWAHL(EINDEUTIG(A1:B6);2))

Servus
Case

Hallo Nochmal,

leider habe ich bei meinem ursprünglichen Thread unterschlagen, dass die Spalten nicht direkt nebeneinander liegen. deshalb funktioniert der Ansatz von Case in meiner meinem Original nicht, da offensichtlich die gesamte Zeile für die Prüfung auf Eindeutigkeit herangezogen wird.

In meinem Fall darf aber nur die Spale A für die Eingeigkeit betrachtet werden und die Summe soll aus Spalte E (in der neuen Datei) erfolgen.

Sorry für meine schlechte Beschreibung und die falschen Beispieldaten

hier nochmal ein Link https://www.herber.de/bbs/user/180790.xlsx

Veile Dank
Alex

Moin Alex, :-)

... z. B. so: ;-)

=SUMME(INDEX(EINDEUTIG(WAHL({1.2};A1:A6;E1:E6));0;2))

Servus
Case

Und noch was, auch für ältere Excelversionen:

=SUMME(E1:E6/ZÄHLENWENNS(A1:A6;A1:A6))

Gruß Daniel

Hi

=SUMME(SPALTENWAHL(EINDEUTIG(HSTAPELN(A1:A6;E1:E6));2))

Oder ein anderer Ansatz:

=SUMME(XVERWEIS(EINDEUTIG(A1:A6);A1:A6;E1:E6;0))

Gruß Daniel

Hallo ihr zwei,

wow, vier(!) Lösungen - Ihr habt mir den Tag gerettet.

Letztlich habe ich die folgende Version genommen, einfach weil ich die am besten Verstanden habe :-)

=SUMME(SPALTENWAHL(EINDEUTIG(HSTAPELN(A29:A40;E29:E40));2))

Nochmal vielen Dank euch zwei
Alex

Hallo Alex,

das freut uns sehr zu hören! Auch wenn das eine etwas „exotische“ Kombination aus HSTAPELN, EINDEUTIG und SPALTENWAHL ist (ein wirklich moderner Ansatz mit den neuen dynamischen Array-Funktionen!), ist das Wichtigste: Es funktioniert und du verstehst, was da passiert.

Ein kleiner Tipp für die Zukunft, falls du das Konstrukt mal anpassen musst:
Die Funktion HSTAPELN (HSTACK) ist super mächtig, um https://1gocasinos.de/ Daten aus verschiedenen Ecken zusammenzuführen. Wenn du dich mit diesen Funktionen erst einmal wohlfühlst, ist das der schnellste Weg, um Excel-Listen zu analysieren, für die man früher ellenlange und komplizierte Matrixformeln gebraucht hätte.

Schön, dass wir dir den Tag retten konnten. Beste Grüße ins (hoffentlich bald verlassene) Krankenhaus – erhol dich gut!

Bis zum nächsten Excel-Problem!