Beiträge zum Thread: Wenn, Wen(Und Verschachtelte Funktion, mehre Bedingungen

Hola,
da mal wieder keine Beispieldatei dabei ist hilft nur raten.

=WENN(Q6=0;WENN(E6=FoBi;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0);WENN(ODER(UND(C6=Springer;D6>=SVERWEIS(E6;Dienstarten!B$3:K$68;9;0);UND(E6=Betriebsrat;D6>=SVERWEIS(E6;Dienstarten!B$3:K$68;9;0))));D6;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0))))

Gruß,
steve1da

Ich werde es nachher ausprobbieren, vielen Dank für dein raten.
Eine Beispieldatei bzw die Ist-Datei werde ich demnächst mal anfügen.

Moin!
Wann denn?
Nach Deinem achten Thread zum ähnlichen Logik-Problem?
Nimm es mir nicht allzu übel, aber Deine ganzen Threads haben doch erst mal wenig mit Excel zu tun, sondern vielmehr mit Deiner Schwierigkeit, logisch zu abstrahieren.
Apropos Abstraktion:
Es könnte tatsächlich sinnvoller sein, den Aufbau der uns unbekannten Datei mal komplett zu überdenken.
Möglich, dass solche Formel-Bandwürmer dann obsolet sind.

Gruß Ralf

Hallo,
> Logik-Problem
Du könntest recht haben, nur dass ich die Logik nicht unbedingt vorgebe sondern versuche diese (vorgegebene Logik) in einer Funktion umzusetzen und hier evtl. auch ein Logik-Problem habe.
Ich versuche hierbei die Logik unseres Rahmendienstplans mit dem Ist-Dienstplan abzubilden, der besagt, dass mind. immer die Regelstunden gelten, auch dann wenn weniger Arbeitszeit erbracht wurde (Recht auf Arbeit, Annahmeverschulden des Abeitgebers).

> unbekannten Datei mal komplett zu überdenken. Möglich, dass solche Formel-Bandwürmer dann obsolet sind.
... ist ein gute Idee. Dazu muss ich das aber erstmal umgesetzt haben, damit das Nachvollzogen werden kann was gemeint ist und alle Ausnahmen von der Regel abgebildet sind.
Ist vielleicht ein bisschen umständlich.

Danke für Deine Lösung. Leider gibt sie nicht den richtigen Wert wieder.

Ich habe eine png-Datei angefügt ich hoffe das klappt und es ist ersichtlich um wass es geht.


Der Wert in H6 müsste eigentlich 12 sein, entsprechend dem Wert in D6 da D6 > als SVERWEIS ist-
In H7 wiederum ist der Wert 5 richtig, da der Wert in D7 =0 und somit < als SVERWEIS.

Die isolierte Funktion
=WENN(UND(E6=Betriebsrat;D6>=SVERWEIS(E6;Dienstarten!B$3:K$68;9;0));D6;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0))
gibt den richtigen Wert, 12 wieder.

Warum das in der verschachteltenFunktion nicht der Fall ist, Weiß ich nicht.

Sorry, ich hab keine Lust Bilder nachzubauen und mir den Rest wieder zusammen zu raten. Viel Erfolg noch.

HI

du kombinierst in einem WENN, ob Betriebsrat und D6 größer SVerweis.
das wird dann in Kombinationen mit anderen Typen komplex
trenne das. Frage erst, ob Betriebsrat und dann, ob D6 > SVerweis()

das mit dem SVerweis würde ich so schreiben: MAX(D6;SVerweis(E6;...))

also als Isolierte Funktion: =Wenn(E6=Betriebsrat;Max(D6;SVerweis(E6;...));D6)

damit lassen sich dann auch andere Gruppierungen leicht ergänzen.

=Wenn(Oder(C6=Springer;E6=Betriebsrat);Max(D6;SVerweis(E6;...));D6)

hier bekommen jetzt Springer und Betriebsrat den Wert aus dem Maximum von D6 und SVerweis, alle anderen den Wert aus D6

Gruß Daniel

Hi Daniel,
vielen Dank für die Lösung.

=WENN(ODER(C6=Springer;E6=Betriebsrat;E6=PraxisAnleiter);MAX(D6;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0));Q6)

funktioniert wie gewünscht. Leider nicht in Kombination mit dem Ersten Teil.

=WENN(Q6=0;WENN(E6=FoBi;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0);WENN(ODER(C6=Springer;E6=Betriebsrat;E6=PraxisAnleiter);MAX(D6;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0));Q6)))

Ich erhalte als Wert "Falsch" Excel korrigiert am Schluss die 3 Klammern.

In den Spalten O bis S befinden sich Korrekturfelder in denen bspw. die bewertete Arbeitszeit (Q6) korrigiert werden kann. Standartwert in O bis Q ist 0. Daher am Anfang die Abfrage ob Q9=0. Die Standdartwerte, laut Regeldienstplan, sind in diesem Stundenzettel bereits automatisch eingetragen. Lediglich Änderungen müssen in den Korrekturspalten eingertagen werden.

Nochmals vielen Dank für Deine Hilfe.

Nachtrag:
Q6 hat den Wert 10,00
Das Formelergebnis müsste also 10,00 lauten.

Nachtrag:2:
Hat Q6 den Wert 0 tritt kein Fehler auf. Die Formel gibt den gewünschten Wert wieder. Steht in Q6 ein Wert, in diesem fall 10,00 ersteint als Wert "Falsch", was ja eigentlich auch richtig ist nur sollte dort der Wert 10,00 stehen. Gebe ich als Formel =WENN(Q6=0;"";Q6) an, erscheint als RückgabeWert 10,00.

HI
du hast einen Wert vergessen, vermutlich den FALSCH-Teil für das letzte WENN:
welcher Wert soll ausgegeben werden, wenn das hier: ODER(C6=Springer;E6=Betriebsrat;E6=PraxisAnleiter) FALSCH ergibt.
das hast du nicht angegeben, und weil du zusätzlich noch ein paar klammern vergessen hast, musste Excel korrigieren und hat dann das Q6 diesem Wenn zugeordnet und nicht dem ersten.

korrekt wäre vermutlich das hier (ich markiere den Falsch-Wert für das letzte WENN mit Fragezeichen)

=WENN(Q6=0;WENN(E6=FoBi;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0);WENN(ODER(C6=Springer;E6=Betriebsrat;E6=PraxisAnleiter);MAX(D6;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0));??));Q6)

Wenn ein WENN einen komplizierten WAHR-Teil hat und einen kurzen FALSCH-Teil, dann verliert man schnell den Überblick.
hier kann es hilfreich sein, die Logik umzudrehen, dass die kurze Formel in den WAHR-Teil kommt:

=WENN(Q6<>0;Q6;WENN(E6=FoBi;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0);WENN(ODER(C6=Springer;E6=Betriebsrat;E6=PraxisAnleiter);MAX(D6;SVERWEIS(E6;Dienstarten!B$3:K$68;9;0));??)))

Gruß Daniel