HERBERS Excel-Forum - das Archiv

Thema: Formel anzahl Monate in Bereich?

Formel anzahl Monate in Bereich?
mablu
Ich habe eine Liste
die ist in Zellen B6: B28 mit Datum zB. Sa. 25. Jan 2025 Sa. 08. Feb 2025in Inteligenter Tabelle usw. eingetragen nun möchte ich eine Auswertung machen
wo ich sehe wieviele Einträge pro Monat sind also Januar, Februar usw.
wie kann ich das per Formel auswerten
mein Versuch ist das aber es funktioniert nicht!
=ANZAHL(WENN(MONAT(Tabelle1[Datum])=1;Tabelle1[Datum]))


wie wäre die richtige Lösung?

https://www.herber.de/bbs/user/176371.xlsx

für die Hilfe besten Dank
Gruss mablu
AW: Formel Anzahl Monate in Bereich?
Uduuh
Hallo,
B4: =SUMMENPRODUKT((TEXT(Tabelle1[[Datum]:[Datum]];"MMMM")=B3)*(Tabelle1[[Datum]:[Datum]]>0))
und nach rechts kopieren.

Gruß aus'm Pott
Udo
Excel 365 und Online
RPP63
Für aktuelle Versionen:
 ABCD
1Datum MonatAnzahl
225.01.2025 2025/012
329.01.2025 2025/024
408.02.2025 2025/031
515.02.2025 Gesamt7
619.02.2025   
728.02.2025   
821.03.2025   

ZelleFormel
C2=LET(dat;TEXT(A2:A8;"JJJJ/MM");GRUPPIERENNACH(dat;dat;ANZAHL2))


Gruß Ralf
AW: Excel 365 und Online
mablu
Habe ich versucht aber die Leerzellen werden immer noch gezählt!?
gruss mablu
Leerzellen
RPP63
Leerzellen (genauer Leerzeilen) haben in einem Tabellenobjekt rein gar nichts zu suchen!
Lösche diese und füge neue Datensätze unterhalb des letzten Eintrags ein.
Dann kannst Du auch die richtigen Bezüge nehmen:
 AB
1MonatAnzahl
22025/012
32025/024
42025/031
5Gesamt7

ZelleFormel
A2=LET(dat;TEXT(Tabelle1[Datum];"JJJJ/MM");GRUPPIERENNACH(dat;dat;ANZAHL2))
AW: Leerzellen
mablu
super danke
gruss mablu
AW: Formel Anzahl Monate in Bereich?
mablu
Hat Funktioniert besten Dank!
Gruss mablu
AW: Formel Anzahl Monate in Bereich?
BoskoBiati
Hi,

alternativ ohne Summenprodukt: 

=ZÄHLENWENNS(Tabelle1!$B$6:$B$12;">=1."&Berechnungen!B$3&".2025";Tabelle1!$B$6:$B$12;"<="&MONATSENDE(--("1."&Berechnungen!B$3&".2025");0))

=LET(xa;Tabelle1!$B$6:$B$12;xb;--("1."&Berechnungen!B$3&".2025");ZÄHLENWENNS(xa;">="&xb;xa;"<="&MONATSENDE(xb;0)))


Gruß

Edgar
AW: Formel Anzahl Monate in Bereich? gelöst!
mablu
Vielen Dank
ja auch diese zwei funktionieren bestens.
wünsche allen einen schönen Sonntag!
Gruss mablu
AW: Formel Anzahl Wochentag im Bereich
mablu
Hallo
ich nochmal ich wollte die Wochentage zählen die in der Intelligenten Tabelle vorhanden sind alles klappt nur wenn ich leere Zellen habe adiert mir bei Samstag die Zellen dazu?
Was mache ich falsch {=SUMME(WENN(WOCHENTAG(Tabelle1[Datum])=7;1;0))}

Formel im Blatt Berechnungen

https://www.herber.de/bbs/user/176377.xlsx

Vielen Dank für die Hilfe
mablu