HERBERS Excel-Forum - das Archiv
Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Mira-Marie
Guten Abend,

ich würde mich freuen, wenn mir jemand beim XVerweis hilft.

Ich habe 2 Registerkarten: "Kunden" mit einer horizontalen Kundenliste und "Rechnungsvorlage" mit einem Adressfeld. In G5 ist eine Dropdown-Liste mit den Kundenkürzeln aus der "Kunden"-Tabelle.

Nun möchte ich die Kundenadresse aus "Kunden" vertikal in der "Rechnungsvorlage" anzeigen. Es funktioniert auch, aber bei Kunde BB steht die VAT nach einer Leerzeile, weil die entsprechende Zelle in "Kunden" leer ist. Wie kriege ich es hin, dass meine Formel leere Zellen in der Rückgabematrix (im Beispiel H3) bei der Ausgabe ignoriert und einfach den nächsten Wert, also I3 ausgibt? Die VAT sollte also in der "Rechnungsvorlage" in B10 stehen und nicht in B11.
Ich habe viel rumprobiert und dann bei ISTLEER, WENNFEHLER, LET etc. aufgegeben...
Wenn jemand einen Tipp für eine einfache Formel hat, gerne :-)

Vielen Dank für eure Hilfe!

Marie

https://www.herber.de/bbs/user/174133.xlsx
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Onur
https://www.herber.de/bbs/user/174134.xlsx
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
BoskoBiati2
Hi,

eine andere Möglichkeit: 

=ZUSPALTE(TEXTTEILEN(TEXTVERKETTEN("|";1;INDEX(FILTER(TKontakte;(TKontakte[Kürzel]=D5));;SPALTE(C1:I1)));"|"))


Gruß

Edgar
Noch 2 Möglichkeiten
Charly CNX
Hi 
=LET(

  x;MTRANS(FILTER(TKontakte[[Kontaktname]:[VAT]];TKontakte[Kürzel]=D5));

  FILTER(x;x<>"")

)

oder so 
=ZEILENUMBRUCH(TEXTTEILEN(TEXTVERKETTEN("|";1;FILTER(TKontakte[[Kontaktname]:[VAT]];TKontakte[Kürzel]=D5));"|");1)

VG Charly
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
daniel
Hi
deine Formel ist schon fast richtig.
du musst nur das letzte: WENN(VAT="";"";VAT) durch das austauschen: FILTER(VAT;VAT<>"")
also:

=MTRANS(LET(VAT;XVERWEIS(D5;TKontakte[Kürzel];TKontakte[[Kontaktname]:[VAT]]);FILTER(VAT;VAT<>"")))

wobei ich dann auch zur vereinheitlichung anstelle des XVerweises ebenfalls filtern würde, aber das ist geschmackssache.

=LET(a;FILTER(TKontakte[[Kontaktname]:[VAT]];TKontakte[Kürzel]=D5);
MTRANS(FILTER(a;a<>"")))

Gruß Daniel






AW: Oder ...
Charly CNX 
=ZUSPALTE(FILTER(TKontakte[[Kontaktname]:[VAT]];TKontakte[Kürzel]=D5);1)

VG Charly
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Onur
Deine Formel kann sie ja in die Schublade legen, für den Fall, dass meine Formel irgendwann nicht mehr funktioniert....
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
BoskoBiati2
Hi Onur,

was hast Du für ein Problem? Auch wenn meine Formel nicht der Weisheit letzter Schluß ist, so zeigt sie doch Alternativen. Die beste Formel ist die von Charly, die ist mir aber erst heute Nacht eingefallen.
Was ich nicht nachvollziehen kann ist, dass man für eine einzelne Formel eine Datei einstellen muß, hast Du Angst davor, dass alle Deine Formeln sehen?


Gruß

Edgar
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Onur
"hast Du Angst davor, dass alle Deine Formeln sehen? " - Nein - nur viel zu oft erlebt, dass es hiess: "Formel funktioniert bei mir nicht" oder "wie baue ich sie denn ein"?

BTW - Was hast DU denn eigentlich für ein Problem, dass du bei bereits gelösten Problemen auch noch DEINE Version posten musst? Wenn sie wenigstens besser oder kürzer wäre, könnte man es ja nachvollziehen, aber so ist das schon etwas peinlich. Sie hat schon eine Formel - was soll sie denn mit noch Einer?
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Onur
Zugegeben, auch ich poste manchmal eine Alternativlösung.
Aber nur dann, wenn meine Lösung einfacher (kürzer) ist oder, wenn ich mit der Lösung schon angefangen hatte, als noch Niemand Eine gepostet hatte und ich nicht für die Tonne gearbeitet haben möchte.
Also kein Grund, mich zu attackieren.
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
daniel
gerade, um sehen zu können ob der eigene Lösungsvorschlag kürzer oder anderweitig in irgendeiner Form besser ist als der gezeigete, wäre es gut, wenn du deine Formel auch schon im Beitrag kurz zeigen würdest und man nicht extra die Beispieldatei dafür öffnen müsste.
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Onur
Hast Recht - In Zukunft poste ich ggf. Beides: Formel und Datei.
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Mira-Marie
Hallo zusammen,

euch allen nochmal vielen Dank für eure Hilfe und eure Formeln. Ich schaue sie mir alle am Wochenende an und versuche, sie nachzuvollziehen. Ich bin begeistert, wie engagiert ihr bei der Sache seid und wie schnell ihr geholfen habt.

Euch einen schönen Tag und ein baldiges Wochenende.
Marie
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Mira-Marie
Hallo Edgar,
auch vielen Dank an dich.
Ich bleibe glaub ich bei Onurs Version, weil ich die einfach besser verstehe, trotzdem danke für deine Hilfe.
Viele Grüße
Marie
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Onur
Oder so:
https://www.herber.de/bbs/user/174135.xlsx
AW: Beim XVerweis leere Zellen der Rückgabematrix ignorieren
Mira-Marie
Hallo Onur,

das ging ja schnell. 1000 Dank!

Viele Grüße
Marie
Gerne !
Onur