Ausgaben pro Datum von versch. Personen

Bild

Betrifft: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 10:31:32

Hallo zusammen,
ich habe eine Tabelle mit 3 Spalten "Datum"(A), "Name"(B) und "Wert"(C). In der Datumsspalte steht jeweils ein Datum (teilweise mehrfach untereinander), in der "Name"-Spalte steht dann eben ein Name (mehrere unterschiedliche, manchmal zum selben Datum, daher kommt dieses mehrfach vor) und in der "Wert"-Spalte steht, wie viel von dieser Person an diesem Datum ausgegeben wurde. Es gibt viele verschiedene Namen, lediglich der erste an jedem Tag ist gleich ("Klaus"). Ich hoffe das ist verständlich.
Ich würde jetzt gerne eine Formel aufstellen, mit der ich berechnen kann, an wie vielen Tagen die Summe der Ausgaben ("Wert") aller Personen ("Name") unter 100€ lag. Ich habe mittlerweile eine Hilfsspalte, die mir sagt ob die Ausgabe einer bestimmten Person an einem bestimmten Tag über oder unter 100€ liegt. Allerdings kann es natürlich sein, dass "Klaus" 50€ ausgegeben hat und "Sabine" 60€ ausgegeben hat, sodass bei beiden unter 100€ angezeigt wird, sie in Summe an diesem Tag allerdings klar über 100€ liegen und somit nicht mitgezählt werden dürften.
Nach meinen bisherigen Gedanken müsste die Formel nun also abgleichen, ob es zu diesem Datum einen weiteren Eintrag gibt und wenn ja, die jeweiligen Werte (durchaus mehrere, können ja auch 3 oder auch 5 oder 10 Namen sein) addieren und dann prüfen ob diese Summe unter 100€ liegt. Falls ja, soll dieses Datum gezählt werden.
Bin bisher mit meinen VERGLEICH und BEREICH.VERSCHIEBEN Formeln nicht besonders weit gekommen.. Kann mir da jemand helfen?
Gruß

Bild

Betrifft: eine kleine Beispieltabelle spart Zeit owT
von: ... neopa C
Geschrieben am: 11.08.2015 10:35:07
Gruß Werner
.. , - ...

Bild

Betrifft: AW: eine kleine Beispieltabelle spart Zeit owT
von: Klaus
Geschrieben am: 11.08.2015 11:07:23
Mir wird ständig "ungültiger Dateiname" angezeigt, egal ob ich als .xlsx oder als .jpg hochladen möchte..

Bild

Betrifft: AW: kann ich so nicht nachvollziehen ...
von: ... neopa C
Geschrieben am: 11.08.2015 11:14:01
Hallo Klaus,
... nutzt Du evtl. mit einen Mac?
Gruß Werner
.. , - ...

Bild

Betrifft: AW: kann ich so nicht nachvollziehen ...
von: Klaus
Geschrieben am: 11.08.2015 11:41:35
Hey Werner,
nutze keinen Mac. Ich versuche mal das Ganze hier darzustellen, vielleicht reicht das ja:
A | B | C | D
1|Datum | Name | Wert | unter 100€?
2|03.05 |Klaus |150€ | nein
3|03.05 |Uwe |200€ | nein
4|03.05 |Sabine | 40€ | ja
5|05.05 |Klaus | 80€ | ja
6|07.05 |Klaus | 70€ | ja
7|07.05 |Sabine | 20€ | ja
8|11.05 |Klaus | 80€ | ja
9|11.05 |Jörg | 50€ | ja
Folgende Daten sind unter 100€:
05.05
07.05
Also genau 2 Stück.
Wie kriege ich das per Formel ausgespuckt?

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Rudi Maintaire
Geschrieben am: 11.08.2015 11:56:10
Hallo,

ABCD
1DatumNameWertunter 100€?
203. MaiKlaus150 €nein
303. MaiUwe200 €nein
403. MaiSabine40 €nein
505. MaiKlaus80 €ja
607. MaiKlaus70 €ja
707. MaiSabine20 €ja
811. MaiKlaus80 €nein
911. MaiJörg50 €nein

ZelleFormel
D2=WENN(SUMMEWENN(A:A;A2;C:C)<100;"ja";"nein")

Gruß
Rudi

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 12:04:49
Danke Rudi! Ist es nun möglich, die Anzahl (2) [der Daten mit Ausgaben unter 100€] in einer Zelle E2 anzeigen zu lassen, bestenfalls auch ohne die Hilfsspalte?
Und gibt es eine Möglichkeit, den Wert der Daten mit Ausgaben unter 100€ zu summieren? (Im Beispiel C5, C6, C7)

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Bernd
Geschrieben am: 11.08.2015 12:30:24
Hi,
was soll denn das für einen Sinn haben, zuerst die Tage unterschiedlich zu berechnen und im Endeffekt wieder mehrere Tage zusammen zählen, also C5 - C7.
Was wenn z.B. am 07. Juni selbiges passiert, auch summieren?
mfg Bernd

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 13:16:20
Ich möchte ja am Ende zweierlei Informationen haben:
1. Die Anzahl der Tage haben, an denen unter 100€ ausgegeben wurden.
2. Die Summe der Beträge von den Tagen, an denen unter 100€ ausgegeben wurden - also ja, wenn am 02. August 60€, am 18. August 30€ und am 20. August 95€ ausgegeben wurden(und sonst immer über 100€), dann hätte ich gerne 185€ als Ergebnis.
Der Sinn ist der folgende: Für jede Zahlung (unabhängig vom Wert) wird eine Pauschale berechnet. Bei höheren Werten macht sie natürlich einen kleineren Anteil aus, was wünschenswert ist. Ich möchte wissen bei welchem "Umsatz"/Ausgaben eine "relativ hohe" Pauschale bezahlt wurde, außerdem kann ich dann so den Durchschnitt der Ausgaben unter 100€ berechnen(zweitrangig).

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Bernd
Geschrieben am: 11.08.2015 13:38:54
Hi,
also in die Zelle E2 kommt die vorhin vorgeschlagene Formel:
=WENN(SUMMEWENN(A:A;A2;C:C)<100;"ja";"nein")~f~
diese nach unten ziehen.
In das Feld F1 schreibe das Wort ja
Nun gib diese Formel für die Summe in eine Zelle Deiner Wahl ein:
~f~=SUMMEWENN(E2:E9;F1;C2:C9)
Nun sollte als Ergebnis 170 raus kommen.
mfg Bernd

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 13:53:25
Danke Bernd, damit komme ich auf jeden Fall schon an die Summe der Beträge (also 2tens).
Mit deinen Formeln komme ich aber nicht auf 1tens, die Anzahl der Tage. Dazu müsste ich eine weitere Hilfsspalte eröffnen, richtig?
Die dann so ausgefüllt wird: WENN(ZÄHLENWENN($A$2:A2;A2)=1;WENN(SUMMEWENN(A:C;A2;C:C)>100;0;1);0)
Oder kriege ich beides in eine Hilfsspalte - oder vielleicht sogar ohne Hilfsspalte hin? x)

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Bernd
Geschrieben am: 11.08.2015 13:59:36
Hallo,
da ich kein Profi bin, sondern selber am Mitlernen bin, würde ich mich mit einer Zusätzlichen Zelle, wo eben die 1er gezählt werden, begnügen.
mfg Bernd

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 12:16:37
Danke Rudi! Ist es nun möglich, die Anzahl (2) [der Daten mit Ausgaben unter 100€] in einer Zelle E2 anzeigen zu lassen, bestenfalls auch ohne die Hilfsspalte?
Und gibt es eine Möglichkeit, den Wert der Daten mit Ausgaben unter 100€ zu summieren? (Im Beispiel C5, C6, C7)

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Bernd
Geschrieben am: 11.08.2015 11:57:10
Hi,
oder so:
=SUMMEWENN(A2:A9;F1;C2:C9)
mfg Bernd

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 12:14:56
Wofür steht das F1? Er zeigt mir überall 0 an..

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Bernd
Geschrieben am: 11.08.2015 12:19:04
Hallo,
in F1 kannst Du das Datum eingeben, welches Du abfragen möchtest.
mfg Bernd

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 13:11:14
Ah, danke.
Ich möchte ja prinzipiell nur die Anzahl der Tage haben, an denen unter 100€ ausgegeben wurden. Die einzelnen Tage interessieren mich nicht wirklich.

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: SF
Geschrieben am: 11.08.2015 12:01:29
Hola,
siehe auch:
http://www.office-loesung.de/p/viewtopic.php?f=166&t=699074
Gruß,
steve1da

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Rudi Maintaire
Geschrieben am: 11.08.2015 14:08:55
was anderes fällt mir dazu nicht ein.

ABCDEFGH
1DatumNameWertunter 100€?Betrag Anzahl TageSumme
203. MaiKlaus150 €   2170
303. MaiUwe200 €     
403. MaiSabine40 €     
505. MaiKlaus80 €05.05.201580   
607. MaiKlaus70 €07.05.201590   
707. MaiSabine20 €     
811. MaiKlaus80 €     
911. MaiJörg50 €     

ZelleFormel
D2=WENN(ZÄHLENWENN(A$1:A2;A2)=1;WENN(SUMMEWENN(A:A;A2;C:C)<100;A2;"");"")
E2=WENN(ISTZAHL(D2);SUMMEWENN(A:A;A2;C:C);"")
G2=ANZAHL(E:E)
H2=SUMME(E:E)

Gruß
Rudi

Bild

Betrifft: AW: Ausgaben pro Datum von versch. Personen
von: Klaus
Geschrieben am: 11.08.2015 16:06:03
Super, vielen vielen Dank!!!

Bild

Betrifft: AW: rate mal, was mir dazu eingefallen war ..
von: ... neopa C
Geschrieben am: 11.08.2015 16:15:39
Hallo Rudi,
... hast sicherlich richtig geraten. Und zwar eine Hilfsspalten- und {}-freie Formellösung natürlich auf auf Basis von AGGREGAT() :

 ABCDE
1DatumNameWertAnzahl TageSumme
203. MaiKlaus150 €2170
303. MaiUwe200 €  
403. MaiSabine40 €  
505. MaiKlaus80 €  
607. MaiKlaus70 €  
707. MaiSabine20 €  
811. MaiKlaus80 €  
911. MaiJörg50 €  
10     

Formeln der Tabelle
ZelleFormel
D2=SUMMENPRODUKT(AGGREGAT(14;6;(SUMMEWENN(A2:A1111;A2:A1111;C2:C1111)<100)*(VERGLEICH(A2:A1111&"";A2:A1111&"";)=ZEILE(A1:A1110))*(C2:C1111>0); ZEILE(A1:A1110)))
E2=SUMMENPRODUKT(AGGREGAT(14;6;(SUMMEWENN(A2:A1111;A2:A1111;C2:C1111)<100)*C2:C1111;ZEILE(A1:A1110)))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: welch Wunder! owT
von: Rudi Maintaire
Geschrieben am: 11.08.2015 16:40:58


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Koordinaten der letzten nichtleeren Zeile in Spalp"