Mit Daten aus PPT Excel sheet erstellen

Forumthread: Mit Daten aus PPT Excel sheet erstellen

22.02.2016 23:00:21

jones

Hallo zusammen,
ich habe folgendes Problem:
Auf mehreren ppt folien soll es die Möglichkeit geben jew. 2 buttons anzuklicken, entweder "richtig" oder "falsch". Am Ende der PPT sollen die Ergebnisse per Knopfdruck in ein vorausgefülltes Excel sheet in bestimmte Zellen übertragen werden. Ich suche nun schon ewig nach einer Lösung, aber anscheinend wollen alle immer nur Tabellen in ppt exportieren...hat von Euch jemand eine Lösung parat?
Danke im Voraus!
Gruß jones

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Mit Daten aus PPT Excel sheet erstellen

23.02.2016 15:43:15

fcs
AW: Mit Daten aus PPT Excel sheet erstellen

23.02.2016 21:47:45

jones

AW: Mit Daten aus PPT Excel sheet erstellen

23.02.2016 15:43:15

fcs

Hallo jones,
grundsätzlich kann man die Ergebnisse von PP nach Excel übertragen.
Allerdings solltest du auf den einzelnen Folien jeweils 2 Options-Schaltflächen für Richtig bzw. Falsch plazieren. Das ist leicter auszuwerten.
Nachfolgend ein Code-Beispiel für die Schaltfläche auf der letzten Folie.
Gruß
Franz

Private Sub CommandButton1_Click()
'Commandbutton auf der letzten Folie
Dim xlApp As Object 'Excel.Application
Dim xlWkb As Object 'Excel.Workbook
Dim xlWks As Object 'Excel.Worksheet
Dim strExcelDatei As String
Dim pptPres As Presentation
Dim pptSlide As Slide
Dim varResult
Dim intS
Set pptPres = ActivePresentation
Set xlApp = CreateObject("Excel.Application")
xlApp.Visible = True
'Leeren Excel-Fragebogen schreibgeschützt öffnen
strExcelDatei = "D:\Test\PPT_Frageboden.xlsx"
Set xlWkb = xlApp.Workbooks.Open(FileName:=strExcelDatei, ReadOnly:=True)
Set xlWks = xlWkb.Worksheets(1)
'Folien mit Fragen abarbeiten ( Folie 2 bis vorletzte Folie )
For intS = 2 To pptPres.Slides.Count - 1
Set pptSlide = pptPres.Slides(intS)
'Options-Schaltflächen auf der Folie auswerten
With pptSlide
If .Shapes("OptionButton1").OLEFormat.Object.Value = True Then
varResult = "Richtig"
ElseIf .Shapes("OptionButton2").OLEFormat.Object.Value = True Then
varResult = "Falsch"
Else
varResult = "keine Antwort"
End If
'Optionsschaltflächen zurücksetzen
.Shapes("OptionButton1").OLEFormat.Object.Value = False
.Shapes("OptionButton2").OLEFormat.Object.Value = False
End With
'Antwort im Excelsheet eintragen
Select Case intS
Case 2 'Frage 1
xlWks.Range("C7").Value = varResult
Case 3 'Frage 2
xlWks.Range("C8").Value = varResult
Case 4 'Frage 3
xlWks.Range("C9").Value = varResult
End Select
Next intS
End Sub

AW: Mit Daten aus PPT Excel sheet erstellen

23.02.2016 21:47:45

jones

Super danke!
Das schau ich mir mal in Ruhe an, das sieht aber schon sehr gut aus!!!
Viele Grüße,
jones

Beliebteste Forumthreads (12 Monate)

Mit Daten aus PPT Excel sheet erstellen

Forumthread: Mit Daten aus PPT Excel sheet erstellen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread