Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1184to1188
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Runde Geburtstage

Runde Geburtstage
Mat
Hallo Leute,
ich würde gerne meine nachfolgende Geburtstagsformel ausbauen.
=WENN(REST(JAHR(HEUTE())-JAHR(C7);10)=9;B7&" " &"wird nächstes Jahr " & JAHR(HEUTE())-JAHR(C7) +1 & ". Jahre alt";"")
Mein Problem ist, dass ich auch noch die 65, 75 und 85 jährigen anzeigen lassen möchte.
Wer kann helfen?
Gruß Mat
AW: Runde Geburtstage
08.11.2010 15:21:55
Markus
Hallo Mat,
was steht in B7 und C7?
Bitte Datei hochladen
Markus
AW: Runde Geburtstage
08.11.2010 15:26:42
Mat
Hallo Markus,
B7 = Name
C7 = Geburtsdatum
Gruß Mat
AW: Runde Geburtstage
08.11.2010 15:36:58
Ralf_P
Hallo Markus,
dazu dient
REST(Zahl;Divisor)
Also in einer Zelle Eingeben =WENN(REST(Geburtstagszahl;5)=0;Geburtstagszahl;"")
Gruß Ralf
Runde Geburtstage - etwas einfacher
08.11.2010 16:01:47
Erich
Hi Markus,
aus deiner Lösung habe ich das hier gemacht:
 C
2Franz wird nächstes Jahr 110 Jahre alt
3 
4 
5 
6 
7Markus wird nächstes Jahr 105 Jahre alt

Formeln der Tabelle
ZelleFormel
C2=WENN(REST(JAHR(HEUTE())-JAHR(B2); 5)=4;A2&" wird nächstes Jahr "&JAHR(HEUTE())-JAHR(B2)+1&" Jahre alt";"")

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: Runde Geburtstage - etwas einfacher
08.11.2010 16:10:55
Markus
Hallo Erich,
bei mir steht ja auch bei VBA erst bescheiden und bei Excel gut.
Ich versuche aber alles, dass ich in die Stufe VBA - gut, Excel - Profi aufsteigen kann.
Aber auf Deine Idee hätte ich auch kommen können.
Markus
AW: Runde Geburtstage - etwas einfacher
08.11.2010 16:18:32
Mat
Hallo Markus,
jetzt war ich zu schnell.
Formel funktioniert zwar, aber ich habe auch die unter 50 jährigen 5er mit dabei. Ich brauche nur 65, 75, 85 jährigen.
Gruß Mat
AW: Runde Geburtstage - etwas einfacher
08.11.2010 16:35:39
KlausF
Hallo Mat,
in C2:
=WENN(JAHR(HEUTE())-JAHR(B2)+1<=49;"";WENN(REST(JAHR(HEUTE())-JAHR(B2);10)=9; A2&" "&"wird nächstes Jahr "&JAHR(HEUTE())-JAHR(B2)+1&". Jahre alt";"")&WENN(REST(JAHR(HEUTE()) -JAHR(B2);10)=4;A2&" "&"wird nächstes Jahr "&JAHR(HEUTE())-JAHR(B2)+1&". Jahre alt";""))
und runterkopieren ...
Gruß
Klaus
Anzeige
Runde Geburtstage - noch mal
08.11.2010 18:27:24
Erich
Hi Mat,
das Ganmze wäre etwas einfacher, wenn du genauer beschreiben würdest, was du brauchst.
Hier werden die vollen 10er-Geburtstage und zusätzlich die 5er-Geburtstage ab 55 Jahre ausgegeben:
 C
1Treffer
2Franz wird nächstes Jahr 110 Jahre alt
3 
4 
5 
6 
7Markus wird nächstes Jahr 105 Jahre alt
8 
51 
52Hans wird nächstes Jahr 60 Jahre alt
53 
54 
55 
56 
57Markus wird nächstes Jahr 55 Jahre alt
58 
59 
60 
61 
62Franz wird nächstes Jahr 50 Jahre alt
63 
64 
65 
66 
67 
68 

Formeln der Tabelle
ZelleFormel
C2=WENN((REST(JAHR(HEUTE())-JAHR(B2); 10)=9) +(REST(JAHR(HEUTE())-JAHR(B2); 10)=4)*(JAHR(HEUTE())-JAHR(B2)>50); A2&" wird nächstes Jahr "&JAHR(HEUTE())-JAHR(B2)+1&" Jahre alt";"")

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: wie schnapszahl ?
08.11.2010 23:53:34
hary
Hallo Erich
wie bekomme ich da noch zusaetzlich =wenn Schnapszahl rein.
Bekomme es nicht rein,evtl. schon ein wenig muede.
gruss hary
mit Schnapszahlen
09.11.2010 00:20:58
Erich
Hallo Hary,
probier mal so:
 C
2Franz wird nächstes Jahr 110 Jahre alt
3 
4 
5 
6 
7Markus wird nächstes Jahr 105 Jahre alt
8 
9 
10 
11 
12Franz wird nächstes Jahr 100 Jahre alt
13Markus wird nächstes Jahr 99 Jahre alt
14 
15 
16 
17Fritz wird nächstes Jahr 95 Jahre alt

Formeln der Tabelle
ZelleFormel
C2=WENN((REST(JAHR(HEUTE())-JAHR(B2); 10)=9) +(REST(JAHR(HEUTE())-JAHR(B2); 11)=10) +(REST(JAHR(HEUTE())-JAHR(B2); 10)=4)*(JAHR(HEUTE())-JAHR(B2)>50); A2&" wird nächstes Jahr "&JAHR(HEUTE())-JAHR(B2)+1&" Jahre alt";"")

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: mit Schnapszahlen
09.11.2010 00:31:30
hary
Hallo Erich
Danke
so in der Art hatte ich es auch, nur einen dussliger Muedigkeitsfehler reingebaut.
hatte geschrieben:
REST(JAHR(HEUTE())-JAHR(B2); 11)=<b>0</b>
gruss hary
mit Schnapszahlen - mit Namen kürzer
09.11.2010 00:38:05
Erich
Hallo Hary,
mit einem Namen schreibt (und rechnet) sich die Formel besser. Lege in Zeile 2 den Namen JDiff an,
die Formel steht in der Tabelle:
 CD
1TrefferName JDiff:
2Franz wird nächstes Jahr 110 Jahre alt109

Formeln der Tabelle
ZelleFormel
C2=WENN((REST(JDiff;10)=9)+(REST(JDiff;11)=10)+(REST(JDiff;10)=4)*(JDiff>50); A2&" wird nächstes Jahr "&JDiff+1&" Jahre alt";"")
D2=JAHR(HEUTE())-JAHR(Tabelle1!$B2)

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
mit Schnapszahlen - noch mal kürzer
09.11.2010 00:43:04
Erich
Hi,
oder so:
 CD
1TrefferName JDiff:
2Franz wird nächstes Jahr 110 Jahre alt110

Formeln der Tabelle
ZelleFormel
C2=WENN((REST(JDiff;10)=0)+(REST(JDiff;11)=0)+(REST(JDiff;10)=5)*(JDiff>49); A2&" wird nächstes Jahr "&JDiff&" Jahre alt";"")
D2=JAHR(HEUTE())-JAHR(Tabelle1!$B2)+1

Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
Anzeige
AW: mit Schnapszahlen - noch mal kürzer
09.11.2010 01:13:21
hary
Hallo Erich
Danke nochmal. So kann ich es in meine Geb.-Liste einbauen.
Hat zwar jahrelang ihren Dienst verrichte, aber kann ja auch mal was modernes rein
so sieht sie noch aus.
Tabelle3
 ABCDEFGHIJ
1Januar      Nächste Geburtstag hat am12. NovHeike S.und wird49Jahre alt
2  01.01.1967Olafist 43 Jahre alt           
3  02.01.1969Kisteist 41 Jahre altnoch3Tage     
4  12.01.1961Tipist 49 Jahre alt           

verwendete Formeln
Zelle Formel Bereich
F1 {=INDEX(B1:B100;VERGLEICH(MIN(WENN(B1:B100<>"";REST((MONAT(B1:B100)+TAG(B1:B100)/100-MONAT(HEUTE())-TAG(HEUTE())/100)+0,001;12,31)));WENN(B1:B100<>"";REST((MONAT(B1:B100)+TAG(B1:B100)/100-MONAT(HEUTE())-TAG(HEUTE())/100)+0,001;12,31));0))} $F$1
G1 =SVERWEIS(F1;B:C;2;0) 
I1 =JAHR(DATUM(JAHR(HEUTE());MONAT(F1);TAG(F1)))-JAHR(INDEX(B:B;VERGLEICH(G1;C:C;0))) 
D2 =WENN(B2="";"";WENN(HEUTE()>DATUM(JAHR(HEUTE());MONAT(B2);TAG(B2));"ist "&WENN(B2="";"";JAHR(HEUTE())-JAHR(B2))&" Jahre alt";"wird "&WENN(B2="";"";JAHR(HEUTE())-JAHR(B2))&" Jahre alt")) 
D3 =WENN(B3="";"";WENN(HEUTE()>DATUM(JAHR(HEUTE());MONAT(B3);TAG(B3));"ist "&WENN(B3="";"";JAHR(HEUTE())-JAHR(B3))&" Jahre alt";"wird "&WENN(B3="";"";JAHR(HEUTE())-JAHR(B3))&" Jahre alt")) 
F3 =DATUM(JAHR(HEUTE())+((MONAT(F1)*50+TAG(F1)-MONAT(HEUTE())*50-TAG(HEUTE()))<0);MONAT(F1);TAG(F1))-HEUTE() 
D4 =WENN(B4="";"";WENN(HEUTE()>DATUM(JAHR(HEUTE());MONAT(B4);TAG(B4));"ist "&WENN(B4="";"";JAHR(HEUTE())-JAHR(B4))&" Jahre alt";"wird "&WENN(B4="";"";JAHR(HEUTE())-JAHR(B4))&" Jahre alt")) 
{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren Version 5.30


gruss hary
Anzeige
AW: Runde Geburtstage
08.11.2010 16:07:54
Mat
Hallo Markus,
danke für Deine Hilfe - klappt prima.
Gruß Mat

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige