Argumenttyp ByRef unverträglich

Guten Tag
Beim Verlassen des Worksheets will ich mir gewisse Bereiche definieren.
Dabei soll die erste und letzte Zeile dem Range ("_F_KFIBU") entsprechen.
Diese Zeilennummern frage ich nachstehend ab. lngFirstRow wird die Zahl 7, lngLastRow wird die Zahl 362 zugewiesen.
Wenn ich dann weiter unten in der Funktion CreateBereich2222 die Zahl 7 durch die Varible lngFirstRow, resp. die Zahl 362 durch die Variable lngLastRow ersetze, erhalte ich die Fehlermeldung "Fehler beim Kompilieren: Argumenttyp ByRef unverträglich".
Ich verstehe nicht, was hier nicht in Ordnung ist.
Gruss, Peter

Private Sub Worksheet_Deactivate()
Dim lngFirstRow As Integer, lngLastRow As Integer, rCell As Range, lngColumn As Integer
'''erste Zeile anhand Range("_FKFIBU") bestimmen
With Me.Range("_F_KFIBU")
lngFirstRow = .Row
End With
'''letzte Zeile anhand Range("_FKFIBU") bestimmen
With Me.Range("_F_KFIBU")
lngLastRow = .Row + .Rows.Count - 1
End With
For Each rCell In Me.Range("C1:G1")
If rCell  "" Then
Call CreateBereich2222(rCell.Value, Me, rCell.Column, 7, rCell.Column, 362)
Else
End If
Next
End Sub

Sub CreateBereich2222(strBereichsname As String, wkTabelle As Worksheet, zeUp As Long, spLinks As Long, zeDown As Long, spRechts As Long)
Dim Bereich As Range
Set Bereich = Worksheets(wkTabelle.Name).Range(wkTabelle.Cells(spLinks, zeUp), wkTabelle.Cells(spRechts, zeDown))
ActiveWorkbook.Names.Add _
Name:=strBereichsname, _
RefersTo:=Bereich, Visible:=True
End Sub

Hi
es gibt zwei Methoden, eine Variable an eine Funktion oder Sub zu übergeben:
a) byRef (Standard)
b) byVal
bei der Übergabe byVal wird nur der Wert übergeben und für die Sub/Function wird eine neue Variable angelegt.
bei der Übergabe byRef wird im Prinzip die Variable selbst an die Sub/Function übergeben, sie erhält hier ggf nur einen anderen Namen.
dh änderst du den Wert der Variablen in der aufgerufenen Sub, so ändert sich auch der Wert der Variablen in der aufrufenden Sub.
der Übergabetyp "byRef" wird von Excel standardmäßig verwendet, wenn du keine genauen Angaben hierzu machst.
bei der Übergabe "byRef" ist es zwingend erforderlich, dass die die Variablentypen genau übereinstimmen, dh du kannst eine Integer-Variable nicht übergeben, wenn eine LONG-Variable gefordert ist, sondern nur eine LONG-Variable.
Verwendest du den Übertabetyp "byVal", dann geht das problemlos (weil hier eine neue Variable entsteht kann Excel die erforderliche Typumwandlung durchführen, bei "byRef" ensteht keine neue Variable, daher müssen die Typen exakt gleich sein.)
Es gibt für deinen Fall folgende Lösungsmöglichkeiten:
a) du passt die Variablentypen in aufrufender und aufgerufener Sub an:
a1) du deklariersst deine Variabeln genau so, wie sie von der Sub benötigt werden, dh nicht als Integer sondern als Long.

Sub Makro1()
Dim x as long
x = 1
Call Makro2(x)
End Sub
Sub Makro2(y as long)
msgbox y*y
End Sub

a2) du kannst die Variable auch temporär umwandeln, so dass sie nur für die Übergabe den anderen Typ hat:

Sub Makro1()
Dim x as Integer
x = 1
Call Makro2(CDbl(x))
End Sub
Sub Makro2(y as long)
msgbox y*y
End Sub

b) du machst die Variablenübergabe vom Typ "byVal"
hierzu gibt es zwei möglichkeiten:
b1) du gibst in der Sub an, dass die Variablenübergabe "byVal" erfolgen soll:

Sub Makro1()
Dim x as Integer
x = 1
Call Makro2(x)
End Sub
Sub Makro2(byVAl y as long)
msgbox y*y
End Sub

b2) du setzt beim Aufruf die Variable in Klammern, dann erfolgt die Übergabe ebenfalls "byVal"

Sub Makro1()
Dim x as Integer
x = 1
Call Makro2((x))
End Sub
Sub Makro2(y as long)
msgbox y*y
End Sub

Gruß Daniel

Forumthread: Argumenttyp ByRef unverträglich

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial

Argumenttyp ByRef und seine Herausforderungen in Excel VBA

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)