HERBERS Excel-Forum - das Archiv

Thema: Zahlen mit Text heraus kopieren!

Zahlen mit Text heraus kopieren!
El-Ti
Hallo Zusammen,

habe eine größere Tabelle mit ein paar Tausend Einträgen

die in etwa so aussehen können (siehe Datei):

Ich habe schon alles versucht, die Daten dementsprechend
mit dem dazugehörenden Text heraus zu lösen. Klappt aber
leider nicht, in einer Formel. Ein Text "Min." bekomme
ich mit der Zahl heraus. Aber den anderen Text "XL" mit
der Zahl geht nicht. Zu mindestens nicht mit einer Formel.

Wenn Ihr mir da behilflich sein könntet, wäre schön.

Vielen Dank im voraus.

Elfriede

https://www.herber.de/bbs/user/178879.xlsx
AW: Zahlen mit Text heraus kopieren!
Uduuh
Hallo,
I8: =GLÄTTEN(WECHSELN(WECHSELN(TEIL(C8;FINDEN(" ";C8;12);999);"Min.";"");"XL";""))

Gruß aus'm Pott
Udo
AW: Zahlen mit Text heraus kopieren!
El-Ti
Hallo Udo,

zuerst Danke mal für Deine Antwort.
Leider ist das nicht das was ich gesucht habe. Die Ergebnisse sollten in der Spalte D stehen
und nur die Zahlen mit Text wie beschrieben oder nur die Zahlen alleine.

Viele Grüße
Elfriede

AW: Zahlen mit Text heraus kopieren!
UweD
Kombination von Uduuh und meinen


auch für ältere Excel...

Arbeitsblatt mit dem Namen 'Tabelle1'
 CDEFGH
806.12.2013 799 Vier Jahreszeiten - acht Modellbahnen799 06.12.2013 Vier Jahreszeiten - acht Modellbahnen

ZelleFormel
D8=GLÄTTEN(WECHSELN(TEIL(C8;12;99);H8;""))
F8=TEIL(C8;1;10)
H8=GLÄTTEN(WECHSELN(WECHSELN(TEIL(C8;FINDEN(" ";C8;12);999);"Min.";"");"XL";""))



LG UweD
Im Anhang ist...
Case
Moin Elfriede, :-)

... eine Alternative mit Power Query: ;-)
https://www.herber.de/bbs/user/178880.xlsx

Servus
Case
AW: Zahlen mit Text heraus kopieren!
UweD
Hallo


so?

Arbeitsblatt mit dem Namen 'Tabelle1'
 CDEFGH
6Datum Nr. TitelSoll-Nr.: Datum Episoden-Titel:
7      
806.12.2013 799 Vier Jahreszeiten - acht Modellbahnen799 06.12.2013 Vier Jahreszeiten - acht Modellbahnen
907.10.2013 787 XL Von der Feldbahn zur Weltbahn - Auf 600 Millimetern durch die Geschichte (ESD: 3sat)787 XL 07.10.2013 Von der Feldbahn zur Weltbahn - Auf 600 Millimetern durch die Geschichte (ESD: 3sat)
1007.10.2013 120 Min. Pässe, Puffer, Palatschinken (ESD: 3sat)120 Min. 07.10.2013 Pässe, Puffer, Palatschinken (ESD: 3sat)
1131.08.2013 798 Bahnnostalgie im Bayerischen Wald798 31.08.2013 Bahnnostalgie im Bayerischen Wald
1224.08.2013 90 Min. Eisenbahn-Romantik - zwischen Bodensee und Westerwald90 Min. 24.08.2013 Eisenbahn-Romantik - zwischen Bodensee und Westerwald
1324.08.2013 797 Von Springböcken, Nashörnern und gefleckten Hunden – Shongololo-Express - Teil 2797 24.08.2013 Von Springböcken, Nashörnern und gefleckten Hunden – Shongololo-Express - Teil 2
1417.08.2013 90 Min. Eisenbahn-Romantik in Bayern90 Min. 17.08.2013 Eisenbahn-Romantik in Bayern
1517.08.2013 796 Von Tausendfüßlern, Elefanten und Löwenbabys – Shongololo-Express – Teil 1796 17.08.2013 Von Tausendfüßlern, Elefanten und Löwenbabys – Shongololo-Express – Teil 1
1610.08.2013 90 Min. Eisenbahn-Romantik unter Volldampf90 Min. 10.08.2013 Eisenbahn-Romantik unter Volldampf
1710.08.2013 795 „Natur, Nostalgie und die 97 501“– oder schaukelnd durch die Biosphäre795 10.08.2013 „Natur, Nostalgie und die 97 501“– oder schaukelnd durch die Biosphäre
1803.08.2013 794 Schienenkreuzfahrt Bodensee – Bahngeschichten am Schwäbischen Meer794 03.08.2013 Schienenkreuzfahrt Bodensee – Bahngeschichten am Schwäbischen Meer
1927.07.2013 793 Zwischen Jungfernsprung und Drachenfels - die Renaissance des Bundenthalers793 27.07.2013 Zwischen Jungfernsprung und Drachenfels - die Renaissance des Bundenthalers
2020.07.2013 792 Elekrisch ins Jrüne - Ausflugsbahnen rund um Berlin792 20.07.2013 Elekrisch ins Jrüne - Ausflugsbahnen rund um Berlin
2113.07.2013 791 Eisenbahnspielen in freier Natur - Garten- und Parkbahnen im Schwabenland791 13.07.2013 Eisenbahnspielen in freier Natur - Garten- und Parkbahnen im Schwabenland
2206.07.2013 790 Irlands dampfende Vergangenheit790 06.07.2013 Irlands dampfende Vergangenheit
2329.06.2013 789 Bahnverein im Schwabenalter - 40 Jahre EFZ789 29.06.2013 Bahnverein im Schwabenalter - 40 Jahre EFZ
2422.06.2013 788 Almost Heaven, West Virginia – Waldbahndinos in Aktion788 22.06.2013 Almost Heaven, West Virginia – Waldbahndinos in Aktion
2515.06.2013 787 Werksverkehr und Ausflugszügle - Feldbahnen im Südwesten787 15.06.2013 Werksverkehr und Ausflugszügle - Feldbahnen im Südwesten
2614.06.2013 45 Min. Mit dem Zug durch den Norden Argentiniens (ESD auf arte)45 Min. 14.06.2013 Mit dem Zug durch den Norden Argentiniens (ESD auf arte)
2713.06.2013 45 Min. Mit dem Zug durch Südengland (ESD: arte)45 Min. 13.06.2013 Mit dem Zug durch Südengland (ESD: arte)
2812.06.2013 45 Min. Mit dem Zug durch Taiwan (ESD: arte)45 Min. 12.06.2013 Mit dem Zug durch Taiwan (ESD: arte)
2911.06.2013 45 Min. Mit dem Zug zum Mont Blanc (ESD: arte)45 Min. 11.06.2013 Mit dem Zug zum Mont Blanc (ESD: arte)
3010.06.2013 796 XL Mit dem Zug durchs südliche Afrika796 XL 10.06.2013 Mit dem Zug durchs südliche Afrika

ZelleFormel
D8=WECHSELN(TEIL(C8;11;99);H8;"")
F8=TEIL(C8;1;10)
H8=GLÄTTEN(WECHSELN(WECHSELN(TEXTNACH(TEIL(C8;12;99);" ");"XL";"");"Min.";""))



Bin nicht sicher, ob in deiner Version schon lauffähig.

LG UweD
AW: Zahlen mit Text heraus kopieren!
El-Ti
Hallo UweD,

Danke für Deine Antwort. Komme leider erst jetzt dazu, Dir zu antworten.

Wenn ich Deine Formel in D kopiere, bringt er mir als Ergebnis "799 Vier Jahreszeiten - acht Modellbahnen" und nicht die gewünschte "799".

Die dritte Formel - wie vermutet - läuft bei mir nicht. Habe noch Excel 2021.

VG Elfriede
AW: Zahlen mit Text heraus kopieren!
Luschi
Hallo

Dein Zitat:
habe eine größere Tabelle mit ein paar Tausend Einträgen
- bei dieser Sachlage sich mit Formel zu beschäftigen
- um 1 vernünftiges Ergebnis zu erhalten
- ist schon fast wie Lotto spielen
- habe gerade erst von 1 paar Tagen ein ähnliche Problem auf dem Tisch gehabt
- und siehe da - gerade an den entscheidenden Stellen zur Trennung der Daten gab es ungewollt zu viele Leerzeichen
- deshalb schau Dir die Power Query Lösung von Case an
- ich habe seine Lösung um eine PQ-M-Funktion erweitert
- so das alle doppelten/dreifachen usw. Leerzeichen hintereinander entfernt werden
- bevor die eigentliche Hauptarbeit von Case's PQ-M-Code beginnt

https://www.herber.de/bbs/user/178885.xlsx

Gruß von Luschi
aus klein-Paris
AW: Zahlen mit Text heraus kopieren!
UweD
Die Formel in D basiert auf dem Ergebnis von H

Wenn H nicht geht, dann kann D auch nichts Richtiges liefern

hast du dir meinen anderen Post angesehen?
Die Formeln klappen auch in deiner Version

LG UweD

https://www.herber.de/forum/messages/2018545.html
AW: Zahlen mit Text heraus kopieren!
Michael
Hallo Elfriede,

eine Formel, die Deine einfach erweitert, wäre für D8 Deiner Beispieldatei diese: 
=WENN(ISTZAHL(SUCHEN("min.";C8));GLÄTTEN(TEIL(C8;12;8));WENN(ISTZAHL(SUCHEN("xl";C8));GLÄTTEN(TEIL(C8;12;6));GLÄTTEN(TEIL(C8;12;4))))

Ich nehme gerne SUCHEN, das unterscheidet nicht zwischen Groß- und Kleinschreibung.

In meiner Excelversion geht auch das hier: 
=TEXTVOR(TEXTNACH(C8;" ");" ";1+(ISTZAHL(SUCHEN("xl";C8))+ISTZAHL(SUCHEN("min.";C8))))

Sie würde auch "120 Min. XL" ausgeben, wenn jemals vorhanden.

In Zelle i8 Deiner Datei reicht dann: 
=GLÄTTEN(WECHSELN(TEIL(C8;12;LÄNGE(C8));D8;""))


VG
Michael
AW: Zahlen mit Text heraus kopieren!
El-Ti
Hallo Michael,

Danke für Deine Antwort. Komme leider erst jetzt dazu, Dir zu antworten.

Deine Formeln funktionieren wunderbar. Habe jetzt die Wahl der Qual
welche Formel ich verwenden werde bzw. kann. (Je nach Anforderung).

Die Formel mit TEXTVOR(TEXTNACH) läuft bei mir nicht. Habe noch Excel 2021.

Nochmals vielen Dank.

VG Elfriede
AW: Zahlen mit Text heraus kopieren!
daniel
Hi
teste mal diese Formel in E8:

=TEIL(C8;12;FINDEN(" ";C8;13)-12+AGGREGAT(14;6;{3;5;0}/ISTZAHL(FINDEN({"XL";"Min.";""};LINKS(C8;20)));1))

wenn weitere Texte hinzukommen, kannst du die in der Formel ergänzen, wenn du die beiden {}-Klammern erweiterst
in der ersten steht die Länge des Textes, in der zweiten dann der Text selbst.
Die Position in der Klammer muss korrestpondieren.
die letzte Postition muss immer das 0 / "" sein, das dann angewendet wird, wenn keiner der vorherigen Texte gefunden wird.

Gruß Daniel

AW: Zahlen mit Text heraus kopieren!
BoskoBiati
Hi,

hier mal mit allen Formeln:

https://www.herber.de/bbs/user/178881.xlsx

Man könnte aber auch die Daten von https://de.wikipedia.org/wiki/Eisenbahn-Romantik/Episodenliste mit PQ einlesen und darstellen.

Gruß

Edgar
AW: Zahlen mit Text heraus kopieren!
El-Ti
Hallo Edgar,

Danke für Deine Antwort. Komme leider erst jetzt dazu, Dir zu antworten.

Deine Formeln funktionieren wunderbar. Habe jetzt die Wahl der Qual
welche Formel ich verwenden werde bzw. kann. (Je nach Anforderung).

Mit PQ habe ich nichts am Hut. Aber vielleicht sollte man sich doch einmal
intensiver damit befassen.

Nochmals vielen Dank.

VG Elfriede
AW: Zahlen mit Text heraus kopieren!
BoskoBiati
Hi,

dann hast Du hier mal alle Beiträge der Eisenbahnromantik:

https://www.herber.de/bbs/user/178887.xlsx

Gruß

Edgar