Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1164to1168
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Zusammenführen von PDF Files

Zusammenführen von PDF Files
PDF
Hallo alle zusammen,
wieder mal brauche ich eure Hilfe. Ich bin auf der Suche nach folgendemn Problem:
Ab Zelle A2 stehen Dateinamen (alle PDFs, A2:A140) und ab B2 ebenfalls alle PDFs (B2:B140).
Nun würde ich gerne die beiden einzelne Pdf-Dokumente zusammenfügen.
Habe mir bereits PDFCreator installiert und PDFTK Builder. Im Netz konnte ich nichts finden.
Ich denk mal sowas müsste es doch geben oder? Habe ebenfalls die Vollversion von Adobe Acrobat (glaub die 8)
Vielen Dank und LG
Urmila
AW: Zusammenführen von PDF Files
05.07.2010 17:06:38
PDF
Hallo Urmila,
probier sowas:
Code:

Option Explicit
Sub multidoc()
  Dim fso As Object, WshShell As Object  
  Dim strOrdner As String, i As Long    
  Dim strMulti As String, strCommand As String, strGS As String  
  Set fso = CreateObject("Scripting.FileSystemObject")  
 'Pfad zu gswin32c.exe anpassen
  strGS = "C:\Programme\Textbearbeitung\Ghostscript\gs8.53\bin\gswin32c.exe"
 'Ausgabeordner anpassen
  strOrdner = "E:\Temp"
  With Tabelle1  'anpassen
   'Spalte A : Dateinamen mit komplettem Pfad
   'Spalte B : Dateinamen mit komplettem Pfad
    For i = 1 To .UsedRange.Rows.Count  
      If fso.FileExists(.Cells(i, 1).Value) And fso.FileExists(.Cells(i, 2).Value) Then  
        strMulti = " " & .Cells(i, 1).Value & " " & .Cells(i, 2).Value
        strOrdner = fso.getfolder(strOrdner).ShortPath
        strGS = fso.GetFile(strGS).ShortPath
        strCommand = strGS & " -q -dSAFER -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile="
        strCommand = strCommand & strOrdner & "\"
       'Name der Ausgabedatei = Name der Datei in der Spalte A
        strCommand = strCommand & fso.GetFile(.Cells(i, 1).Value).Name & strMulti
        Set WshShell = CreateObject("WScript.Shell")  
        WshShell.Run strCommand, 0, True
        Set WshShell = Nothing  
      End If  
    Next
  End With  
  Set fso = Nothing  
  MsgBox "Fertig"
End Sub  


mfg Anton
Anzeige
AW: Zusammenführen von PDF Files
05.07.2010 20:58:26
PDF
Hallo Anton,
erst mal lieben Dank für Rückmeldung.
Ich habe Ghostscript installiert, habe sämtliche Pfade im Tabellenblatt und Skript angepasst. Er macht was, aber nicht was gewünscht. In Zelle A2 steht die Datei E:\Temp\001.pdf und in Zelle B2 die Datei E:\Temp\002.pdf
Nach dem Auslösen des Skripts ist der Inhalt der Datei 002.pdf = 001.pdf, also die Datei in Zelle B wird mit der Datei in Zelle A überschrieben...
Hmmm.....sieht aber schon richtig aus oder?
Danke und LG
Urmila
AW: Zusammenführen von PDF Files
05.07.2010 21:12:42
PDF
Hallo Urmila,
versuch mal als Ausgabeordner einen Ordner anzugeben , der nicht deine pdf's enthält(z.B. C:\Temp\Ausgabe).
Der Ordner muss aber existieren.
mfg Anton
Anzeige
AW: Zusammenführen von PDF Files
06.07.2010 08:00:14
PDF
Hallo Anton,
ich habs versucht bzw einen Ordner angelegt, nichts tut, immer noch das selbe. Versuchs gleich nochmals, aber muss ich noch den Ausgabepfad nicht im Skript eingeben?
LG
Urmila
AW: Zusammenführen von PDF Files
06.07.2010 14:38:44
PDF
Hallo Urmila,
muss ich noch den Ausgabepfad nicht im Skript eingeben?
ja,musst du:
'Ausgabeordner anpassen
strOrdner = "C:\Temp\Ausgabe"
mfg Anton
AW: Zusammenführen von PDF Files
06.07.2010 15:39:17
PDF
Hi Anton,
ja da habe ich auch schon bereits getan....es war ne blöde Frage (weiß ich) da es im Code ja bereits drauf hingewiesen wurde, den Pfad anzupassen....was ich ja auch gemacht hatte
Nur jetzt macht er eine leere Seite in dem Ausgabeordner......
LG
Urmila
Anzeige
AW: Zusammenführen von PDF Files
06.07.2010 15:48:46
PDF
Hallo Urmila,
kannst du eine Beispieldatei mit dem Code hochladen?
mfg Anton
AW: Zusammenführen von PDF Files
06.07.2010 21:56:18
PDF
Hallo Urmila,
kann es sein das deine pdf's in Namen Leerzeichen haben?
wenn ja, dann so:
Code:

Option Explicit
Sub multidoc()
  Dim fso As Object, WshShell As Object  
  Dim strOrdner As String, i As Long    
  Dim strMulti As String, strCommand As String, strGS As String  
  Set fso = CreateObject("Scripting.FileSystemObject")  
 'Pfad zu gswin32c.exe anpassen
  strGS = "C:\Programme\Textbearbeitung\Ghostscript\gs8.53\bin\gswin32c.exe"
 'Ausgabeordner anpassen
  strOrdner = "E:\Temp\Simon test"
  With Tabelle1   'anpassen
   'Spalte A : Dateinamen mit komplettem Pfad
   'Spalte B : Dateinamen mit komplettem Pfad
    For i = 2 To .UsedRange.Rows.Count  
      If fso.FileExists(.Cells(i, 1).Value) And fso.FileExists(.Cells(i, 2).Value) Then  
        strMulti = " " & Chr(34) & .Cells(i, 1).Value & Chr(34) & " " & Chr(34) & .Cells(i, 2).Value & Chr(34)
        strOrdner = fso.getfolder(strOrdner).ShortPath
        strGS = fso.GetFile(strGS).ShortPath
        strCommand = strGS & " -q -dSAFER -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile=" & Chr(34)
        strCommand = strCommand & strOrdner & "\"
       'Name der Ausgabedatei = Name der Datei in der Spalte A
        strCommand = strCommand & fso.GetFile(.Cells(i, 1).Value).Name & Chr(34) & strMulti
        Debug.Print strCommand
        Set WshShell = CreateObject("WScript.Shell")  
        WshShell.Run strCommand, 0, True
        Set WshShell = Nothing  
      End If  
    Next
  End With  
  Set fso = Nothing  
  MsgBox "Fertig"
End Sub  


mfg Anton
Anzeige
AW: Zusammenführen von PDF Files
07.07.2010 08:57:00
PDF
Hallo Anton,
habe die Leerstellen (Ordnername und PDF-Files) rausgenommen aber trotzedem tut es nichts machen.
Macht es eigentlich bei dir das zusammenführen?
Danke und LG
Urmila
AW: Zusammenführen von PDF Files
07.07.2010 15:43:58
PDF
Hallo Urmila,
Macht es eigentlich bei dir das zusammenführen?

Ja.
Starte den letzten Code und guck im Direktfenster , ob da was passiert.
Wenn ja , dann poste hier paar Zeilen daraus, wenn nicht , dann passen deine Pfade nicht.
mfg Anton
AW: yahhhooooooo..... :)
07.07.2010 19:32:18
Urmila
Hi Anton,
habe soeben den neuen Code eingefügt und nochmals probiert und nochmals und nochmals.....und es klapppt wuuuuuuunderbaaaar.....endlich
Vielen lieben herzlichen Dank A N T O N ......
Danke und LG
Urmila
Anzeige
wobei noch eine Frage zur Interesse...
07.07.2010 19:37:42
Urmila
Hi Anton,
sooooorry....wollte aber nur mal gerne Fragen, wenn es ja die Möglichkeit besteht Dokumente zusammenzuführen, geht es auch wenn man die Seite löschen will, bzw bestimmte Seiten oder verschieben will.
Oder könntest du mir verraten wie man den Code ändern müsste für verschd. Aktionen?
Bittte....vielen Dank und Gruß
Urmila

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige