Verweis beim Öffnen automatisch aktivieren?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo,
wechen dem Archiv stelle ichs doch hier rein.
In jeder Datei wird der Verweis auf MS Forms2.0 gesetzt, dafür steht dieser GUID-Ausdruck. Es geht auch mit Verweis setzen auf eine xla, dll usw, aber weiß grad nihct wie da die Syntax ist. Wäre nett wenn dass jmd umschreibt oder mitteilt wie/wo man die GUID Nummer für den Verweis von Kasimir herausbekommt.
Code steht in Personl.xls, man braucht ein Klassenmodul dass clsApplication heißt.
Warum auch immer war ne Zeitlang immer die Berechnung auf manuell gestellt, hatte nie rausgefunden warum das passiert, jedenfalls seitdem ich das mit reinschrieb ist das Problem weg, deshalbb das mit Calculation im Code.
Diese Arbeitsmappe

Option Explicit
Private objApplication As clsApplication
Private Sub Workbook_Open()
'Application.Caption = "Reinhard"
Set objApplication = New clsApplication
Set objApplication.prpApplication = Application
End Sub

Modul1

Option Explicit
Private Const FM20_GUID = "{0D452EE1-E08F-101A-852E-02608C4D0BB4}"
Public Sub prcAddReverence(objWorkbook As Workbook)
Dim intIndex As Integer
Dim blnFound As Boolean
On Error GoTo err_exit
With objWorkbook.VBProject.References
For intIndex = 1 To .Count
If .Item(intIndex).GUID = FM20_GUID Then
If .Item(intIndex).IsBroken Then
.Remove .Item(intIndex)
Else
blnFound = True
End If
End If
Next
If Not blnFound Then _
.AddFromGuid GUID:=FM20_GUID, Major:=2, Minor:=0
End With
objWorkbook.Application.Calculation = xlCalculationAutomatic
Exit Sub
err_exit:
MsgBox "Fehler " & CStr(Err.Number) & vbLf & _
vbLf & Err.Description, vbCritical, "Fehler"
End Sub

clsApplication

Option Explicit
Private WithEvents mobjApplication As Application
Public Property Set prpApplication(objApplication As Application)
Set mobjApplication = objApplication
End Property
Private Sub mobjApplication_NewWorkbook(ByVal Wb As Workbook)
Call prcAddReverence(Wb)
End Sub
Private Sub mobjApplication_WorkbookOpen(ByVal Wb As Workbook)
Call prcAddReverence(Wb)
End Sub

Gruß
Reinhard
ps: Ich freue mich über eine Rückmeldung ob diese Antwort hilfreich war oder nicht..

Hallo Kasimir
In der Registry kannst du auch rumwurschteln ohne den Verweis mit addFromFile zu setzen.
Schau dir das hier mal an:

Sub Create_Specific_RegKey()
'(C) by Ramses
Dim MyWSH As Object, myNewRegKey As String
Dim myRegResKey As String, myRegToWriteKey As String
Set MyWSH = CreateObject("WScript.Shell")
'Es wird ein spezifischer Schlüssel in DEM Registryzweig angelegt,
'der normalerweise auch von EXCEL aus mit Get- und SaveSetting erreicht werden kann
'Mit WSH kann jedoch die gesamte Registry beschrieben,
'verändert und gelesen werden
'Hier wird zu Beispielzwecken NUR ein Unterschlüssel DemoWSH Script mit Unterschlüssel Setting
'und dem Wert "Wert1" erstellt
myNewRegKey = "HKEY_CURRENT_USER\Software\VB and VBA Program Settings\DemoWSH Script\Setting\Wert1"
'Dem zu erstellen Schlüssel wird der Wert 100 zugewiesen
MyWSH.regWrite myNewRegKey, "100"
End Sub
Sub Read_Specific_RegKey()
'(C) by Ramses
Dim MyWSH As Object, myReadRegKey As String
Dim myRegResKey As String
'WSH Object erstellen
Set MyWSH = CreateObject("WScript.Shell")
'Es muss auch der Unter-Eintrag im Key angegeben werden
'hier die 1
myReadRegKey = "HKEY_CURRENT_USER\Software\VB and VBA Program Settings\DemoWSH Script\Setting\Wert1"
myRegResKey = MyWSH.regread(myReadRegKey)
MsgBox "Aktueller Wert:" & myRegResKey
End Sub
Sub Change_Specific_RegKey()
'(C) by Ramses
Dim MyWSH As Object, myReadRegKey As String
Dim myRegResKey As String, myRegToWriteKey As String
Set MyWSH = CreateObject("WScript.Shell")
'Es muss auch der Unter-Eintrag im Key angegeben werden
'hier "Wert1"
myReadRegKey = "HKEY_CURRENT_USER\Software\VB and VBA Program Settings\DemoWSH Script\Setting\Wert1"
myRegResKey = MyWSH.regread(myReadRegKey)
MsgBox "Aktueller Wert:" & myRegResKey
myRegToWriteKey = InputBox("Neuen Wert bitte eintragen:", "Registry Wert ändern", myRegResKey + 10)
If Not IsNumeric(CDbl(myRegToWriteKey)) Then
MsgBox "Der Wert muss eine Zahl sein"
Exit Sub
End If
MyWSH.regWrite myReadRegKey, myRegToWriteKey
End Sub

ransi

Beliebteste Forumthreads (12 Monate)

Verweis beim Öffnen automatisch aktivieren?

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Verweis beim Öffnen automatisch aktivieren?

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread