im Ordner alle Dateien durchlaufen und bearbeiten

Hallo,
ich habe eine ziemlich schwierige Frage...
Zu mindest für mich.
Folgende Problemmstellung:
Es giebt ein Ordner zb: C:/ Eigene Dateie /Ordner.
In diesem Ordner befinden sich 100 Dateien, die gleich aufgebaut sind,
jede diese Excel Datei hat ein Tabellenblatt "Data", der aber verstäckt ist....
Aus diesem Blatt müssen einige Zellen, z.B. A1:A50 kopiert werden und in eine Zentralle Excel Datei in ein Blatt an B1 eingefügt werden ... In der Nächsten Datei wird auch A1:A50 kopiert und in die Zentralle Datei aber in C1 eingefügt... Und so mit allen unter-Dateien, die sich in einem bestimmten Ordner befinden...
idealer weise wäre es, wenn in einem Zentralen ExcelDatei ein Knopf giebt,
per Knopfdruck, wählt man den Ordner und alle Dateien, die in diesem Ordner liegen werden wie oben beschrieben bearbeitet....
Die Aufgabe ist für mich ziemlich schwierig... Und ich würde mich sehr freuen, wenn ihr mir hilft...
Vielen Dank und viele Grüße
Anja
un

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Anja!
Füge diesen Code in ein allgemeines Modul der Mappe in der die Daten
gesammelt werden sollen.
Du must im VBA-Editor unter &gt Extras &gt Verweise den Verweis auf
"Microsoft Shell Controls and Automation" setzen!
Option Explicit
'!!!!!!!!!!!!!!!!!Achtung!!!!!!!!!!!!!!!!!
'Zuerst Verweis auf "Microsoft Shell Controls And Automation" objekt Bibliothek setzen!
Private Const BIF_RETURNONLYFSDIRS As Long = &H1
Private Const BIF_DONTGOBELOWDOMAIN As Long = &H2
Private Const BIF_RETURNFSANCESTORS As Long = &H8
Private Const BIF_BROWSEFORCOMPUTER As Long = &H1000
Private Const BIF_BROWSEFORPRINTER As Long = &H2000
Private Const BIF_BROWSEINCLUDEFILES As Long = &H4000
Private Const MAX_PATH As Long = 260

Function BrowseFolder(Optional Caption As String, _
Optional InitialFolder As String) As String
'Created By Chip Pearson and Pearson Software Consulting Services
'© Copyright 1997-2003 Charles H. Pearson
' http://www.cpearson.com/excel/BrowseFolder.htm
Dim SH As Shell32.Shell
Dim F As Shell32.Folder
Set SH = New Shell32.Shell
Set F = SH.BrowseForFolder(0&, Caption, BIF_RETURNONLYFSDIRS, _
InitialFolder)
If Not F Is Nothing Then
BrowseFolder = F.Items.Item.Path
End If
End Function

Sub importData()
Dim fSearch As FileSearch
Dim wkb As Workbook
Dim wks As Worksheet, ziel As Worksheet
Dim strPath As String
Dim iCnt As Integer, iCol As Integer
Set ziel = ThisWorkbook.Sheets("Tabelle1") 'Zieltabelle - anpassen
strPath = BrowseFolder("Ordner Auswählen", "C:/Eigene Dateie/Ordner")
If strPath = "" Then Exit Sub
With Application
.ScreenUpdating = False
.EnableEvents = False
.DisplayAlerts = False
.Calculation = xlCalculationManual
End With
iCol = 2
Set fSearch = Application.FileSearch
With fSearch
.LookIn = strPath
.SearchSubFolders = False '<<<<Unterordner durchsuchen True/False
.FileType = msoFileTypeExcelWorkbooks
.Execute
For iCnt = 1 To .FoundFiles.Count
Set wkb = Workbooks.Open(.FoundFiles(iCnt))
On Error GoTo ERRORHANDLER
Set wks = wkb.Sheets("Data")
With ziel
.Range(.Cells(1, iCol), .Cells(50, iCol)).Value = wks.Range("A1:A50").Value
End With
iCol = iCol + 1
ERRORHANDLER:
wkb.Close False
On Error GoTo 0
Next
End With
With Application
.ScreenUpdating = True
.EnableEvents = True
.DisplayAlerts = True
.Calculation = xlCalculationAutomatic
End With
End Sub
Gruß Sepp

Beliebteste Forumthreads (12 Monate)

im Ordner alle Dateien durchlaufen und bearbeiten

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread