Excel und VBA: Formeln, Programmierung, Lösungen

Die Excel/VBA-Beispiele

Bewerten Sie hier bitte das Excel-Portal

Home Zurück Vor

Download Beispiel-Arbeitsmappe

Thema

Zellkontextmenü ein Neues Menü mit Datum & Zeit hinzufügen

Gruppe

Context

Problem

Wie kann ich dem Zellkontextmenü ein neues Menü mit einer Abrufmöglichkeit für Datum und Zeit hinzufügen? Das Menü soll nur in der aktuellen Arbeitsmappe wirksam sein.

Lösung

Geben Sie den Ereigniscode in das Klassenmodul der Arbeitsmappe ein.

ClassModule: DieseArbeitsmappe

Private Sub Workbook_Activate()
   Dim oPopUp As CommandBarControl
   Dim oBtn As CommandBarButton
   Call CmdDelete
   Set oPopUp = Application.CommandBars("Cell"). _
      Controls.Add(msoControlPopup, before:=1)
   oPopUp.Caption = "Datum und Zeit"
   Set oBtn = oPopUp.Controls.Add
   With oBtn
      .Caption = "Datum"
      .OnAction = "DatumErmitteln"
      .Style = msoButtonIconAndCaption
      .FaceId = 1094
   End With
   Set oBtn = oPopUp.Controls.Add
   With oBtn
      .Caption = "Zeit"
      .BeginGroup = True
      .OnAction = "ZeitErmitteln"
      .Style = msoButtonIconAndCaption
      .FaceId = 33
   End With
End Sub

Private Sub Workbook_Deactivate()
   Call CmdDelete
End Sub

StandardModule: basMain

Sub DatumErmitteln()
   MsgBox Date
End Sub

Sub ZeitErmitteln()
   MsgBox Time
End Sub

Sub CmdDelete()
   On Error GoTo ERRORHANDLER
   Application.CommandBars("Cell").Controls("Datum und Zeit").Delete
ERRORHANDLER:
End Sub