Links in Dynamische Labels

Forumthread: Links in Dynamische Labels

13.06.2018 15:32:09

Claudia

Hallo,
ich brauche Hilfe bei dynamischen Labels. In meiner excel Anwendung habe ich div. Frames in einer Userform. In den Frames erstelle ich dynamische Labes.
So kann ich sehr gut eine Liste mit Daten aus einer Datenbank abbilden.
Was ich bisher nicht hinbekomme ich, einen Link als Label o.a. einzufügen, so dass er dann angeklickt werden kann und sich die Website öffnet.
Da ich neu bin hoffe ich das ich mich verständlich ausgedrückt habe und würde mich über eine Hilfestellung freuen.
Danke schon mal & LG
Claudia

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Links in Dynamische Labels

13.06.2018 15:41:50

Nepumuk
AW: Links in Dynamische Labels

13.06.2018 15:48:05

Claudia
AW: Links in Dynamische Labels

13.06.2018 16:22:17

Nepumuk
AW: Links in Dynamische Labels

13.06.2018 20:23:25

Claudia
AW: Links in Dynamische Labels

13.06.2018 20:34:28

Daniel
AW: Links in Dynamische Labels

13.06.2018 20:35:41

Claudia
AW: Links in Dynamische Labels

14.06.2018 09:02:21

Nepumuk
AW: Links in Dynamische Labels

13.06.2018 15:51:16

Luschi
Zur Info:

13.06.2018 21:33:50

RPP63

AW: Links in Dynamische Labels

13.06.2018 15:41:50

Nepumuk

Hallo Claudia,
ein Beispiel:

Private Sub Label1_Click()
Call ThisWorkbook.FollowHyperlink(Address:="http://www.herber.de/forum/", NewWindow:=True)
End Sub

Gruß
Nepumuk

AW: Links in Dynamische Labels

13.06.2018 15:48:05

Claudia

Hallo Nepumuk,
danke schon mal. Das wäre ja der normale Label. Ich fülle jedoch so in den Frame
With uf.Frame_uebersichtsliste.Controls.Add("Forms.Label.1"): .Caption = s7.Cells(i, 3): .Top = 16 * zeile: .Left = 65: .WordWrap = False: end With
LG Claudia

AW: Links in Dynamische Labels

13.06.2018 16:22:17

Nepumuk

Hallo Claudia,
ist das immer der selbe Link oder ist der auch dynamisch?
Gruß
Nepumuk

AW: Links in Dynamische Labels

13.06.2018 20:23:25

Claudia

Hallo,
der Link ist immer unterschiedlich aus der Datentabelle.
LG Claudia

AW: Links in Dynamische Labels

13.06.2018 20:34:28

Daniel

HI
die LINK-Adresse könnte beim Erstellen des Labels in die TAG-Eigenschaft geschrieben werden und im Klick-Event des Labels dort aufgerufen werden.
Wenn du bei zur Laufzeit erstellten Steuerelementen ein Eventmakro haben willst, müsstest du entweder
- zusätzlich zu jedem Label das entsprechende Makro per Code erstellen
oder
- dich mit KLassenprogrammierung beschäftigen, dh ein einziges Klick-Eventmakro, welches dann aber allen neu erstellten Labels zugeordnet wird, so dass du nur ein ein Makro für alle Labels benötigst und nicht für jedes Label eines.
das währe hier das Mittel der Wahl. Zum Thema "Klassenprogrammierung" bitte in den Forenarchiven oder im WWW nach Anleitungen suchen.
Gruß Daniel

AW: Links in Dynamische Labels

13.06.2018 20:35:41

Claudia

Hallo, danke Dir ich werde da mal tiefer reinschauen.

AW: Links in Dynamische Labels

14.06.2018 09:02:21

Nepumuk

Hallo Claudia,
ein Beispiel:
Im Modul des Userforms:

Option Explicit
Private mobjLabelCollection As Collection
Private Sub UserForm_Initialize()
Dim lngIndex As Long
Dim objLabelClass As clsLabel
Dim objLabel As MSForms.Label
Set mobjLabelCollection = New Collection
For lngIndex = 1 To 10
Set objLabel = Frame1.Controls.Add(bstrProgID:="Forms.Label.1")
With objLabel
.Caption = Tabelle1.Cells(lngIndex, 3).Text
.Tag = Tabelle1.Cells(lngIndex, 4).Text 'Das ist der Hyperlink
.Top = 16 * lngIndex
.Left = 65
.WordWrap = False
End With
Set objLabelClass = New clsLabel
Set objLabelClass.Label = objLabel
Call mobjLabelCollection.Add(Item:=objLabelClass)
Set objLabelClass = Nothing
Next
Set objLabel = Nothing
End Sub
Private Sub UserForm_Terminate()
Set mobjLabelCollection = Nothing
End Sub

In einem Klassenmodul mit dem Namen clsLabel:

Option Explicit
Private WithEvents mobjLabel As MSForms.Label
Private Sub Class_Terminate()
Set Label = Nothing
End Sub
Friend Property Get Label() As MSForms.Label
Set Label = mobjLabel
End Property
Friend Property Set Label(ByRef probjLabel As MSForms.Label)
Set mobjLabel = probjLabel
End Property
Private Sub mobjLabel_Click()
Call ThisWorkbook.FollowHyperlink(Address:=mobjLabel.Tag, NewWindow:=True)
End Sub

Gruß
Nepumuk

AW: Links in Dynamische Labels

13.06.2018 15:51:16

Luschi

Hallo Claudia,
warum googelst Du nicht? [userform label hyperlink]
Dann hättest Du diesen Tipp von John Walkenbach gefunden.
http://spreadsheetpage.com/index.php/tip/adding_a_hyperlink_to_a_userform/
Da kannst Du auch eine Demodatei zum Thema herunterladen.
Gruß von Luschi
aus klein-Paris

Beliebteste Forumthreads (12 Monate)

Forumthread: Links in Dynamische Labels

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread