Datenabgleich

Liebe Mitglieder, die Datei ist folgende:
https://www.herber.de/bbs/user/130099.xlsx
mom. reichen meine Kenntnisse nicht aus bzw. es fehlt mir die Idee wie folgende Fragestellung umzusetzen sei:
1. Das Sheet "Zeiten" beschreibt einen kompletten Monat (zeile 1) und ab Zeile 3 die Standorte: steht für einen Standort unter einem Datum WAHR drin, hat der Standort an diesem Datum geöffnet. Für Samstage, Sonntage kann ein Datum auch zweimal vorkommen!
2. Im Blatt Daten sind die Ergebnisse aufgelistet, ist eine sql Abfrage ursprünglich.
Letztendlich soll für jeden Standort eine Überprüfung stattfinden, wenn für ein bestimmtes Datum ein WAHR ausgewiesen wird, überprüfe, ob für diesen Standort dieses Datum auch im Blatt "Daten" vorhanden ist.
Wenn ja, alles gut, wenn nein
schreibe das fehlende Datum und den Standort in Blatt 3.
Die Datei ist im Original natürlich viel umfangreicher, daher wäre eine VBA Lösung superklasse, das Anpassen krieg ich hin.
Vielen Dank G

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo
so?

Option Explicit

Sub Prüfen()
    Dim TB1, TB2, TB3, Z1 As Integer, S1 As Integer, LR As Long, LC As Integer
    Dim i As Long, j As Integer, Sp1 As Integer
    Dim FSt2 As Integer, FDat2 As Integer, WF, Z As Long
    
    Set TB1 = Sheets("Zeiten")
    Set TB2 = Sheets("Daten")
    Set TB3 = Sheets("Tabelle3")
    Set WF = WorksheetFunction
    
    Z1 = 3 'ab Zeile 3 
    Sp1 = 4 'Standorte stehen in Spalte D 
    S1 = 6 'Datum ab F 
    
    FSt2 = 1 'FindeStandorte in Spalte A 
    FDat2 = 8 'FindeDatum in Spalte H 
    
    LR = TB1.Cells(TB1.Rows.Count, Sp1).End(xlUp).Row 'letzte Zeile der Spalte D 
    LC = TB1.Cells(1, TB1.Columns.Count).End(xlToLeft).Column 'letzte Spalte einer Zeile 1 
    
    'reset 
    TB3.UsedRange.ClearContents
    
    With TB1
        For i = Z1 To LR ' Durchlaufe alle Zeilen in 'Zeiten' 
        
            For j = S1 To LC 'Durchlaufe alle Spalten mit Datum 
            
                If .Cells(i, j) Then ' Wahr 
                
                    'Zählenwenns() 
                    If WF.CountIfs(TB2.Columns(FSt2), .Cells(i, Sp1), TB2.Columns(FDat2), .Cells(1, j)) = 0 Then
                    
                        TB3.Cells(Z + 1, 1) = .Cells(i, Sp1)
                        TB3.Cells(Z + 1, 2) = Format(.Cells(1, j), "DD.MM.YYYY")
                        Z = Z + 1
                    End If
                End If
            Next j
        Next i
    End With
    
    MsgBox "Fertig" & vbLf & Z & " Termine fehlen"
End Sub

LG UweD

Beliebteste Forumthreads (12 Monate)

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread