Beiträge zum Thread: Letzten wert aus mehreren spalten wiedergeben

Moin Uwe!
Du hast einen Spaltenversatz von 9 und dies insgesamt zwölfmal.
Dies deutet stark darauf hin, dass es sich hier um "Papierdenken" einer Jahresauswertung handelt.
Glaube mir, dass hier "der Fisch vom Kopf her stinkt" (auch und gerade wegen Deiner Basiskenntnisse in Excel).
Wäre ich eine KI, würde ich strikt nach Prompt vorgehen, die Vektoren vertikal stapeln und den Wert über der ersten Lücke ermitteln.
Ich bin aber keine solche und würde (nach Vorlage eines Beispiels) eher Alternativen vorschlagen.

Gruß Ralf

Hi
das wäre jetzt meine Idee:

=LET(

x;E3:CZ33;

y;MAX(WENN((x<>"")*(REST(SPALTE(x);9)=5);SPALTE(x)*100+ZEILE(x);""));

INDEX(A:CZ;REST(y;100);y/100))

ich hoffe, ich habe dich richtig verstanden.

Gruß Daniel

=INDEX(E3:E33;ANZAHL(E3:E33))
Hallo, habe mit dieser Formel, mit entsprechenden Zelladressen die passende Lösung gefunden.
Musste ein bisschen basteln, aber jetzt passt es.
Gruß und herzlichen Dank
Uwe

Moin!
Deine einfache Lösung hat jetzt aber nichts mit Deiner Threaderöffnung zu tun.
Sie ergibt die letzte Zahl im Bereich E3:E33 (bei lückenloser Füllung von oben nach unten).
Nicht von ungefähr sind Daniels und meine Formeln "ein wenig" umfangreicher.

Gruß Ralf

Hatte etwas Langeweile und mich auch mal an eine Formellösung herangewagt. ;)

• Bereich:
ich nehme den Bereich A:CZ (Spalte 1 bis 108) und indiziere
die Zeilen 3:33 sind SEQUENZ(31;;3)
die Spalten 5, 14, 23, … , 104 sind SEQUENZ(;12;5;9)
folglich ist der fragmentierte Bereich ax

ax;INDEX(A:CZ;SEQUENZ(31;;3);SEQUENZ(;3;5;9))

• leere Zellen:
Diese INDEX-Methode hat den Nachteil, leere Zellen als 0 auszugeben.
Falls 0 als echter Wert vorhanden sein darf, muss man Nichts durch Nichts WECHSELN …
(Den Sinn muss man ja nicht unbedingt verstehen)
Der so korrigierte Bereich bx ist folglich

bx;WECHSELN(ax;;)

• bx in Vektor cx zwingen:

cx;ZUSPALTE(bx;;1)

• Fundstelle der ersten Leerzelle ist XVERGLEICH("";cx)
• Ich brauche aber die (gefüllte) Zelle darüber, also

Fund;XVERGLEICH("";cx)-1

• Jetzt gebe ich den Wert mittels INDEX aus

INDEX(cx;Fund)

Ergibt meine LET()

=LET(

ax;INDEX(A:CZ;SEQUENZ(31;;3);SEQUENZ(;12;5;9));

bx;WECHSELN(ax;;);

cx;ZUSPALTE(bx;;1);

Fund;XVERGLEICH("";cx)-1;

INDEX(cx;Fund))