Ergebnisse auswerten

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

Hallo Hella,
im Printip sollte es mit KGRÖSSTE und VERGLEICH funktionieren. Es gibt aber immer das Problem, das bei Punktgleich Vergleich nur den 1. gefundenen Namen zurückgibt.
Versuche deine Daten als Pivot-Tabellebreicht auszuwerten. Wenn man dort den Wertefilter auf Top3 einstellt und absteigend nach der Gesamtpunktzahl sortiert gibt das auch das gewünschte Ergebnis.
Eine solche Pivot-Tabellenbericht-Auswertung erstellt man aber besser auf einem separaten Blatt oder neben den auszuwertenden Daten.
Gruß
Franz
Tabelle3

	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Name03	54
2	Name07	53
3	Name02	38
4
5	Pivotauswertung
6	Summe von Total
7	Name	Ergebnis
8	Name03	54
9	Name07	53	Name	P001	P002	P003	P004	P005	P006	P007	P008	P009	Total
10	Name02	38	Name01	1	2	4	6	3	4	6	8	1	35
11			Name02	4	3	5	4	3	2	8	6	3	38
12			Name03	2	2	8	7	6	7	8	9	5	54
13			Name04	3	4	1	1	2	1	2	1	2	17
14			Name05	1	6	3	4	2	5	3	2	4	30
15			Name06	1	2	2	2	6	3	2	3	1	22
16			Name07	2	1	8	9	8	9	7	8	1	53
17			Name08	3	2	1	1	1	1	1	1	1	12

Formeln der Tabelle

Zelle	Formel
A1	=INDEX($C$10:$C$36;VERGLEICH(B1;$M$10:$M$36;0); 1)
B1	=KGRÖSSTE($M$10:$M$36;ZEILE(A1))
A2	=INDEX($C$10:$C$36;VERGLEICH(B2;$M$10:$M$36;0); 1)
B2	=KGRÖSSTE($M$10:$M$36;ZEILE(A2))
A3	=INDEX($C$10:$C$36;VERGLEICH(B3;$M$10:$M$36;0); 1)
B3	=KGRÖSSTE($M$10:$M$36;ZEILE(A3))
M10	=SUMME(D10:L10)
M11	=SUMME(D11:L11)
M12	=SUMME(D12:L12)
M13	=SUMME(D13:L13)
M14	=SUMME(D14:L14)
M15	=SUMME(D15:L15)
M16	=SUMME(D16:L16)
M17	=SUMME(D17:L17)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Hallo Hella,
da muss du dann mit ein paar Hilfsspalten arbeiten.
1. Max - In dieser Spalte wird der Maximum-Wert aus den Monaten in der Zeile berechnet.
2. Rang - hier wird der Rang/Plazierung der Maximalwerte ermittelt.
3. Hilfsspalte - in dieser Spalte wird der Rang so modifiziert, dass bei gleichem Rang ein eindeutiger Wert entsteht.
Tabelle3

	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P
1	Name03	12	100
2	Name02	11	200
3	Name05	11	201
4
5	Pivotauswertung
6	mit berechnetem Feld
7	Max-Wert
8	Name	Ergebnis
9	Name03	12	Name	P001	P002	P003	P004	P005	P006	P007	P008	P009	P010	Max	Rang	Hilfsspalte
10	Name05	11	Name01	1	2	4	6	3	4	6	8	1		8	6	600
11	Name02	11	Name02	4	3	5	4	3	2	8	6	3	11	11	2	200
12			Name03	2	2	8	7	6	7	8	9	12		12	1	100
13			Name04	3	4	1	1	2	1	2	1	2		4	16	1600
14			Name05	1	6	3	4	2	5	3	2	4	11	11	2	201
15			Name06	1	2	2	2	6	3	2	3	1		6	11	1100
16			Name07	2	1	8	9	8	9	7	8	1		9	4	400

Formeln der Tabelle

Zelle	Formel
A1	=INDEX($C$10:$C$36;VERGLEICH(C1;$P$10:$P$36;0); 1)
B1	=INDEX($N$10:$N$36;VERGLEICH(C1;$P$10:$P$36;0); 1)
C1	=KKLEINSTE($P$10:$P$36;ZEILE(A1))
A2	=INDEX($C$10:$C$36;VERGLEICH(C2;$P$10:$P$36;0); 1)
B2	=INDEX($N$10:$N$36;VERGLEICH(C2;$P$10:$P$36;0); 1)
C2	=KKLEINSTE($P$10:$P$36;ZEILE(A2))
A3	=INDEX($C$10:$C$36;VERGLEICH(C3;$P$10:$P$36;0); 1)
B3	=INDEX($N$10:$N$36;VERGLEICH(C3;$P$10:$P$36;0); 1)
C3	=KKLEINSTE($P$10:$P$36;ZEILE(A3))
N10	=MAX(D10:M10)
O10	=RANG(N10;$N$10:$N$36;0)
P10	=O10*100+ZÄHLENWENN($O$9:O9;O10)
N11	=MAX(D11:M11)
O11	=RANG(N11;$N$10:$N$36;0)
P11	=O11*100+ZÄHLENWENN($O$9:O10;O11)
N12	=MAX(D12:M12)
O12	=RANG(N12;$N$10:$N$36;0)
P12	=O12*100+ZÄHLENWENN($O$9:O11;O12)
N13	=MAX(D13:M13)
O13	=RANG(N13;$N$10:$N$36;0)
P13	=O13*100+ZÄHLENWENN($O$9:O12;O13)
N14	=MAX(D14:M14)
O14	=RANG(N14;$N$10:$N$36;0)
P14	=O14*100+ZÄHLENWENN($O$9:O13;O14)
N15	=MAX(D15:M15)
O15	=RANG(N15;$N$10:$N$36;0)
P15	=O15*100+ZÄHLENWENN($O$9:O14;O15)
N16	=MAX(D16:M16)
O16	=RANG(N16;$N$10:$N$36;0)
P16	=O16*100+ZÄHLENWENN($O$9:O15;O16)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Ich empfehle hier aber eine Auswerung mit Pivot-Tabellenbericht.
Hier sind keine Hilfsspalten erforderlich. Den Max-Wert der Monate für die einzelnen Namen kann man als Formel/Berechnetes Feld einrichten.
Beispiel:
Userbild

Gruß
Franz

Beliebteste Forumthreads (12 Monate)

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread