Prüfen ob Fenster extistiert

Private Function GetWindowInfo(ByVal hwnd&, STitel$, Optional booVisible As Boolean = True) As _ Long Dim Result&, Style&, Title$ 'Darstellung des Fensters Style = GetWindowLong(hwnd, GWL_STYLE) Style = Style And (WS_VISIBLE Or WS_BORDER) 'Fensetrtitel ermitteln Result = GetWindowTextLength(hwnd) + 1 Title = Space$(Result) Result = GetWindowText(hwnd, Title, Result) Title = Left$(Title, Len(Title) - 1) 'prüfen ob Fenster Sichtbar If (Style = (WS_VISIBLE Or WS_BORDER)) Or booVisible = False Then If Title Like "*" & STitel & "*" Then GetWindowInfo = hwnd Exit Function End If End If GetWindowInfo = 0 End Function

Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Benutzer

Hallo Sebastian,
jetzt schreib mal das was Du gepostet hast in ein Modul einer neuen Arbeitsmappe und probier aus, ob irgendwas passiert... merkst Du was? Wie sollen wir Dir helfen, wenn Du einen offensichtlich unvollständigen Code postest? Naja egal, schwer zu finden war der Originalcode ja nicht.

Option Explicit
Private Declare Function GetDesktopWindow Lib "user32" () _
As Long
Private Declare Function GetWindow Lib "user32" (ByVal hWnd _
As Long, ByVal wCmd As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias _
"GetWindowLongA" (ByVal hWnd As Long, ByVal wIndx As _
Long) As Long
Private Declare Function GetWindowTextLength Lib "user32" _
Alias "GetWindowTextLengthA" (ByVal hWnd As Long) _
As Long
Private Declare Function GetWindowText Lib "user32" Alias _
"GetWindowTextA" (ByVal hWnd As Long, ByVal lpString _
As String, ByVal cch As Long) As Long
Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2
Const GW_CHILD = 5
Const WS_VISIBLE = &H10000000
Const WS_BORDER = &H800000
Const GWL_STYLE = (-16)
Function sucheFenster(suchName As String, Optional ByVal teilSuche As Boolean = False, _
Optional ByVal grossKlein As Boolean = False) As Boolean
Dim hWnd As Long
Dim fensterTitel As String
' gross/Kleinschreibung unwichtig?
If Not grossKlein Then suchName = LCase(suchName)
' Nur nach Teil des Namens suchen
If teilSuche Then suchName = "*" & suchName & "*"
'Einstieg
hWnd = GetWindow(GetWindow(GetDesktopWindow(), GW_CHILD), GW_HWNDFIRST)
'Alle vorhandenen Fenster abklappern
Do
fensterTitel = GetWindowInfo(hWnd)
If Not grossKlein Then fensterTitel = LCase(fensterTitel)
If fensterTitel Like suchName Then
sucheFenster = True
Exit Function
End If
hWnd = GetWindow(hWnd, GW_HWNDNEXT)
Loop Until hWnd = 0
End Function
Private Function GetWindowInfo(ByVal hWnd As Long) As String
Dim Result As Long
Dim Title As String
Dim Style As Long
Style = GetWindowLong(hWnd, GWL_STYLE)
Style = Style And (WS_VISIBLE Or WS_BORDER)
'Title des Fenster auslesen
Result = GetWindowTextLength(hWnd) + 1
Title = Space$(Result)
Result = GetWindowText(hWnd, Title, Result)
Title = Left$(Title, Len(Title) - 1)
If Style = (WS_VISIBLE Or WS_BORDER) Then
GetWindowInfo = Title
End If
End Function

Das ist jetzt reduziert aus das, was Du brauchst. Mit der Funktion sucheFenster kannst Du abfragen, ob ein Fenster mit diesem Titel aktiv ist.
Gruß, Jogy

Beliebteste Forumthreads (12 Monate)

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread