Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1236to1240
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Open For Append - Reihenfolge

Open For Append - Reihenfolge
Heiko
Hallo,
Wenn ich mit der Methode append Daten an eine bestehende Textdatei anhaenge, werden die Daten ja hinten angehaengt. Der aktuelleste Eintrag ist also am Ende.
Wenn ich nun die Textdatei zum Lesen oeffne und die Daten mit Input bzw LineInput lese, faengt die Leserei ja von vorne an, also beim aeltesten Eintrag.
Gibt es einen Weg, entweder den aktuellsten Eintrag vorne einzufuegen oder die Datei von hinten zu lesen?
Ersteres waere mir lieber, weil es sich immer um ganze Textbloecke aus jeweils rund 20 Zeilen handelt...
Wuerde mich ueber Tips freuen,
Heiko

3
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Open For Append - Reihenfolge
21.11.2011 20:48:56
Josef

Hallo Heiko,
da musst du schon selber eingreifen, z. B. so.
Sub textAnhängen()
  Dim strFile As String, strOld As String, strNew As String
  Dim ff As Integer
  
  strFile = "C:\DeineTextdatei.txt" 'Textdatei
  
  strNew = "Der neue text"
  
  ff = FreeFile
  
  Open strFile For Binary As #ff
  strOld = Space$(LOF(ff))
  Get #ff, , strOld
  Close #ff
  
  strNew = strNew & vbCrLf & strOld
  
  ff = FreeFile
  
  Open strFile For Output As #ff
  Print #ff, strNew;
  Close #ff
  
End Sub



« Gruß Sepp »

Anzeige
noch eine Variante
21.11.2011 21:12:46
CitizenX
Hi,
Sub Aktuell()
Dim Filename As String
Dim strTemp As String, strNew As String
Dim FSO As Object, oStream As Object
Set FSO = CreateObject("Scripting.FileSystemObject")
Filename = "D:\XXXXXXXXXXX\Test.txt" 'Pfad anpassen
strNew = "Das ist dein neuer Text"
'Textdatei öffnen & temporär auslesen
Set oStream = FSO.OpenTextFile(Filename, 1)
strTemp = oStream.ReadAll
oStream.Close
'Datei öffnen & Überschreiben
Set oStream = FSO.OpenTextFile(Filename, 2)
strTemp = strNew & vbNewLine & strTemp
oStream.Write strTemp
oStream.Close
Set oStream = Nothing
Set FSO = Nothing
End Sub

Grüße
Steffen
Anzeige
AW: Open For Append - Reihenfolge
21.11.2011 21:31:21
Heiko
hi, Josef und CitizenX,
vielen Dank fuer Eure Beitraege!
Ich habe bereits Josefs Metode angepasst und eingebaut - klappt sehr gut!
Die andere Variante probier ich aber auch mal aus.
Also, danke schoen nochmals,
Heiko

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige