Doppelte Zahlen zählen

Forumthread: Doppelte Zahlen zählen

Werner

Hallo, ich brauche mal wieder Hilfe:
In den Zellen A1 bis E1 werden mit "Zufallsbereich" Zahlen zwischen 0 und 50 erzeugt.
Jetzt möchte ich wissen, ob in diesem Breich gleiche Zahlen vorkommen, d.h. ob eine Zahl doppelt, dreifach, vierfach oder gar fünffach vorkommt, und wenn ja, welche und wie oft.
Beispiel: In F1 steht die Zahl, doppelt vorkommt, in G1 die Zahl, die dreimal vorkommt u.s.w.
Hat jemand eine Idee?
Gruß aus dem hohen Norden
Werner

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Doppelte Zahlen zählen

24.10.2011 23:34:32

Josef

Hallo Werner,
so?
Tabelle2

	A	B	C	D	E	F	G	H	I	J
1	49	21	4	21	16		II	III	IV	V
2							21
3

Formeln der Tabelle

Zelle	Formel
A1	=GANZZAHL(ZUFALLSZAHL()*50)+1
B1	=GANZZAHL(ZUFALLSZAHL()*50)+1
C1	=GANZZAHL(ZUFALLSZAHL()*50)+1
D1	=GANZZAHL(ZUFALLSZAHL()*50)+1
E1	=GANZZAHL(ZUFALLSZAHL()*50)+1
G2	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(B$1))/SPALTE(B$1))<ZEILE($A1); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(B$1); $A$1:$E$1); ZEILE($A1)*2-1))}
H2	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(C$1))/SPALTE(C$1))<ZEILE($A1); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(C$1); $A$1:$E$1); ZEILE($A1)*2-1))}
I2	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(D$1))/SPALTE(D$1))<ZEILE($A1); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(D$1); $A$1:$E$1); ZEILE($A1)*2-1))}
J2	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(E$1))/SPALTE(E$1))<ZEILE($A1); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(E$1); $A$1:$E$1); ZEILE($A1)*2-1))}
G3	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(B$1))/SPALTE(B$1))<ZEILE($A2); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(B$1); $A$1:$E$1); ZEILE($A2)*2-1))}
H3	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(C$1))/SPALTE(C$1))<ZEILE($A2); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(C$1); $A$1:$E$1); ZEILE($A2)*2-1))}
I3	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(D$1))/SPALTE(D$1))<ZEILE($A2); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(D$1); $A$1:$E$1); ZEILE($A2)*2-1))}
J3	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(E$1))/SPALTE(E$1))<ZEILE($A2); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=SPALTE(E$1); $A$1:$E$1); ZEILE($A2)*2-1))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

« Gruß Sepp »

kleine Korrektur für..

24.10.2011 23:40:23

Josef

... größere Bereiche.
Tabelle2

	A	B	C	D	E	F	G	H	I	J
1	34	37	46	12	31		II	III	IV	V
2
3
4

Formeln der Tabelle

Zelle	Formel
G2	{=WENN(SUMMENPRODUKT((ZÄHLENWENN($A$1:$E$10;$A$1:$E$10)=SPALTE(B$1))/SPALTE(B$1))<ZEILE($A1); "";KKLEINSTE(WENN(ZÄHLENWENN($A$1:$E$10;$A$1:$E$10)=SPALTE(B$1); $A$1:$E$10); ZEILE($A1)*SPALTE(B$1)-1))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

« Gruß Sepp »

ZählenWenn()

24.10.2011 23:41:31

Matthias

Hallo
Hier eine Variante
Tabelle1

	A	B	C	D	E	F	G	H	I	J
1	1	18	7	15	18	1	18	7	15	18
2						1 mal	2 mal	1 mal	1 mal	2 mal

Formeln der Tabelle

Zelle	Formel
A1	=ZUFALLSBEREICH(0;50)
B1	=ZUFALLSBEREICH(0;50)
C1	=ZUFALLSBEREICH(0;50)
D1	=ZUFALLSBEREICH(0;50)
E1	=ZUFALLSBEREICH(0;50)
F1	=A1
G1	=B1
H1	=C1
I1	=D1
J1	=E1
F2	=ZÄHLENWENN($A$1:$E$1;F$1)
G2	=ZÄHLENWENN($A$1:$E$1;G$1)
H2	=ZÄHLENWENN($A$1:$E$1;H$1)
I2	=ZÄHLENWENN($A$1:$E$1;I$1)
J2	=ZÄHLENWENN($A$1:$E$1;J$1)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Matthias

AW: Doppelte Zahlen zählen

25.10.2011 02:46:40

Daniel

Hi
das kannst du so lösen:
F1: =Max(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=2;$A$1:$E$1))
F2: =MIN(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=2;$A$1:$E$1)) ( bei 5 Zahlen können auch 2 2x vorkommen
G1: =Max(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=3;$A$1:$E$1))
H1: =Max(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=4;$A$1:$E$1))
I1: =Max(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=5;$A$1:$E$1))
alle Formeln sind Matrix-Formeln, dh die Eingabe ist mit STRG+SHIFT+ENTER abzuschließen.
man kann die Formeln in Zeile 1 auch ziehbar machen:
=Max(WENN(ZÄHLENWENN($A$1:$E$1;$A$1:$E$1)=Spalte()-4;$A$1:$E$1))
Gruß Daniel

Beliebteste Forumthreads (12 Monate)

Forumthread: Doppelte Zahlen zählen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread