HERBERS
Excel-Forum
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Entdecke rund 2 Millionen Excel-Lösungen im
Forumsarchiv
Zum Forum Zum Forum Zum Forumthread Zum Forumthread Zum Archivthread Zum Archivthread
Forumbeitrag
Excel-Version des Fragestellers:
2019
Erfahrungslevel des Fragestellers:
VBA nur mit Recorder
daniel
25.04.2026 01:18:24
AW: Prüfung auf Doppeleingabe Code macht Probleme
Hi
vermutlich ist das Problem, dass .Find nichts findet.
wenn du bei .Find mit LookIn:=xlvalues suchst, dann schaut VBA nicht in den unformatierten Zellwerten, sondern in den formatierten Zellwerten.
das ZählenWenns hingegen arbeitet als Formel immer mit den Unformatierten Zellwerten.
Dh. wenn du nach 1,234 suchst und in der durchsuchten Spalte diese Zahl nur als 1,23 angezeigt wird, kann dein .Find sie nicht finden, du müsstest dann nach 1,23 suchen.

mein Tipp: da du nur eine Spalte durchsuchst, kannst du mit Application.Match (Vergleich) arbeiten.
das arbeitet als Formel auch mit den unformatierten Zellwerten und du bekommst auch sofort die Position, wo sich das gesuchte Element befindet.

mit Application.Match bekommst du auch keinen Fehlerabbruch, wenn das Suchelement nicht gefunden wird, sondern einen Fehlerwert, auf den du prüfen kannst.

Beispiel: 
dim vntFundstelle as variant

vntFundstelle = Application.Match(vntItem, wks.Range(conDetectionRangeAddress), 0)

if not IsError(vntFundstelle) Then Msgbox "Gefunden in Zeile " & vntFundstelle


und noch ein Tipp:
bei .Find sollte man immer möglichst viele Parameter angeben, zumidest LookAt und LookIn, und ggf auch Matchcase
gibt man die nicht an, dann verwendest du die zuletzt gemachte Einstellung, und das kann dann auch den Effekt haben, dass es manchmal funktioniert und machmal nicht.
Gruß Daniel

Beim Antworter bedanken Als gefällt mir markieren Als hervorragend auszeichnen
Als Antwort auf diesen Beitrag
Sabrina
25.04.2026 00:14:49
Prüfung auf Doppeleingabe Code macht Probleme
Hallo,

Ich habe einen Code, welcher mich auf eine Doppeleingabe (Zahl) in Spalte A hinweist, und zwar werden alle 10 TABs überprüft. Aaaaber: Er funktioniert nur einwandfrei, wenn ich eine Testdatei erstelle, und diese neu mit Daten fülle.

Wenn ich dagegen den Code in meiner Originaldatei benutze, dann funktioniert er nur manchmal, ich konnte nicht feststellen, bei welcher Zahl er mir eine Meldung ausgibt oder einen Debugger. Es ist echt zum verrückt werden.

Es ist der einzige Code "in dieser Arbeitsmappe". Es sind keine Gültigkeiten (Datenüberprüfung) und bed. Formatierungen oder spezielle Zellformate vorhanden.

Dann hatte ich schon gedacht, meine Originaldatei ist eine uuuuuuralte .xls die natürlich Versionsabhängig immer mal wieder konvertiert wurde. Also habe ich die einzelen TABs in eine neu Mappe kopiert, dennoch kommt ein Debugger: "Laufzeitfehler 91" und dann wird der folgende Bereich markiert:

MsgBox "Lfd. Nr. " & vntItem & " ist bereits in " & wks.Name & vbNewLine & "in Zelle " & wks.Range(conDetectionRangeAddress).Find(vntItem, , xlValues).Address(0, 0) & " vorhanden!", _
vbExclamation, "A C H T U N G"

Bin echt verzweifelt, weil ich den Fehler einfach nicht finde. Ich würde ja eine Testdatei zur Verfügung stellen, aber da funktioniert er ja.

Bin sehr dankbar über eure Unterstützung. VG Sabrina 

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)



' On Error Resume Next



Dim wks As Worksheet

Dim rngIntersect As Range

Dim rngArea As Range

Dim vntItem As Variant



Dim blnExist As Boolean

Dim lngCount As Long



Const conDetectionRangeAddress As String = "A2:A50"



With Target



Set rngIntersect = Intersect(Target, Sh.Range(conDetectionRangeAddress))



If Not rngIntersect Is Nothing Then



For Each wks In Me.Worksheets



lngCount = Abs(wks Is Sh)



For Each rngArea In rngIntersect.Areas



If rngArea.Cells.Count = 1 Then

vntItem = rngArea.Value

blnExist = (WorksheetFunction.CountIf(wks.Range(conDetectionRangeAddress), vntItem) > lngCount)

Else



For Each vntItem In rngArea.Value

blnExist = (WorksheetFunction.CountIf(wks.Range(conDetectionRangeAddress), vntItem) > lngCount)

If blnExist Then: Exit For

Next



End If



If blnExist Then Exit For



Next



If blnExist Then Exit For



Next



If blnExist Then



Application.EnableEvents = False

Application.Undo

Application.EnableEvents = True





MsgBox "Lfd. Nr. " & vntItem & " ist bereits in  " & wks.Name & vbNewLine & "in Zelle  " & wks.Range(conDetectionRangeAddress).Find(vntItem, , xlValues).Address(0, 0) & "  vorhanden!", _

vbExclamation, "A C H T U N G"



End If



End If



End With



Set wks = Nothing

Set rngArea = Nothing

Set rngIntersect = Nothing



End Sub


Folgenachrichten
Zum Forumthread
Antwort auf Beitrag erstellen
Bitte einen Anwendernamen ohne @ eingeben.
Bitte das Passwort eingeben.
Bitte eine gültige E-Mail-Adresse eingeben.
Bitte einen Betreff eingeben.
Weitere Optionen
Aktivieren, wenn die Frage/der Beitrag noch nicht beantwortet wurde und unter Listen > Offene Threads erscheinen soll.
Beispieldatei hochladen
Bitte einen Nachrichtentext eingeben.