Wörter trennen

Forumthread: Wörter trennen

Wörter trennen

17.04.2009 13:59:04

Hirschi

Hallo zusammen
In meiner Zelle A1 steht folgendes drin:
MaxMustermann
Ich möchte dies zu:
Max Mustermann
ändern.
Kennt jemand ne Funktion dafür? Es soll also einfach vor dem zweiten Großbuchstaben ein Leerzeichen eingefügt werden.
Wäre super, wenn mir jemand helfen könnte, vielen Dank!
Gruss

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Wörter trennen

17.04.2009 14:18:20

hary
AW: Wörter trennen

17.04.2009 14:28:05

David
AW: Wörter trennen

17.04.2009 14:36:44

Hirschi
Du solltest Boris' Lösung beachten,...

18.04.2009 00:51:14

Luc:-?
OT Nachfrage

18.04.2009 01:12:01

Reinhard
Das bezieht sich natürlich nur auf MxFml,...

18.04.2009 01:24:28

Luc:-?
AW: Wörter trennen

17.04.2009 22:45:29

{Boris}

AW: Wörter trennen

17.04.2009 14:18:20

hary

Hi Hirschi
Formel von WF. Matrixformel abschliessen mit strg+shift+enter
Tabellenblattname: Tabelle1

	A	B
1	MaxMustermann	Max Mustermann

Benutzte Formeln:
B1: =WECHSELN(A1;ZEICHEN(MIN(CODE(TEIL(A1;ZEILE(INDIREKT("2:"&LÄNGE(A1)));1)))); " "&ZEICHEN(MIN(CODE(TEIL(A1;ZEILE(INDIREKT("2:"&LÄNGE(A1)));1)))))
Gruss hary

AW: Wörter trennen

17.04.2009 14:28:05

David

Hallo Hirschi,
das geht so:
Tabelle1

	A	B	C
1	MaxMustermann	Max	Mustermann

Zelle	Formel
B1	{=LINKS(A1;MAX(WENN(ZEILE(2:99)>LÄNGE(A1);0;IDENTISCH(TEIL($A$1;ZEILE(2:99);1);GROSS(TEIL($A$1;ZEILE(2:99);1)))*ZEILE(2:99)))-1)}
C1	{=TEIL(A1;MAX(WENN(ZEILE(2:99)>LÄNGE(A1);0;IDENTISCH(TEIL($A$1;ZEILE(2:99);1);GROSS(TEIL($A$1;ZEILE(2:99);1)))*ZEILE(2:99)));99)}

{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren

Rückmeldung wäre nett.
Gruß
David

AW: Wörter trennen

17.04.2009 14:36:44

Hirschi

passt!
danke auch

Du solltest Boris' Lösung beachten,...

18.04.2009 00:51:14

Luc:-?

...Hirschi,
die ist universeller...!
Noch kürzer (zumindest in einer 1Zellenlösung ala Hary, aber dafür universal wie Boris' Variante) ist...
=LINKS(A1)&WECHSELN(TEIL(A1;2;LÄNGE(A1));TEIL(MaskOn(A1;"gb");SUCHEN(" ";MaskOn(A1;"gb"))+1;1);
" "&TEIL(MaskOn(A1;"gb");SUCHEN(" ";MaskOn(A1;"gb"))+1;1);1)
...ausdrücklich keine Matrixfml! Würde auch mit meiner udFkt MaskOn, die hier in älterer Version noch irgendwo im Archiv rumschwirren muss, nicht gehen.
Gruß Luc :-?

OT Nachfrage

18.04.2009 01:12:01

Reinhard

Hallo Luc,
du sagst, die Lösung von Boris ist universeller, okay.
Dann präsentierst du eine Formel die noch kürzer und universal ist, okay.
In der Formel benutzt du die BDF MaskeOn und sagst: würde auch mit dieser BDF NICHT gehen.
Verwirrte Grüße
Reinhard
..Hirschi,
die ist universeller...!
Noch kürzer (zumindest in einer 1Zellenlösung ala Hary, aber dafür universal wie Boris' Variante) ist...
=LINKS(A1)&WECHSELN(TEIL(A1;2;LÄNGE(A1));TEIL(MaskOn(A1;"gb");SUCHEN(" ";MaskOn(A1;"gb"))+1;1);
" "&TEIL(MaskOn(A1;"gb");SUCHEN(" ";MaskOn(A1;"gb"))+1;1);1)
...ausdrücklich keine Matrixfml! Würde auch mit meiner udFkt MaskOn, die hier in älterer Version noch irgendwo im Archiv rumschwirren muss, nicht gehen.
Gruß Luc :-?

Das bezieht sich natürlich nur auf MxFml,...

18.04.2009 01:24:28

Luc:-?

...Reinhard... ;-)
MaskOn ist schlicht nicht matrixformelfähig, würde dann FWert liefern, aber ich hab sie ja auch nicht in einer MxFml verwendet!
Wohl doch schon'n bissken spät - Gutnacht!
Luc :-?

AW: Wörter trennen

17.04.2009 22:45:29

{Boris}

Hi,
die bisherigen Lösungen gehen bei Doppelnamen wie MaxMustermann-Meier in die Hose.
Daher sollte man nur nach dem ersten Großbuchstaben suchen und den Rest unverändert übernehmen. Mein Vorschlag daher (in A1 steht der Name):
B1 (Vorname - Achtung: Array!):
{=LINKS(A1;MIN(WENN(CODE(TEIL(A1;SPALTE($1:$1)+1;1)&" ")<91;SPALTE($1:$1))))}
C1 (Nachname):
=TEIL(A1;LÄNGE(B1)+1;99)
Grüße Boris

Beliebteste Forumthreads (12 Monate)

Forumthread: Wörter trennen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread