Hyperlink mit Leerzeichen

Forumthread: Hyperlink mit Leerzeichen

22.06.2016 18:40:23

Lupo

Hallo Forum,
ich habe ein Makro, mit dem ich ein Inhaltsverzeichnis erstelle.
Das Inhaltsverzeichnis listet alle Sheets einer Exceltabelle auf und erstellt für die einzelnen Sheets einen Hyperlink.
Das läuft auch alles prima.
Wenn aber der Sheetname ein Leerzeichen hat funktioniert der Link nicht.
Hat jemand eine Idee?
Danke schon mal im voraus.
Schöne Grüße,
Lupo
Folgende Code habe ich:

Sub Tabellenlistehy()
' Erstellt das Inhaltverzeichnis
Dim wks As Worksheet
Dim Zeile As Long
'nach alter Liste suchen und löschen
For Each wks In ThisWorkbook.Worksheets
If wks.Name = "Inhaltsverzeichnis" Then
Application.DisplayAlerts = False
wks.Delete
Application.DisplayAlerts = True
End If
Next wks
Worksheets.Add
ActiveSheet.Name = "Inhaltsverzeichnis"
ActiveSheet.Move Before:=Worksheets(1)
Zeile = 1
'alle Tabellen eintragen
For Each wks In ThisWorkbook.Worksheets
'als Hyperlink
With ThisWorkbook.Worksheets("Inhaltsverzeichnis")
'Hyperlink erstellen
.Hyperlinks.Add Cells(Zeile, 1), _
Address:="", SubAddress:=wks.Name & "!A1", TextToDisplay:=wks.Name
End With
Zeile = Zeile + 1
Next wks
End Sub

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Hyperlink mit Leerzeichen

22.06.2016 20:00:50

Matthias
AW: Hyperlink mit Leerzeichen

22.06.2016 20:19:03

Lupo

AW: Hyperlink mit Leerzeichen

22.06.2016 20:00:50

Matthias

Hallo! Füge bei deiner Subadress den wks.Name in Apostrophe. UNd ich habe bei meinem Code noch vor das Cells(Zeile,1) beim Hyperlink Add einen Punkt gemacht. So trägt er die Links auch in das Blatt Inhaltsverzeichnis ein, wenn es aus einem anderen Blatt aufgerufen wird. Achja, das mit dem Apostroph ist auch dabei. Schönen Abend noch

Sub Tabellenlistehy()
' Erstellt das Inhaltverzeichnis
Dim wks As Worksheet
Dim Zeile As Long
'nach alter Liste suchen und löschen
For Each wks In ThisWorkbook.Worksheets
If wks.Name = "Inhaltsverzeichnis" Then
Application.DisplayAlerts = False
wks.Delete
Application.DisplayAlerts = True
End If
Next wks
Worksheets.Add
ActiveSheet.Name = "Inhaltsverzeichnis"
ActiveSheet.Move Before:=Worksheets(1)
Zeile = 1
'alle Tabellen eintragen
For Each wks In ThisWorkbook.Worksheets
'als Hyperlink
With ThisWorkbook.Worksheets("Inhaltsverzeichnis")
'Hyperlink erstellen
.Hyperlinks.Add .Cells(Zeile, 1), Address:="", _
SubAddress:=Chr(39) & wks.Name & Chr(39) & "!A1", TextToDisplay:=wks.Name
End With
Zeile = Zeile + 1
Next wks
End Sub

AW: Hyperlink mit Leerzeichen

22.06.2016 20:19:03

Lupo

Hallo Matthias,
danke für die Hilfe.
Schöne Grüße,
Lupo

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Um Hyperlinks in Excel zu erstellen, die auch dann funktionieren, wenn der Sheetname Leerzeichen enthält, kannst du folgenden VBA-Code verwenden. Dieser Code erstellt ein Inhaltsverzeichnis, das alle Sheets der Arbeitsmappe auflistet und die entsprechenden Hyperlinks erstellt.

Öffne Excel und drücke ALT + F11, um den VBA-Editor zu öffnen.
Klicke auf Einfügen und dann auf Modul, um ein neues Modul zu erstellen.
Füge den folgenden Code in das Modul ein:

Sub Tabellenlistehy()
    ' Erstellt das Inhaltsverzeichnis
    Dim wks As Worksheet
    Dim Zeile As Long
    ' nach alter Liste suchen und löschen
    For Each wks In ThisWorkbook.Worksheets
        If wks.Name = "Inhaltsverzeichnis" Then
            Application.DisplayAlerts = False
            wks.Delete
            Application.DisplayAlerts = True
        End If
    Next wks
    Worksheets.Add
    ActiveSheet.Name = "Inhaltsverzeichnis"
    ActiveSheet.Move Before:=Worksheets(1)
    Zeile = 1
    ' alle Tabellen eintragen
    For Each wks In ThisWorkbook.Worksheets
        ' als Hyperlink
        With ThisWorkbook.Worksheets("Inhaltsverzeichnis")
            ' Hyperlink erstellen
            .Hyperlinks.Add .Cells(Zeile, 1), Address:="", _
                SubAddress:=Chr(39) & wks.Name & Chr(39) & "!A1", TextToDisplay:=wks.Name
        End With
        Zeile = Zeile + 1
    Next wks
End Sub

Schließe den VBA-Editor und kehre zu Excel zurück.
Drücke ALT + F8, wähle Tabellenlistehy aus und klicke auf Ausführen.

Dieser Code sorgt dafür, dass die Hyperlinks auch bei Sheetnamen mit Leerzeichen korrekt erstellt werden.

Häufige Fehler und Lösungen

Fehler: Hyperlink funktioniert nicht bei Sheetnamen mit Leerzeichen.
- Lösung: Stelle sicher, dass du die Sheetnamen in Apostrophe (') setzt, wie im obigen Code gezeigt.
Fehler: Fehlermeldung beim Ausführen des Makros.
- Lösung: Überprüfe, ob bereits ein Arbeitsblatt mit dem Namen "Inhaltsverzeichnis" existiert. Der Code löscht dieses Blatt, bevor er ein neues erstellt.

Alternative Methoden

Wenn du keine VBA-Makros nutzen möchtest, kannst du auch manuell Hyperlinks erstellen:

Wähle die Zelle aus, in die du den Hyperlink einfügen möchtest.
Gehe zu Einfügen > Link > Link einfügen.
Wähle den Reiter Aktuelles Dokument und gib den Namen des Sheets mit Leerzeichen in der Form 'Sheet Name' ein.

Diese Methode ist einfacher, erfordert aber manuelle Eingaben für jeden Link.

Praktische Beispiele

Angenommen, du hast drei Sheets in deiner Arbeitsmappe: "Jahresbericht", "Finanzen 2023" und "Projekte 2023". Der VBA-Code wird für das Inhaltsverzeichnis die folgenden Links erstellen:

Jahresbericht
'Finanzen 2023'
'Projekte 2023'

Damit kannst du einfach zwischen den Sheets navigieren, ohne manuell nach ihnen suchen zu müssen.

Tipps für Profis

Wenn du oft mit Hyperlinks in Excel arbeitest, erwäge, ein benutzerdefiniertes Makro zu erstellen, das spezifische Anforderungen erfüllt, z.B. das Entfernen von Leerzeichen in URLs.
Nutze die Funktion WECHSELN oder SÄUBERN, um unerwünschte Leerzeichen aus deinen Sheetnamen zu entfernen, bevor du sie in Links umwandelst.

FAQ: Häufige Fragen

1. Was ist der Grund für die Verwendung von Apostrophen in Sheetnamen?
Apostrophe werden verwendet, um sicherzustellen, dass Excel den gesamten Namen als einen zusammenhängenden String interpretiert, besonders wenn Leerzeichen enthalten sind.

2. Wie kann ich Leerzeichen in URL umwandeln?
In Excel kannst du URLs mit Leerzeichen so anpassen, dass du %20 anstelle von Leerzeichen verwendest. Dies geschieht oft automatisch, wenn du einen Hyperlink erstellst.

3. Gibt es eine Möglichkeit, Links mit Leerzeichen in einem Textfeld zu erstellen?
Ja, du kannst in einem Textfeld manuell Hyperlinks erstellen, indem du die gleiche Methode wie bei Zellen verwendest, jedoch sicherstellst, dass du die Leerzeichen korrekt behandelst.

Beliebteste Forumthreads (12 Monate)