Formel SVERWEIS oder ?

Forumthread: Formel SVERWEIS oder ?

22.11.2013 16:59:30

Horst

https://www.herber.de/bbs/user/88216.xlsx
Guten Abend an alle
Ich suche eine Formel um mein Problem zu lösen. Bin ratlos. Nun kommt wieder meine schwäche die Erklärung, seid nicht sauer wenn ich Bahnhof schreibe. Werde mein bestes geben.
Also wenn eine Zahl z.B 31 in einer zelle steht soll diese in Spalte A gesucht werden und den Namen aus Spalt B wiedegeben.
Vielleicht mit WENN 31 dann zwischen kleiner gleich 32 und grösser gleich 30 de Wert Gerd wiedergeben.
Nun denke ich doch meie Beschreibung könnt ihr verstehen.
Gruß Horst

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Formel SVERWEIS oder ?

22.11.2013 17:12:02

KlausF

Hallo Horst,
wenn z.B. E1 die Zelle ist wo 31 drin steht, dann
=SVERWEIS(E1;A:B;2;FALSCH)
Gruß
Klaus

sorry, jetzt erst die Mappe gesehen ...

22.11.2013 17:15:56

KlausF

Hab jetzt erst gesehen, dass die Zahl auch gar nicht auftreten kann ...

AW: sorry, jetzt erst die Mappe gesehen ...

22.11.2013 17:34:01

Horst

Ja, Klaus das ist mein Problem.

aber jetzt

22.11.2013 18:02:13

KlausF

Hallo Horst,
=SVERWEIS(MIN(WENN(ABS(A1:A1000-F4)=MIN(ABS(A1:A1000-F4));A1:A1000));A1:B1000;2;FALSCH)
als Arrayformel eingeben
(Abschluss der Formel mit Strg+Shift+Return,
das erzeugt die geschweiften Klammern {...}
https://www.herber.de/bbs/user/88217.xls
Gruß
Klaus

AW: sorry, jetzt erst die Mappe gesehen ...

22.11.2013 18:14:37

Horst

Super Klaus funktioniert wie ich es haben wollte. Danke und noch ein paar ruhige Abendstunden

oder so ? ...

22.11.2013 18:13:49

robert

=WENN(ZÄHLENWENN(A1:A9;F4)>0;SVERWEIS(F4;A1:B9;2;0);"nix da")
Gruß
robert

Willst du dann beide Werte, den davor und ...

22.11.2013 18:23:51

Luc:-?

…den danach, haben, Horst?
Dann würde es mit 1zelliger MatrixFml bspw so gehen:
{=WENNFEHLER(SVERWEIS(F4;A1:B9;2;0);SVERWEIS(MAX((A1:A9<F4)*A1:A9);A1:B9;2;0) &" & "&SVERWEIS(MIN(A1:A9+(A1:A9<F4)*10^3);A1:B9;2;0)) }
Falls beide Werte in separaten Zellen ausgegeben wdn sollen, entstünde das Problem (wenn es denn eines wäre), dass bei exakter Übereinstimmung 2× der gleiche Wert im ErgebnisZellbereich stehen würde. Die benannte MatrixFml (über 2 Zellen!) könnte dann so aussehen:
{=suchfmlname} wobei suchfmlname für den definierten Namen der eigentlichen Fml steht:
{=AUSWERTEN("{"""&WENNFEHLER(SVERWEIS(F4;A1:B9;2;0);SVERWEIS(MAX((A1:A9<F4)*A1:A9);A1:B9;2;0) &"""."""&SVERWEIS(MIN(A1:A9+(A1:A9<F4)*10^3);A1:B9;2;0))&"""}") }
Sollen die beiden Ergebnisse untereinander stehen, muss Pkt in &"""."""& durch Semikolon ersetzt wdn.
Nach den Begriffen neben den leeren Feldern kann so aber nicht gesucht wdn. Auch bei doppelten Werten wird stets nur der ErstAuftritt behandelt.
Gruß Luc :-?

Varianten

23.11.2013 00:45:29

Hi,
erste kleinste gefundene Differenz egal ob größer oder kleiner:
{=INDEX(B:B;VERGLEICH(MIN(ABS(A1:A100-F4));ABS(A1:A100-F4);0))}
erste kleinste gefundene Differenz kleiner:
{=INDEX(B:B;VERGLEICH(MIN(WENN(ABS(A1:A100-F4)=MIN(ABS(A1:A100-F4));A1:A100));A:A;0))}
noch differenzierter (mit Behandlung von Leerstellen) siehe unsere:
http://www.excelformeln.de/formeln.html?welcher=65
Salut WF

Beliebteste Forumthreads (12 Monate)

Forumthread: Formel SVERWEIS oder ?

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread