Formel gesucht

Forumthread: Formel gesucht

Formel gesucht

Jean

Guten Abend,
ich suche eine Formel. Der erste Formelversuch
'=oder(A3größer=50;B3größer=1:00) erhält die Benotung mangelhaft, da fehlerhaft,
die Alternativformel
'=oder(A3größer=50;b3größer=0,041666667) ausreichend, da zeitaufwendig wegen der Ermittlung der Kommazahl.
Wie könnte für diese Aufgabenstellung eine optimale Formel aussehen?
Gruß
Jean

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Formel gesucht

05.10.2011 22:36:24

Josef

Hallo Jean,
=ODER(A3>=50;B3>=ZEIT(0;1;0))

« Gruß Sepp »

AW: Formel gesucht

05.10.2011 22:47:49

Jean

Hallo Sepp,
vielen Dank für Deine rasche Antwort.
Wenn Deine Formel nach unten kopiert wird, dann wird offensichtlich in Zeile 6 ein falscher Rückgabewert WAHR angezeigt, obwohl dort in A6 20 steht, in B6 0:30.
Es wird in allen Fällen WAHR angezeigt.
Die Eingaben in B haben das Zeitformat 0:00
Woran kann es liegen?
Gruß
Jean

AW: Formel gesucht

05.10.2011 22:56:58

Uwe

Hallo Jean,
ich glaube Sepp ist da die 1 etwas verrutscht. So:
=ODER(A3>=50;B3>=ZEIT(1;0;0))
entspricht es 01:00 Uhr. ZEIT(0;1;0) wäre 0:01 Uhr.
Vielleicht ist es mit Zeitwert besser lesbar:
=ODER(A3>=50;B3>=ZEITWERT("1:00"))
DAS entspricht der obigen Formel.
Gruß
Uwe
(:o)

@ Uwe! Wehe du behauptest noch einmal ...

05.10.2011 23:04:45

Josef

... das mir was "verrutscht" ist ;-))
Danke für's "mitdenken"

« Gruß Sepp »

AW: @ Sepp: (:o)))))) o.T.

06.10.2011 00:54:10

Uwe

Gruß
Uwe
(:o)

Danke

06.10.2011 08:34:43

Jean

Hallo Uwe,
vielen Dank für Deinen Beitrag. Die Formel funktioniert wie erhofft.
Gruß
Jean

AW: Formel gesucht

05.10.2011 22:59:24

Josef

Hallo Jean,
"Woran kann es liegen?"
ganz einfach daran, dass meine Formel falsch ist;-((
So passt es, und besser noch mit RUNDEN(), weil sich sonst bei Zeitwerten oft Rundungsfehler einschleichen.
Tabelle1

	A	B	C	D	E
1	100				WAHR
2	49	01:00			WAHR
3	20	00:30			FALSCH
4	55				WAHR

Formeln der Tabelle

Zelle	Formel
E1	=ODER(A1>=50;RUNDEN(B1;6)>=RUNDEN(ZEIT(1;0;0); 6))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

« Gruß Sepp »

Alternative

06.10.2011 01:52:11

Erich

Hi zusammen,
in Spalte E noch eine Alternative, für die man nur wissen muss, dass ein Tag 24 Stunden hat.
(Man muss dabei auch nicht 1/24 = 0,041666667 berechnen!)

	A	B	C	D	E	F
1	100			WAHR	WAHR	WAHR
2	49	01:00		WAHR	WAHR	FALSCH
3	20	00:30		FALSCH	FALSCH	FALSCH
4	50			WAHR	WAHR	FALSCH

Formeln der Tabelle

Zelle	Formel
D1	=ODER(A1>=50;RUNDEN(B1;6)>=RUNDEN(ZEIT(1;0;0); 6))
E1	=ODER(A1>=50;RUNDEN(B1*24;6)>=1)
F1	=ODER(A1>50;RUNDEN(B1*24;6)>1)

In Spalte F steht eine weitere Alternative - für den Fall, dass du, Jean, doch "größer" und nicht "größergleich" meinst.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Alternative, nur größergleich...

06.10.2011 08:06:05

Erich

Hi Jean,
sorry, ich habe mal wieder ungenau gelesen. Du wolltest "größer="...
Also vergiss bitte meinen Vorschlag in Spalte F.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

Danke und Zusatzfrage

06.10.2011 08:59:33

Jean

Hallo Erich,
vielen Dank für Deine ergänzenden Lösungen. Nun liegt eine große Palette an Lösungen vor.
Warum aber Runden auf die 6. Stelle
'=RUNDEN((1/24);6) ergibt 0,041667
'=RUNDEN((1/24);8) ergibt 0,04166667
Reicht Runden auf die 8. Stelle nicht aus?
Gruß
Jean

Rundung von Uhrzeiten

06.10.2011 12:26:22

Uhrzeiten

Hi Jean,
Runden auf die 8. Stelle wäre viel besser als auf die 6. Stelle!
Ein paar Beispiele:

	A	B	C	D	E	F	G	H	I
1	Zeit	dezimal	Stunden	RUNDEN(3)	RUNDEN(4)	RUNDEN(5)	RUNDEN(6)	RUNDEN(7)	RUNDEN(8)
2	00:59	0,040972222	0,98333333	0,98300000	0,98330000	0,98333000	0,98333300	0,98333330	0,98333333
3	00:59:50	0,041550926	0,99722222	0,99700000	0,99720000	0,99722000	0,99722200	0,99722220	0,99722222
4	00:59:59	0,041655093	0,99972222	1,00000000	0,99970000	0,99972000	0,99972200	0,99972220	0,99972222
5	00:59:59,9	0,041665509	0,99997222	1,00000000	1,00000000	0,99997000	0,99997200	0,99997220	0,99997222
6	00:59:59,99	0,041666551	0,99999722	1,00000000	1,00000000	1,00000000	0,99999700	0,99999720	0,99999722
7	00:59:59,999	0,041666655	0,99999972	1,00000000	1,00000000	1,00000000	1,00000000	0,99999970	0,99999972

Formeln der Tabelle

Zelle	Formel
B2	=A2
C2	=A2*24
D2	=RUNDEN(C2;3)
E2	=RUNDEN(C2;4)
F2	=RUNDEN(C2;5)
G2	=RUNDEN(C2;6)
H2	=RUNDEN(C2;7)
I2	=RUNDEN(C2;8)

Bei den ocker gefärbten Zellen in den Spalten D:G sieht man, dass eine zu grobe Rundung bei manchen Zeiten dazu führt,
dass der gerundete Wert gleich 1 ist - obwohl die Zeit kleiner als 1 Stunde ist.
Also ist es wohl besser, auf 7 oder 8 Stellen zu runden.
Naürlich:
Wenn man nicht mit Zehntel- oder Hundertstelsekunden hantiert, reicht die Rundung auf 4 Stellen.
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort

AW: Rundung von Uhrzeiten

06.10.2011 16:45:27

Uhrzeiten

Hallo Erich,
vielen Dank für Deine überzeugenden Beispiele.
Gruß
Jean

Zusatzfrage

06.10.2011 08:32:16

Jean

Hallo Sepp,
vielen Dank für die ODER-Formel.
Warum wird gerade auf die 6. Stelle gerundet?
Gruß
Jean

Beliebteste Forumthreads (12 Monate)

Forumthread: Formel gesucht

13 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread