Argumenttyp byRef unverträglich

Tobias · 2009-03-13T18:01:33+00:00

Hallo allerseits, wieso klappt das ohne probleme: WaitShell ftp_command, vbMinimizedNoFocus, 120, True wohingegen dies hier dim showshell as string showshell = vbMinimizedNofocus WaitShell ftp_command, showshell, 120, True zum Fehler führt (siehe Betreff) Hab auch schon versucht als variant zu definieren, bzw. unter anführungszeichen zu setzen, keine änderung. any help?

Hi Tino,
Im Prinzip stimmt die Erkärung so. ByRef ist nix anderes wie ein Zeiger auf die 'MemoryPosition', gibt also dem Empfänger direkt die Möglichkeit in diese zu schreiben. ByVal es wird der Wert übergeben und dieser in der lokalen Prozedur an einen neue 'MemoryPosition' geschrieben.
Kleine Demo:


Sub X()
Dim xy As String
xy = "HELLO WORLD"
MsgBox "Calling Y [byVal] with:" & xy, vbOKOnly, "Sub X"
Call Y(xy)
MsgBox "Return from Y is now:" & xy, vbOKOnly, "Sub X"
MsgBox "Calling Z [byRef] with:" & xy, vbOKOnly, "Sub X"
Call Z(xy)
MsgBox "Return from Z is now:" & xy, vbOKOnly, "Sub X"
End Sub
Sub Y(ByVal xy As String)
MsgBox "xy is now: " & xy & vbCrLf & _
"will be set to: HELLO MOON", vbOKOnly, "Sub Y"
xy = "HELLO MOON"
End Sub
Sub Z(ByRef xy As String)
MsgBox "xy is now: " & xy & vbCrLf & _
"will be set to: HELLO MOON", vbOKOnly, "Sub Z"
xy = "HELLO MOON"
End Sub

GreetZ Renée

Hallo Tino,
das ist schon richtig so!!!
ByRef übergibt der aufgerufenen Prozedur die Speicheradresse der Variablen. ByVal legt eine neue Varianble an, in welche der Wert geschrieben wird. Konstanten werden aber trotz ByRef und Änderung in der aufgerufenen Prozedur, in der Aufrufenden Prozedur nicht geändert. Konstanten werden anscheinend automatisch ByVal übergeben auch wenn ich es anders angegebe.

Public Sub Test1()
    Const Konstante = 1
    Call Test2(Konstante)
End Sub

Public Sub Test2(ByRef Wert As Long)
    Wert = 999
End Sub

Du kannst übrigens die Typenkonvertierung auch erzwingen:

Public Sub Test1()
    Dim strVariable As String
    strVariable = "1"
    Call Test2((strVariable))
End Sub

Public Sub Test2(ByRef lngWert As Long)
    Debug.Print lngWert
End Sub

Das hat allerdings zur Folgen, dass eine solche Übergabe wieder automatisch ByVal erfolgt:

Public Sub Test1()
    Dim lngVariable As Long
    Call Test2((lngVariable))
    Debug.Print lngVariable
    Call Test2(lngVariable)
    Debug.Print lngVariable
End Sub

Public Sub Test2(ByRef Wert As Long)
    Wert = 999
End Sub

Da ist noch viel Dunkel wo gleißendes Licht sein sollte.
Gruß
Nepumuk

Forumthread: Argumenttyp byRef unverträglich

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial