HERBERS Excel-Forum - die Beispiele

Thema: Dateiliste mit allen xl-Dateien und Hyperlinks erstellen

Home

Gruppe

Datei

Problem

Zu dem in Zelle B1 genannten Laufwerk bzw. Pfad soll eine Liste aller Excel-Dateien mit Größe, Hyperlink und Aktualisierungsdatum erstellt werden.

Lösung
Geben Sie den nachfolgenden Code in ein Standardmodul ein und weisen Sie ihn einer Schaltfläche zu.
StandardModule: Modul1

Sub CreateFileList()
   Dim wks As Worksheet
   Dim iCounter As Integer, iCount As Integer
   Dim sSource As String, sTxt As String
   Application.ScreenUpdating = False
   Rows(5).Hidden = False
   sSource = Range("Source").Value
   If Len(sSource) = 1 Then
      sSource = sSource & ":\"
   End If
   Workbooks.Add 1
   Set wks = ActiveSheet
   ThisWorkbook.Activate
   Application.ScreenUpdating = True
   wks.Columns("A:B").NumberFormat = "@"
   wks.Columns("C").NumberFormat = "#,##0"
   wks.Range("A1").Value = "LfdNr."
   wks.Range("B1").Value = "Dateiname"
   wks.Range("C1").Value = "Dateigröße"
   wks.Range("D1").Value = "Dateidatum"
   With wks.Range("A1:D1")
      .Font.Bold = True
      .Interior.ColorIndex = 1
      .Font.ColorIndex = 2
   End With
   With Application.FileSearch
      .NewSearch
      .LookIn = sSource
      .Filename = "*.xl*"
      .SearchSubFolders = True
      .Execute
      iCount = .FoundFiles.Count
      For iCounter = 1 To iCount
         If iCounter Mod 100 = 0 Then Range("D5").Value = _
            "Bearbeite Datei Nr. " & iCounter & "..."
         wks.Cells(iCounter + 1, 2).Value = .FoundFiles(iCounter)
         wks.Hyperlinks.Add _
            anchor:=wks.Cells(iCounter + 1, 2), _
            Address:=.FoundFiles(iCounter)
         wks.Cells(iCounter + 1, 3).Value = FileLen(.FoundFiles(iCounter))
         wks.Cells(iCounter + 1, 4).Value = FileDateTime(.FoundFiles(iCounter))
      Next iCounter
   End With
   Application.ScreenUpdating = False
   wks.Range("A1").CurrentRegion.Sort _
      key1:=wks.Range("B2"), order1:=xlAscending, header:=xlYes
   For iCounter = 2 To iCount + 1
      wks.Cells(iCounter, 1).Value = Format(iCounter - 1, "0000")
   Next iCounter
   Rows(5).Hidden = True
   wks.Columns.AutoFit
   wks.Columns("E:IV").Hidden = True
   wks.Rows(iCounter & ":" & Rows.Count).Hidden = True
   wks.Name = "Dateiliste"
   Windows(wks.Parent.Name).DisplayHeadings = False
   wks.Parent.Activate
End Sub

Beiträge aus dem Excel-Forum zu den Themen Datei und Verzeichnis

Excel/PDF Datei unter bestimmten Pfad abspeichern aus excel Worddatei nach Wert durchsuchen
Split-Funktion beim Einlesen TXT-Datei Datei löschen mit unterschiedlichen Zahlen im Name
Datei löschen mit unterschiedlichen Zhalen im Name geöffnete Worddatei und Word aus Excel beenden
Excel-Datei nicht im Projekt-Explorer Suche nach jüngster Datei
Mehrere Zellen in mehreren Dateien ersetzen Datei öffnen mit variablen im Namen
Vergleichen zweier Dateien und aktualisieren Datei langsam durch Formel
Dateien aus Unterordner öffnen Daten import aus txt--Datei
Dateipfad öffnen mit VBA Datei-Verknüpfungen
Masterdatei erschaffen? Mehrere Datenblätter als PDF-Datei ausgeben
Makro bei Erstellen einer Datei aus einer Vorlage Zusammenführung aus mehreren Dateien
Rechteck per Button in andere Datei einfügen. Alle Dateien in einem Unterordner öffnen
VBA: MsgBox: yes/no. Bei yes andere Datei öffnen Mehrere txt Dateien einlesen in ein Programm
VBA Datei als .txt speichern Excel Datei in CSV Datei wandeln mit Extras
aktierten Text in geöffnete Worddatei Spalte in andere Dateien kopieren + zurückkopieren
Aus einer CSV-Datei ein bestimmtes Layout erzeugen Daten ausgew. WS in 2. Datei zusammenführen
VBA Links im Verzeichnis auslesen Per VBA aktuelle Datei in Autostart-Ordner
csv Dateien importieren Makrodatei als Software hochwertiger gestalten
manuelles Speichern bei schreibgeschützter Datei Daten aus geschlossener Datei in Zieldatei kopiere
Dateinamen per VBA vorgeben (Datum: Vormonat) Ordner mit Unterordnern/Dateien kopieren
Ein Verzeichnis per VBA löschen Auswertung über mehrere Dateien
Geschlossene Excel-Datei bearbeiten? datei öffnen durch vba ohne makroaktivierung
Datei öffnet im Entwurfsmodus Dateinamen der ausgelesenen Datei anzeigen
Dateien vergleichen-doppelte löschen Datendatei per Doppelklick einlesen
Hyperlink auf Excel-Datei funktioniert nicht Kopieren über 2 Dateien?
Dateiinfo aller Dateien in allen Verz./Unterverz