alphanumerische Summe/ Anzahl

Bild

Betrifft: alphanumerische Summe/ Anzahl
von: Andre´
Geschrieben am: 21.05.2015 18:07:13

Hallo alle zusammen,
ich möchte von dem Bereich A2 bis G2
folgendes ermitteln, dass was jeweils in den Zellen von I1 bis M1 steht
Leere Zelle müssen ignoriert werden!
Die Ergebnisse habe ich in den Zellen I2 bis M2 eingetragen
Userbild
Hier die Bsp.: Datei https://www.herber.de/bbs/user/97765.xls
Ich hoffe mir kann jemand helfen.
Vielen Dank im Voraus!
MFG
Andre

Bild

Betrifft: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Luc:-?
Geschrieben am: 21.05.2015 19:45:09
…André:
I2: {=SUMME(WENNFEHLER(--TEIL(A2:G2;2;9);0))}
J2[:K2]: {=SUMME(WENN(LINKS($A2:$G2)=RECHTS(J1);--TEIL($A2:$G2;2;9);0))}
L2[:M2]: {=ANZAHL(WENN(LINKS($A2:$G2)=RECHTS(L1);--TEIL($A2:$G2;2;9);""))}
J2 auch nach K2 und L2 nach M2 ziehen! MatrixFml-Eingabe-Modalitäten beachten!
Gruß, Luc :-?

Besser informiert mit …

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Andre´
Geschrieben am: 21.05.2015 19:58:02
Hallo Luc,
vielen Dank für die Lösung, funktioniert wie gewünscht!
MFG Andre

Bild

Betrifft: Bitte sehr, gern geschehen! owT
von: Luc:-?
Geschrieben am: 21.05.2015 20:09:07
:-?

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Daniel
Geschrieben am: 21.05.2015 20:08:12
Hi
die Anzahl kannst du auch direkt mit ZählenWenn bestimmen:
für g: =ZählenWenn($A2:$G2;"g*")
oder um das "g" aus der Zelle abzuleigen:
=ZählenWenn($A2:$G2;rechts(L2;1)&"*")
die Summe für "g" alternativ auch mit:
=SUMMENPRODUKT((LINKS(A2:G2;1)="x")*("0"&TEIL(A2:G2;2;99)))
netter nebeneffekt von Summenprodukt ist, dass man die Eingabe ganz normal mit ENTER abschließen kann, obwohl es eigentlich eine Matrixfunktion ist.
Gruß Daniel

Bild

Betrifft: Eine MatrixFunktion ist etwas Anderes als eine ...
von: Luc:-?
Geschrieben am: 21.05.2015 20:13:01
…MatrixFormel, Daniel… ;-]
Luc :-?

Bild

Betrifft: ...aber jeder weiß, was gemeint war...
von: {Boris}
Geschrieben am: 21.05.2015 20:21:49
...insofern lasst diese Sticheleien doch mal gut sein... :-/
:-)
VG, Boris

Bild

Betrifft: Ich hatte dazu eine Grundsatzdiskussion mit ...
von: Luc:-?
Geschrieben am: 21.05.2015 20:38:36
…neopa geführt, die ich hier nicht wiederholen will, Boris;
und ob wirklich jeder weiß, was der Unterschied zwischen beiden Begriffen ist, wage ich zu bezweifeln. Wenn wir die Verwendung der richtigen Termini bei den Fragern anmahnen, müssen wir das auch selbst tun, um die gerade um diese Begriffe existierende Verwirrnis nicht noch zu vergrößern.
Das hat in diesem Fall also wenig mit „Stichelei“, umso mehr mit Exaktheit zu tun.
Gruß, Luc :-?

Bild

Betrifft: AW: Ich hatte dazu eine Grundsatzdiskussion mit ...
von: Daniel
Geschrieben am: 21.05.2015 20:51:31
SummenProdukt() ist eine Funktion und keine Formel.
Gruß Daniel

Bild

Betrifft: Eben, und die findet man NICHT unter der ...
von: Luc:-?
Geschrieben am: 22.05.2015 15:08:55
…Xl-Funktionsrubrik Matrixfunktionen! Du vermengst 2 ganz verschiedene offizielle Definitionen miteinander.
Luc :-?

Bild

Betrifft: AW: Eben, und die findet man NICHT unter der ...
von: Daniel
Geschrieben am: 22.05.2015 15:57:57
ich weiss, deswegen nehme ich wenn möglich auch die Excelstandardfunktionen, wenns damit machbar ist.
Gruß Daniel

Bild

Betrifft: Das ist aber auch eine... ;-) owT
von: Luc:-?
Geschrieben am: 23.05.2015 05:40:50
:-?

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Andre´
Geschrieben am: 21.05.2015 22:40:17
Hallo Daniel,
auch Dir vielen Dank für den Lösungsweg!
Wenn die Gesamtsumme ermittelt werden soll, so kann ich auch <>"?" einfügen, weil dies nicht vorkommt
=SUMMENPRODUKT((LINKS(A2:G2;1)<>"?")*("0"&TEIL(A2:G2;2;99)))
MFG Andre

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Daniel
Geschrieben am: 21.05.2015 22:46:45
Hi
die Prüfung einfach weglassen.
=SUMMENPRODUKT(1*("0"&TEIL(A2:G2;2;99)))
Gruß Daniel

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Andre´
Geschrieben am: 21.05.2015 22:57:53
Hallo Daniel,
bei Inhalten mit z.B. g-4 kommt bei der Summe #Wert!
Hast Du dafür vielleicht auch eine Lösung über Summenprodukt?
MFG Andre

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Daniel
Geschrieben am: 21.05.2015 23:50:16
=SUMMENPRODUKT(1*(WECHSELN("0"&TEIL(A2:G2;2;99);"0-";"-")))
Gruß´Daniel

Bild

Betrifft: AW: Nur 3 1zellige Matrixformeln sind erforderlich,...
von: Andre´
Geschrieben am: 22.05.2015 08:19:23
Hallo Daniel,
vielen Dank, funktioniert prima!
MFG Andre

 Bild

Beiträge aus den Excel-Beispielen zum Thema "alphanumerische Summe/ Anzahl"