HERBERS Excel-Forum - das Archiv
Bewerten Sie hier bitte das Excel-Portal
alles groß in spalte
Ralf

Hallo gibt es eine möglichkeit das in dem bereich F 16 -F120 nur groß geschrieben wird bei format habe ich nichts gefunden
gruß Ralf

..schau in die schriftarten-owT
robert

AW: ..schau in die schriftarten-owT
Ralf

Also ich kann bei mir keine schriftart finden, die nur groß schreibt wie heißt die denn
und was heißt owT ?
gruß Ralf
AW: ..schau in die schriftarten-owT
robert

hi,
hast du die schriftart
Felix Titling ?
und owT bedeutet ohne weiteren Text
gruß
robert
..sorry, vergiss es... owT
robert

und ich wollte schon ... ;o) oT
Matthias

und was :-) wolltest du...owT
robert

AW: alles groß in spalte
Josef

Hallo Ralf,
nur per VBA.
' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rng As Range
  
  On Error GoTo ErrExit
  
  If Not Intersect(Target, Range("F16:F120")) Is Nothing Then
    Application.EnableEvents = False
    For Each rng In Intersect(Target, Range("F16:F120"))
      rng = UCase(rng)
    Next
  End If
  
  ErrExit:
  Application.EnableEvents = True
End Sub

Gruß Sepp

AW: alles groß in spalte
Ralf

Hallo
in einem leeren blatt klappt es super
nur wenn ich es in dem blatt einfügen möchte kommt dann eine fehlermeldung
Mehrdeutiger Name Worksheet- change
da habe ich auch schon ein anderes makro weiß nicht ob es daran liegen kann vba habe ich kein plan von
vielleicht oder besser gesagt mit sicherheit wisst ihr wo der wurm ist
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim rng As Range
On Error GoTo ErrExit
If Not Intersect(Target, Range("F16:F120")) Is Nothing Then
Application.EnableEvents = False
For Each rng In Intersect(Target, Range("F16:F120"))
rng = UCase(rng)
Next
End If
ErrExit:
Application.EnableEvents = True
End Sub


Private Sub Worksheet_Change(ByVal Target As Excel.Range)
'* H. Ziplies                                     *
'* 29.12.09                                       *
'* erstellt von HajoZiplies@WEB.de                *
'* http://Hajo-Excel.de
Dim RaBereich As Range, RaZelle As Range
Dim InS As Integer
Dim InM As Integer
' Bereich der Wirksamkeit
Set RaBereich = Range("C12:D120")
'ActiveSheet.Unprotect
Application.EnableEvents = False
Set RaBereich = Intersect(RaBereich, Range(Target.Address))
If Not RaBereich Is Nothing Then
For Each RaZelle In Range(Target.Address)
With RaZelle
If .Value <> "" Then
If IsNumeric(.Value) And InStr(.Value, ":") = 0 Then
.NumberFormat = "[hh]:mm"
If InStr(RaZelle, ",") > 0 Then
InS = Left(RaZelle, InStr(RaZelle, ",") - 1)
InM = Left(Mid(RaZelle & "0", InStr(RaZelle, ",") + 1), 2)
Else
InS = RaZelle
End If
.Value = InS & ":" & InM
End If
End If
End With
Next RaZelle
End If
'ActiveSheet.protect
Application.EnableEvents = True
Set RaBereich = Nothing
End Sub

AW: alles groß in spalte
Josef

Hallo Ralf,
' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
  '**************************************************
  '* H. Ziplies *
  '* 29.12.09 *
  '* erstellt von HajoZiplies@WEB.de *
  '* http://Hajo-Excel.de
  
  
  '**************************************************
  Dim RaBereich As Range, RaZelle As Range
  Dim InS As Integer
  Dim InM As Integer
  
  
  On Error GoTo ErrExit
  Application.EnableEvents = False
  
  If Not Intersect(Target, Range("F16:F120")) Is Nothing Then
    For Each RaZelle In Intersect(Target, Range("F16:F120"))
      RaZelle = UCase(RaZelle)
    Next
  End If
  
  ' Bereich der Wirksamkeit
  Set RaBereich = Range("C12:D120")
  'ActiveSheet.Unprotect
  Set RaBereich = Intersect(RaBereich, Range(Target.Address))
  If Not RaBereich Is Nothing Then
    For Each RaZelle In Range(Target.Address)
      With RaZelle
        If .Value <> "" Then
          If IsNumeric(.Value) And InStr(.Value, ":") = 0 Then
            .NumberFormat = "[hh]:mm"
            If InStr(RaZelle, ",") > 0 Then
              InS = Left(RaZelle, InStr(RaZelle, ",") - 1)
              InM = Left(Mid(RaZelle & "0", InStr(RaZelle, ",") + 1), 2)
            Else
              InS = RaZelle
            End If
            .Value = InS & ":" & InM
          End If
        End If
      End With
    Next RaZelle
  End If
  'ActiveSheet.protect
  ErrExit:
  Application.EnableEvents = True
  Set RaBereich = Nothing
End Sub

Gruß Sepp

Danke dafür
Ralf

Danke
Mit besten grüßen aus Damme